1 #!/usr/bin/env perl
2 #
3 # Copyright (c) 2022, 2023 Omar Polo <op@omarpolo.com>
4 #
5 # Permission to use, copy, modify, and distribute this software for any
6 # purpose with or without fee is hereby granted, provided that the above
7 # copyright notice and this permission notice appear in all copies.
8 #
9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
16 
17 use strict;
18 use warnings;
19 use v5.32;
20 
21 use open ":std", ":encoding(UTF-8)";
22 
23 use Getopt::Long qw(:config bundling require_order);
24 use File::Basename;
25 use File::Find;
26 use File::Temp qw(tempfile);
27 
28 my $store = $ENV{'PLASS_STORE'} // $ENV{'HOME'}.'/.password-store';
29 
30 my $gpg = $ENV{'PLASS_GPG'} // 'gpg';
31 my @gpg_flags = qw(--quiet --compress-algo=none --no-encrypt-to --use-agent);
32 
33 my %subcmd = (
34 	cat	=> [\&cmd_cat,		"entries..."],
35 	edit	=> [\&cmd_edit,		"entry"],
36 	find	=> [\&cmd_find,		"[pattern]"],
37 	mv	=> [\&cmd_mv,		"from to"],
38 	rm	=> [\&cmd_rm,		"entries..."],
39 	tee	=> [\&cmd_tee,		"[-q] entry"],
40     );
41 
42 my $usage = "[-h] command [argument ...]";
43 my $cmd;
44 sub usage {
45 	my $prog = basename $0;
46 	if (defined($cmd) and defined($subcmd{$cmd})) {
47 		say STDERR "Usage: $prog $cmd $usage";
48 	} else {
49 		say STDERR "Usage: $prog $usage";
50 		say STDERR "unknown command $cmd" if defined($cmd);
51 		say STDERR "commands: ", join(' ', sort(keys %subcmd));
52 	}
53 	exit 1;
54 }
55 
56 GetOptions("h|?" => \&usage) or usage();
57 
58 $cmd = shift // 'find';
59 usage() unless defined $subcmd{$cmd};
60 my $fn;
61 ($fn, $usage) = @{$subcmd{$cmd}};
62 chdir $store;
63 $fn->();
64 exit 0;
65 
66 
67 # utils
68 
69 sub name2file {
70 	my $f = shift;
71 	$f .= ".gpg" unless $f =~ m,\.gpg$,;
72 	return $f;
73 }
74 
75 sub mkdirs {
76 	my $dir = shift;
77 	my $parent = dirname $dir;
78 	mkdirs($parent) unless -d $parent || $parent eq '/';
79 	mkdir $dir or die "mkdir $dir: $!"
80 	    unless -d $dir;
81 }
82 
83 sub recipient {
84 	open my $fh, '<', "$store/.gpg-id"
85 	    or die "can't open recipient file";
86 	my $r = <$fh>;
87 	chomp $r;
88 	close($fh);
89 	return $r;
90 }
91 
92 sub passfind {
93 	my $pattern = shift;
94 	my @entries;
95 
96 	find({
97 		wanted => sub {
98 			if (m,/.git$, || m,/.got$,) {
99 				$File::Find::prune = 1;
100 				return;
101 			}
102 			return unless -f && m,.gpg$,;
103 
104 			s,^$store/*,,;
105 			s,.gpg$,,;
106 
107 			return if defined($pattern) && ! m/$pattern/i;
108 			push @entries, $_;
109 		},
110 		no_chdir => 1,
111 		follow_fast => 1,
112 	     }, ($store));
113 	return sort(@entries);
114 }
115 
116 sub got {
117 	# discard stdout
118 	open my $fh, '-|', ('got', @_);
119 	close($fh);
120 	return !$?;
121 }
122 
123 sub got_add {
124 	return got 'add', '-I', shift;
125 }
126 
127 sub got_rm {
128 	got 'remove', '-f', shift
129 	    or exit(1);
130 }
131 
132 sub got_ci {
133 	my $pid = fork;
134 	die "failed to fork: $!" unless defined $pid;
135 
136 	if ($pid != 0) {
137 		wait;
138 		die "failed to commit changes" if $?;
139 		return;
140 	}
141 
142 	open (STDOUT, ">&", \*STDERR)
143 	    or die "can't redirect stdout to stderr";
144 	exec ('got', 'commit', '-m', shift)
145 	    or die "failed to exec got: $!";
146 }
147 
148 
149 # cmds
150 
151 sub cmd_cat {
152 	GetOptions('h|?' => \&usage) or usage;
153 	usage unless @ARGV;
154 
155 	while (@ARGV) {
156 		my $file = name2file(shift @ARGV);
157 		system ($gpg, @gpg_flags, '-d', $file);
158 		die "failed to exec $gpg: $!" if $? == -1;
159 	}
160 }
161 
162 sub cmd_edit {
163 	GetOptions('h|?' => \&usage) or usage;
164 	usage if @ARGV != 1;
165 
166 	my $editor = $ENV{'VISUAL'} // $ENV{'EDITOR'} // 'ed';
167 
168 	my $entry = shift @ARGV;
169 	my $epath = name2file $entry;
170 
171 	my ($fh, $filename) = tempfile "/tmp/plass-XXXXXXXXXX";
172 
173 	open (my $stdout, ">&", STDOUT) or die "can't redirect stdout: $!";
174 
175 	open (STDOUT, ">&", $fh) or die "can't redirect stdout to $filename";
176 	system ($gpg, @gpg_flags, '-d', $epath);
177 	die "$gpg exited with $?\n" if $? != 0;
178 
179 	# restore stdout so the editor can access the TTY if needed.
180 	open (STDOUT, ">&", $stdout) or die "can't restore stdout: $!";
181 
182 	my $oldtime = (stat($fh))[9];
183 
184 	system ($editor, $filename);
185 	die "editor $editor failed\n" if $? != 0;
186 
187 	my $newtime = (stat($filename))[9];
188 
189 	if ($oldtime == $newtime) {
190 		say STDERR "no changes made.";
191 		unlink $filename or die "can't delete $filename: $!\n";
192 		return
193 	}
194 
195 	open(STDIN, '<', $filename) or die "can't redirect stdin: $!";
196 	open(STDOUT, '>', $epath) or die "can't redirect stdout: $!";
197 	system ($gpg, @gpg_flags, '-e', '-r', recipient(), '-o', '-');
198 	unlink $filename or die "can't delete $filename: $!\n";
199 	die "gpg failed" if $? != 0;
200 
201 	got_add $epath;
202 	got_ci "update $entry";
203 }
204 
205 sub cmd_find {
206 	GetOptions('h|?' => \&usage) or usage;
207 	usage if @ARGV > 1;
208 
209 	map { say $_ } passfind(shift @ARGV);
210 }
211 
212 # TODO: handle moving directories?
213 sub cmd_mv {
214 	GetOptions('h|?' => \&usage) or usage;
215 	usage if @ARGV != 2;
216 
217 	my $a = shift @ARGV;
218 	my $b = shift @ARGV;
219 
220 	my $pa = name2file $a;
221 	my $pb = name2file $b;
222 
223 	die "source password doesn't exist" unless -f $pa;
224 	die "target password exists" if -f $pb;
225 
226 	mkdirs(dirname $pb);
227 	rename $pa, $pb or die "can't rename $a to $b: $!";
228 
229 	got_rm $pa;
230 	got_add $pb or die "can't add $pb\n";
231 	got_ci "mv $a $b";
232 }
233 
234 sub cmd_rm {
235 	GetOptions('h|?' => \&usage) or usage;
236 	usage unless @ARGV;
237 
238 	while (@ARGV) {
239 		my $name = shift @ARGV;
240 		my $file = name2file $name;
241 
242 		got_rm $file;
243 		got_ci "-$name";
244 	}
245 }
246 
247 sub cmd_tee {
248 	my $q;
249 	GetOptions(
250 		'h|?' => \&usage,
251 		'q'   => \$q,
252 	    ) or usage;
253 	usage if @ARGV != 1;
254 
255 	my $name = shift @ARGV;
256 	my $file = name2file $name;
257 
258 	my $msg = -f $file ? "update $name" : "+$name";
259 	mkdirs(dirname $file);
260 
261 	my @args = ($gpg, @gpg_flags, '-e', '-r', recipient(),
262 	    '--batch', '--yes', '-o', $file);
263 	open my $fh, '|-', @args;
264 
265 	local $/ = \1024;
266 	while (<STDIN>) {
267 		print $fh $_;
268 		print $_ unless $q;
269 	}
270 	close($fh);
271 	exit $? if $?;
272 
273 	got_add $file;
274 	got_ci $msg;
275 }