1 #!/usr/bin/env perl
2 #
3 # Copyright (c) 2022 Omar Polo <op@omarpolo.com>
4 #
5 # Permission to use, copy, modify, and distribute this software for any
6 # purpose with or without fee is hereby granted, provided that the above
7 # copyright notice and this permission notice appear in all copies.
8 #
9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
16 
17 use strict;
18 use warnings;
19 use v5.32;
20 
21 use open ":std", ":encoding(UTF-8)";
22 
23 use Getopt::Long qw(:config bundling require_order);
24 use File::Basename;
25 use File::Find;
26 
27 my $store = $ENV{'PLASS_STORE'} // $ENV{'HOME'}.'/.password-store';
28 
29 my $got = $ENV{'PLASS_GOT'} // 'got';
30 my $tog = $ENV{'PLASS_TOG'} // 'tog';
31 
32 my $gpg = $ENV{'PLASS_GPG'} // 'gpg2';
33 my @gpg_flags = qw(--quiet --compress-algo=none --no-encrypt-to);
34 
35 my $default_chars = $ENV{'PLASS_CHARS'} // '!-~';
36 my $default_length = $ENV{'PLASS_LENGTH'};
37 if (!defined($default_length) || $default_length lt 0) {
38 	$default_length = 32;
39 }
40 
41 my %subcmd = (
42 	cat	=> [\&cmd_cat,		"entries..."],
43 	find	=> [\&cmd_find,		"[pattern]"],
44 	gen	=> [\&cmd_gen,		"[-nq] [-c chars] [-l length] entry"],
45 	got	=> [\&cmd_got,		"args ..."],
46 	mv	=> [\&cmd_mv,		"from to"],
47 	rm	=> [\&cmd_rm,		"entries..."],
48 	tee	=> [\&cmd_tee,		"[-q] entry"],
49 	tog	=> [\&cmd_tog,		"args ..."],
50     );
51 
52 my $usage = "[-h] [command argument ...]";
53 my $cmd;
54 sub usage {
55 	my $prog = basename $0;
56 	if (defined($cmd) and defined($subcmd{$cmd})) {
57 		say STDERR "Usage: $prog $cmd $usage";
58 	} else {
59 		say STDERR "Usage: $prog $usage";
60 		say STDERR "unknown command $cmd" if defined($cmd);
61 		say STDERR "commands: ", join(' ', sort(keys %subcmd));
62 	}
63 	exit 1;
64 }
65 
66 GetOptions("h|?" => \&usage) or usage();
67 
68 $cmd = shift // 'find';
69 usage() unless defined $subcmd{$cmd};
70 my $fn;
71 ($fn, $usage) = @{$subcmd{$cmd}};
72 chdir $store;
73 $fn->();
74 exit 0;
75 
76 
77 # utils
78 
79 sub name2file {
80 	my $f = shift;
81 	$f .= ".gpg" unless $f =~ m,\.gpg$,;
82 	return $f;
83 }
84 
85 # tr -cd -- $chars < /dev/random | dd bs=$len count=1 status=none
86 sub gen {
87 	my ($chars, $length) = @_;
88 	my $pass = "";
89 
90 	open(my $fh, '<:raw', '/dev/random')
91 	    or die "can't open /dev/random: $!";
92 	my $l = $length;
93 	while ($l gt 0) {
94 		read($fh, my $t, $length * 4)
95 		    or die "failed to read /dev/random: $!";
96 		$t =~ s/[^$chars]//g;
97 		$l -= length($t);
98 		$pass .= $t;
99 	}
100 	close($fh);
101 
102 	return substr($pass, 0, $length);
103 }
104 
105 sub readpass {
106 	# todo some stty black magic to avoid echo
107 	print shift if -t;
108 	my $pass = <>;
109 	die "failed to read stdin: $!" unless defined($pass);
110 	chomp $pass;
111 	return $pass;
112 }
113 
114 sub mkdirs {
115 	my $dir = shift;
116 	my $parent = dirname $dir;
117 	mkdirs($parent) unless -d $parent || $parent eq '/';
118 	mkdir $dir or die "mkdir $dir: $!"
119 	    unless -d $dir;
120 }
121 
122 sub writepass {
123 	my ($file, $pass) = @_;
124 
125 	mkdirs(dirname $file);
126 
127 	my @args = ($gpg, @gpg_flags, '-e', '-r', recipient(),
128 	    '-o', $file);
129 	open my $fh, '|-', @args;
130 	say $fh "$pass";
131 	close($fh);
132 }
133 
134 sub recipient {
135 	open my $fh, '<', "$store/.gpg-id"
136 	    or die "can't open recipient file";
137 	my $r = <$fh>;
138 	chomp $r;
139 	close($fh);
140 	return $r;
141 }
142 
143 sub passfind {
144 	my $pattern = shift;
145 	my @entries;
146 
147 	find({
148 		wanted => sub {
149 			if (m,/.git$, || m,/.got$,) {
150 				$File::Find::prune = 1;
151 				return;
152 			}
153 
154 			return if defined($pattern) && ! m/$pattern/;
155 			return unless -f && m,.gpg$,;
156 
157 			s,^$store/*,,;
158 			s,.gpg$,,;
159 			push @entries, $_;
160 		},
161 		no_chdir => 1,
162 		follow_fast => 1,
163 	     }, ($store));
164 	return sort(@entries);
165 }
166 
167 sub got {
168 	# discard stdout
169 	open my $fh, '-|', ($got, @_);
170 	close($fh);
171 	return !$?;
172 }
173 
174 sub got_add {
175 	return got 'add', '-I', shift;
176 }
177 
178 sub got_rm {
179 	got 'remove', '-f', shift
180 	    or exit(1);
181 }
182 
183 sub got_ci {
184 	my $pid = fork;
185 	die "failed to fork: $!" unless defined $pid;
186 
187 	if ($pid ne 0) {
188 		wait;
189 		die "failed to commit changes" if $?;
190 		return;
191 	}
192 
193 	open (STDOUT, ">&", \*STDERR)
194 	    or die "can't redirect stdout to stderr";
195 	exec ($got, 'commit', '-m', shift)
196 	    or die "failed to exec $got: $!";
197 }
198 
199 
200 # cmds
201 
202 sub cmd_cat {
203 	GetOptions('h|?' => \&usage) or usage;
204 	usage unless @ARGV;
205 
206 	while (@ARGV) {
207 		my $file = name2file(shift @ARGV);
208 		system ($gpg, @gpg_flags, '-d', $file);
209 		die "failed to exec $gpg: $!" if $? == -1;
210 	}
211 }
212 
213 sub cmd_find {
214 	GetOptions('h|?' => \&usage) or usage;
215 	usage if @ARGV gt 1;
216 
217 	map { say $_ } passfind(shift @ARGV);
218 }
219 
220 sub cmd_gen {
221 	my $chars = $default_chars;
222 	my $length = $default_length;
223 	my $nop;
224 	my $q;
225 
226 	GetOptions(
227 		'c=s' => sub { $chars = $_[1] },
228 		'h|?' => \&usage,
229 		'l=i' => sub { $length = $_[1] },
230 		'n'   => \$nop,
231 		'q'   => \$q,
232 	    ) or usage;
233 	usage if @ARGV ne 1;
234 
235 	my $name = shift @ARGV;
236 	my $file = name2file $name;
237 	my $renamed = -f $file;
238 
239 	my $pass = gen($chars, $length);
240 
241 	unless ($nop) {
242 		writepass($file, $pass);
243 		got_add $file;
244 		got_ci($renamed ? "update $name" : "+$name");
245 	}
246 	say $pass unless $q;
247 }
248 
249 sub cmd_got {
250 	exec $got, @ARGV;
251 }
252 
253 # TODO: handle moving directories?
254 sub cmd_mv {
255 	GetOptions('h|?' => \&usage) or usage;
256 	usage if @ARGV ne 2;
257 
258 	my $a = shift @ARGV;
259 	my $b = shift @ARGV;
260 
261 	my $pa = name2file $a;
262 	my $pb = name2file $b;
263 
264 	die "source password doesn't exist" unless -f $pa;
265 	die "target password exists" if -f $pb;
266 
267 	rename $pa, $pb or die "can't rename $a to $b: $!";
268 
269 	got_rm $pa;
270 	got_add $pb or die "can't add $pb\n";
271 	got_ci "mv $a $b";
272 }
273 
274 sub cmd_rm {
275 	GetOptions('h|?' => \&usage) or usage;
276 	usage unless @ARGV;
277 
278 	while (@ARGV) {
279 		my $name = shift @ARGV;
280 		my $file = name2file $name;
281 
282 		got_rm $file;
283 		got_ci "-$name";
284 	}
285 }
286 
287 sub cmd_tee {
288 	my $q;
289 	GetOptions(
290 		'h|?' => \&usage,
291 		'q'   => \$q,
292 	    ) or usage;
293 	usage if @ARGV ne 1;
294 
295 	my $name = shift @ARGV;
296 	my $file = name2file $name;
297 
298 	my $pass = readpass "Enter the password: ";
299 	writepass($file, $pass);
300 
301 	got_add $file;
302 	got_ci (-f $file ? "update $name" : "+$name");
303 	say $pass unless $q;
304 }
305 
306 sub cmd_tog {
307 	exec $tog, @ARGV;
308 }