op public repos

Blob

Date:: Mon Mar 21 17:28:14 2005 UTC
Message:: move functions to appease mawk
Actions:: History | Blame | Raw File
1 # Usage: cd $PLAN9; awk -f dist/checkman.awk man?/*.?
2 #
3 # Checks:
4 #	- .TH is first line, and has proper name section number
5 #	- sections are in order NAME, SYNOPSIS, DESCRIPTION, EXAMPLES,
6 #		FILES, SOURCE, SEE ALSO, DIAGNOSTICS, BUGS
7 #	- there's a manual page for each cross-referenced page
8 
9 BEGIN {
10 
11 #	.SH sections should come in the following order
12 
13 	Weight["NAME"] = 1
14 	Weight["SYNOPSIS"] = 2
15 	Weight["DESCRIPTION"] = 4
16 	Weight["EXAMPLE"] = 8
17 	Weight["EXAMPLES"] = 16
18 	Weight["FILES"] = 32
19 	Weight["SOURCE"] = 64
20 	Weight["SEE ALSO"] = 128
21 	Weight["DIAGNOSTICS"] = 256
22 	Weight["SYSTEM CALLS"] = 512
23 	Weight["BUGS"] = 1024
24 
25 	Skipdirs["CVS"] = 1
26 
27 	# allow references to pages provded
28 	# by the underlying Unix system
29 	Omitman["awk(1)"] = 1
30 	Omitman["bash(1)"] = 1
31 	Omitman["chmod(1)"] = 1
32 	Omitman["compress(1)"] = 1
33 	Omitman["cp(1)"] = 1
34 	Omitman["egrep(1)"] = 1
35 	Omitman["gs(1)"] = 1
36 	Omitman["gv(1)"] = 1
37 	Omitman["lex(1)"] = 1
38 	Omitman["lp(1)"] = 1
39 	Omitman["lpr(1)"] = 1
40 	Omitman["mail(1)"] = 1
41 	Omitman["make(1)"] = 1
42 	Omitman["nm(1)"] = 1
43 	Omitman["prof(1)"] = 1
44 	Omitman["pwd(1)"] = 1
45 	Omitman["qiv(1)"] = 1
46 	Omitman["sh(1)"] = 1
47 	Omitman["ssh(1)"] = 1
48 	Omitman["stty(1)"] = 1
49 	Omitman["tex(1)"] = 1
50 	Omitman["unutf(1)"] = 1
51 	Omitman["vnc(1)"] = 1
52 	Omitman["xterm(1)"] = 1
53 
54 	Omitman["access(2)"] = 1
55 	Omitman["brk(2)"] = 1
56 	Omitman["chdir(2)"] = 1
57 	Omitman["close(2)"] = 1
58 	Omitman["connect(2)"] = 1
59 	Omitman["fork(2)"] = 1
60 	Omitman["gethostname(2)"] = 1
61 	Omitman["getpid(2)"] = 1
62 	Omitman["getuid(2)"] = 1
63 	Omitman["open(2)"] = 1
64 	Omitman["pipe(2)"] = 1
65 	Omitman["ptrace(2)"] = 1
66 	Omitman["rmdir(2)"] = 1
67 	Omitman["send(2)"] = 1
68 	Omitman["signal(2)"] = 1
69 	Omitman["sigprocmask(2)"] = 1
70 	Omitman["socketpair(2)"] = 1
71 	Omitman["unlink(2)"] = 1
72 
73 	Omitman["abort(3)"] = 1
74 	Omitman["assert(3)"] = 1
75 	Omitman["fprintf(3)"] = 1
76 	Omitman["fscanf(3)"] = 1
77 	Omitman["fopen(3)"] = 1
78 	Omitman["isalpha(3)"] = 1
79 	Omitman["malloc(3)"] = 1
80 	Omitman["perror(3)"] = 1
81 	Omitman["remove(3)"] = 1
82 	Omitman["sin(3)"] = 1
83 	Omitman["strerror(3)"] = 1
84 
85 	Omitman["core(5)"] = 1
86 	Omitman["passwd(5)"] = 1
87 
88 	Omitman["signal(7)"] = 1
89 
90 	Omitman["cron(8)"] = 1
91 
92 	# don't need documentation for these in bin
93 	Omitted[".cvsignore"] = 1
94 	Omitted["Getdir"] = 1
95 	Omitted["Irc"] = 1
96 	Omitted["Juke"] = 1
97 	Omitted["ajuke"] = 1
98 	Omitted["goodmk"] = 1
99 	Omitted["jukefmt"] = 1
100 	Omitted["jukeget"] = 1
101 	Omitted["jukeindex"] = 1
102 	Omitted["jukeinfo"] = 1
103 	Omitted["jukeplay"] = 1
104 	Omitted["jukeput"] = 1
105 	Omitted["jukesearch"] = 1
106 	Omitted["jukesongfile"] = 1
107 	Omitted["m4ainfo"] = 1
108 	Omitted["mp3info"] = 1
109 	Omitted["notes"] = 1
110 	Omitted["tcolors"] = 1
111 	Omitted["tref"] = 1
112 	Omitted["unutf"] = 1
113 	Omitted["volume"] = 1
114 	Omitted["vtdump"] = 1
115 
116 	# not for users
117 	Omittedlib["creadimage"] = 1
118 	Omittedlib["pixelbits"] = 1
119 	Omittedlib["bouncemouse"] = 1
120 	Omittedlib["main"] = 1	# in libthread
121 	
122 	Omittedlib["opasstokey"] = 1	# in libauthsrv
123 
124 	# functions provided for -lthread_db
125 	Omittedlib["ps_get_thread_area"] = 1
126 	Omittedlib["ps_getpid"] = 1
127 	Omittedlib["ps_lcontinue"] = 1
128 	Omittedlib["ps_lgetfpregs"] = 1
129 	Omittedlib["ps_lgetregs"] = 1
130 	Omittedlib["ps_lsetfpregs"] = 1
131 	Omittedlib["ps_lsetregs"] = 1
132 	Omittedlib["ps_lstop"] = 1
133 	Omittedlib["ps_pcontinue"] = 1
134 	Omittedlib["ps_pdread"] = 1
135 	Omittedlib["ps_pdwrite"] = 1
136 	Omittedlib["ps_pglobal_lookup"] = 1
137 	Omittedlib["ps_pstop"] = 1
138 	Omittedlib["ps_ptread"] = 1
139 	Omittedlib["ps_ptwrite"] = 1
140 
141 	# libmach includes a small dwarf and elf library
142 	Omittedlib["corecmdfreebsd386"] = 1
143 	Omittedlib["corecmdlinux386"] = 1
144 	Omittedlib["coreregsfreebsd386"] = 1
145 	Omittedlib["coreregslinux386"] = 1
146 	Omittedlib["coreregsmachopower"] = 1
147 	Omittedlib["crackelf"] = 1
148 	Omittedlib["crackmacho"] = 1
149 	Omittedlib["dwarfaddrtounit"] = 1
150 	Omittedlib["dwarfclose"] = 1
151 	Omittedlib["dwarfenum"] = 1
152 	Omittedlib["dwarfenumunit"] = 1
153 	Omittedlib["dwarfget1"] = 1
154 	Omittedlib["dwarfget128"] = 1
155 	Omittedlib["dwarfget128s"] = 1
156 	Omittedlib["dwarfget2"] = 1
157 	Omittedlib["dwarfget4"] = 1
158 	Omittedlib["dwarfget8"] = 1
159 	Omittedlib["dwarfgetabbrev"] = 1
160 	Omittedlib["dwarfgetaddr"] = 1
161 	Omittedlib["dwarfgetn"] = 1
162 	Omittedlib["dwarfgetnref"] = 1
163 	Omittedlib["dwarfgetstring"] = 1
164 	Omittedlib["dwarflookupfn"] = 1
165 	Omittedlib["dwarflookupname"] = 1
166 	Omittedlib["dwarflookupnameinunit"] = 1
167 	Omittedlib["dwarflookupsubname"] = 1
168 	Omittedlib["dwarflookuptag"] = 1
169 	Omittedlib["dwarfnextsym"] = 1
170 	Omittedlib["dwarfnextsymat"] = 1
171 	Omittedlib["dwarfopen"] = 1
172 	Omittedlib["dwarfpctoline"] = 1
173 	Omittedlib["dwarfseeksym"] = 1
174 	Omittedlib["dwarfskip"] = 1
175 	Omittedlib["dwarfunwind"] = 1
176 	Omittedlib["elfclose"] = 1
177 	Omittedlib["elfdl386mapdl"] = 1
178 	Omittedlib["elfinit"] = 1
179 	Omittedlib["elfmachine"] = 1
180 	Omittedlib["elfmap"] = 1
181 	Omittedlib["elfopen"] = 1
182 	Omittedlib["elfsection"] = 1
183 	Omittedlib["elfsym"] = 1
184 	Omittedlib["elfsymlookup"] = 1
185 	Omittedlib["elftype"] = 1
186 	Omittedlib["machoclose"] = 1
187 	Omittedlib["machoinit"] = 1
188 	Omittedlib["machoopen"] = 1
189 	Omittedlib["stabsym"] = 1
190 	Omittedlib["symdwarf"] = 1
191 	Omittedlib["symelf"] = 1
192 	Omittedlib["symmacho"] = 1
193 	Omittedlib["symstabs"] = 1
194 	Omittedlib["elfcorelinux386"] = 1
195 	Omittedlib["linux2ureg386"] = 1
196 	Omittedlib["ureg2linux386"] = 1
197 	Omittedlib["coreregs"] = 1	# haven't documented mach yet
198 	Omittedlib["regdesc"] = 1
199 
200 	Omittedlib["auth_attr"] = 1	# not happy about this
201 
202 	Omittedlib["ndbnew"] = 1		# private to library
203 	Omittedlib["ndbsetval"] = 1
204 
205 	Renamelib["chanalt"] = "alt"
206 	Renamelib["channbrecv"] = "nbrecv"
207 	Renamelib["channbrecvp"] = "nbrecvp"
208 	Renamelib["channbrecvul"] = "nbrecvul"
209 	Renamelib["channbsend"] = "nbsend"
210 	Renamelib["channbsendp"] = "nbsendp"
211 	Renamelib["channbsendul"] = "nbsendul"
212 	Renamelib["chanrecv"] = "recv"
213 	Renamelib["chanrecvp"] = "recvp"
214 	Renamelib["chanrecvul"] = "recvul"
215 	Renamelib["chansend"] = "send"
216 	Renamelib["chansendp"] = "sendp"
217 	Renamelib["chansendul"] = "sendul"
218 	Renamelib["threadyield"] = "yield"
219 
220 	Renamelib["fmtcharstod"] = "charstod"
221 	Renamelib["fmtstrtod"] = "strtod"
222 
223 	Renamelib["regcomp9"] = "regcomp"
224 	Renamelib["regcomplit9"] = "regcomplit"
225 	Renamelib["regcompnl9"] = "regcompnl"
226 	Renamelib["regerror9"] = "regerror"
227 	Renamelib["regexec9"] = "regexec"
228 	Renamelib["regsub9"] = "regsub"
229 	Renamelib["rregexec9"] = "rregexec"
230 	Renamelib["rregsub9"] = "rregsub"
231 
232 	lastline = "XXX";
233 	lastfile = FILENAME;
234 }
235 
236 func getnmlist(lib,    cmd)
237 {
238 	cmd = "nm -g " lib
239 	while (cmd | getline) {
240 		if (($2 == "T" || $2 == "L") && $3 !~ "^_"){
241 			sym = $3
242 			sub("^p9", "", sym)
243 			if(sym in Renamelib)
244 				List[Renamelib[sym]] = lib " as " sym
245 			else
246 				List[sym] = lib
247 		}
248 	}
249 	close(cmd)
250 }
251 
252 
253 func getindex(dir,    fname)
254 {
255 	fname = dir "/INDEX"
256 	while ((getline < fname) > 0)
257 		Index[$1] = dir
258 	close(fname)
259 }
260 
261 func getbinlist(dir,    cmd, subdirs, nsd)
262 {
263 	cmd = "ls -p -l " dir
264 	nsd = 0
265 	while (cmd | getline) {
266 		if ($1 ~ /^d/) {
267 			if (!($10 in Skipdirs))
268 				subdirs[++nsd] = $10
269 		} else if ($10 !~ "^_")
270 			List[$10] = dir
271 	}
272 	for ( ; nsd > 0 ; nsd--)
273 		getbinlist(dir "/" subdirs[nsd])
274 	close(cmd)
275 }
276 
277 func clearindex(    i)
278 {
279 	for (i in Index)
280 		delete Index[i]
281 }
282 
283 func clearlist(    i)
284 {
285 	for (i in List)
286 		delete List[i]
287 }
288 
289 
290 FNR==1	{
291 	if(lastline == ""){
292 		# screws up troff headers
293 		print lastfile ":$ is a blank line"
294 	}
295 
296 	n = length(FILENAME)
297 	nam = FILENAME
298 	if(nam ~ /\.html$/)
299 		next
300 	if(nam !~ /^man\/man(.*)\/(.*)\.(.*)$/){
301 		print "nam", nam, "not of form [0-9][0-9]?/*"
302 		next
303 	}
304 	nam = substr(nam, 8)
305 	gsub("[/.]", " ", nam);
306 	n = split(nam, a)
307 	sec = a[1]
308 	name = a[2]
309 	section = a[3]
310 	if($1 != ".TH" || NF != 3)
311 		print "First line of", FILENAME, "not a proper .TH"
312 	else if(($2 != toupper(name) || substr($3, 1, length(sec)) != sec || $3 != toupper(section)) \
313 			&& ($2!="INTRO" || name!="0intro") \
314 			&& (name !~ /^9/ || $2!=toupper(substr(name, 2)))){
315 		print ".TH of", FILENAME, "doesn't match filename"
316 	}else
317 		Pages[tolower($2) "(" tolower($3) ")"] = 1
318 	Sh = 0
319 }
320 
321 { lastline=$0; lastfile=FILENAME; }
322 
323 $1 == ".SH" {
324 	if(inex)
325 		print "Unterminated .EX in", FILENAME, ":", $0
326 	inex = 0;
327 	if (substr($2, 1, 1) == "\"") {
328 		if (NF == 2) {
329 			print "Unneeded quote in", FILENAME, ":", $0
330 			$2 = substr($2, 2, length($2)-2)
331 		} else if (NF == 3) {
332 			$2 = substr($2, 2) substr($3, 1, length($3)-1)
333 			NF = 2
334 		}
335 	}
336 	if(Sh == 0 && $2 != "NAME")
337 		print FILENAME, "has no .SH NAME"
338 	w = Weight[$2]
339 	if (w) {
340 		if (w < Sh)
341 			print "Heading", $2, "out of order in", FILENAME
342 		Sh += w
343 	}
344 	sh = $2
345 }
346 
347 $1 == ".EX" {
348 		if(inex)
349 			print "Nested .EX in", FILENAME ":" FNR, ":", $0
350 		inex = 1
351 }
352 
353 $1 == ".EE" {
354 	if(!inex)
355 		print "Bad .EE in", FILENAME ":" FNR ":", $0
356 	inex = 0;
357 }
358 
359 $1 == ".TF" {
360 	smallspace = 1
361 }
362 
363 $1 == ".PD" || $1 == ".SH" || $1 == ".SS" || $1 == ".TH" {
364 	smallspace = 0
365 }
366 
367 $1 == ".RE" {
368 	lastre = 1
369 }
370 
371 $1 == ".PP" {
372 	if(smallspace && !lastre)
373 		print "Possible missing .PD at " FILENAME ":" FNR
374 	smallspace = 0
375 }
376 
377 $1 != ".RE" {
378 	lastre = 0
379 }
380 
381 sh == "BUGS" && $1 == ".br" {
382 	print FILENAME ":" FNR ": .br in BUGS"
383 }
384 
385 sh == "SOURCE" && $1 ~ /^\\\*9\// {
386 	s = ENVIRON["PLAN9"] substr($1, 4)
387 	Sources[s] = 1
388 }
389 
390 sh == "SOURCE" && $2 ~ /^\\\*9\// {
391 	s = ENVIRON["PLAN9"] substr($2, 4)
392 	Sources[s] = 1
393 }
394 
395 sh == "SOURCE" && $1 ~ /^\// {
396 	Sources[$1] = 1
397 }
398 
399 sh == "SOURCE" && $2 ~ /^\// {
400 	Sources[$2] = 1
401 }
402 
403 $0 ~ /^\.[A-Z].*\([1-9]\)/ {
404 		if ($1 == ".IR" && $3 ~ /\([0-9]\)/) {
405 			name = $2
406 			section = $3
407 		}else if ($1 == ".RI" && $2 == "(" && $4 ~ /\([0-9]\)/) {
408 			name = $3
409 			section = $4
410 		}else if ($1 == ".IR" && $3 ~ /9.\([0-9]\)/) {
411 			name = $2
412 			section = "9"
413 		}else if ($1 == ".RI" && $2 == "(" && $4 ~ /9.\([0-9]\)/) {
414 			name = $3
415 			section = "9"
416 		} else {
417 			if ($1 == ".HR" && $3 == "\"Section")
418 				next;
419 			print "Possible bad cross-reference format in", FILENAME ":" FNR
420 			print $0
421 			next
422 		}
423 		gsub(/[^0-9]/, "", section)
424 		Refs[toupper(name) "(" section ")"]++
425 }
426 
427 END {
428 	if(lastline == ""){
429 		print lastfile ":$ is a blank line"
430 	}
431 
432 	print "Checking Source References"
433 	cmd = "xargs -n 100 ls -d 2>&1 >/dev/null | sed 's/^ls: /	/; s/: .*//'"
434 	for (i in Sources) {
435 		print i |cmd
436 	}
437 	close(cmd)
438 	print ""
439 	print "Checking Cross-Referenced Pages"
440 	for (i in Refs) {
441 		if (!(tolower(i) in Pages) && !(tolower(i) in Omitman)){
442 			b = tolower(i)
443 			gsub("\\(", " \\(", b)
444 			gsub("\\)", "\\)", b)
445 			split(tolower(i), a, "/")
446 			print "egrep -in '^\\.IR.*" b "' $PLAN9/man/man*/* # Need " tolower(i) |"sort"
447 		}
448 	}
449 	close("sort")
450 	print ""
451 	print "Checking commands"
452 	getindex("man/man1")
453 	getindex("man/man4")
454 	getindex("man/man7")
455 	getindex("man/man8")
456 	getbinlist("bin")
457 	for (i in List) {
458 		if (!(i in Index) && !(i in Omitted))
459 			print "Need", i, "(in " List[i] ")" |"sort"
460 	}
461 	close("sort")
462 	print ""
463 	for (i in List) {
464 		if (!(i in Index) && (i in Omitted))
465 			print "Omit", i, "(in " List[i] ")" |"sort"
466 	}
467 	close("sort")
468 	clearindex()
469 	clearlist()
470 	print ""
471 	print "Checking libraries"
472 	getindex("man/man3")
473 	getnmlist("lib/lib9.a")
474 	getnmlist("lib/lib9p.a")
475 	getnmlist("lib/lib9pclient.a")
476 	getnmlist("lib/libString.a")
477 	getnmlist("lib/libauth.a")
478 	getnmlist("lib/libauthsrv.a")
479 	getnmlist("lib/libbin.a")
480 	getnmlist("lib/libbio.a")
481 	getnmlist("lib/libcomplete.a")
482 	# getnmlist("lib/libcontrol.a")
483 	getnmlist("lib/libdisk.a")
484 	getnmlist("lib/libdraw.a")
485 	getnmlist("lib/libflate.a")
486 	getnmlist("lib/libframe.a")
487 	getnmlist("lib/libgeometry.a")
488 	getnmlist("lib/libhtml.a")
489 	# getnmlist("lib/libhttpd.a")
490 	getnmlist("lib/libip.a")
491 	getnmlist("lib/libmach.a")
492 	# getnmlist("lib/libmemdraw.a")
493 	# getnmlist("lib/libmemlayer.a")
494 	getnmlist("lib/libmp.a")
495 	getnmlist("lib/libmux.a")
496 	getnmlist("lib/libndb.a")
497 	getnmlist("lib/libplumb.a")
498 	getnmlist("lib/libregexp9.a")
499 	getnmlist("lib/libsec.a")
500 	getnmlist("lib/libthread.a")
501 	# getnmlist("lib/libventi.a")
502 	for (i in List) {
503 		if (!(i in Index) && !(i in Omittedlib))
504 			print "Need", List[i], i |"sort"
505 			# print "Need", i, "(in " List[i] ")" |"sort"
506 	}
507 	close("sort")
508 	print ""
509 	for (i in List) {
510 		if (!(i in Index) && (i in Omittedlib))
511 			print "Omit", List[i], i |"sort"
512 			# print "Omit", i, "(in " List[i] ")" |"sort"
513 	}
514 	close("sort")
515 }
516