1 AC_INIT([kamid], [0.2], [kamid@omarpolo.com], [],
2 	[https://kamid.omarpolo.com])
3 AC_CONFIG_AUX_DIR(etc)
4 AC_CONFIG_LIBOBJ_DIR(compat)
5 AM_INIT_AUTOMAKE([foreign subdir-objects])
6 
7 KAMID_RELEASE=No
8 
9 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
10 AC_SUBST(VERSION)
11 AC_SUBST(KAMID_RELEASE)
12 
13 AC_CANONICAL_HOST
14 
15 # When CFLAGS isn't set at this stage and gcc is detected by the macro below,
16 # autoconf will automatically use CFLAGS="-O2 -g". Prevent that by using an
17 # empty default.
18 : ${CFLAGS=""}
19 
20 # Save user CPPFLAGS, CFLAGS and LDFLAGS. We need to change them because
21 # AC_CHECK_HEADER doesn't give us any other way to update the include
22 # paths. But for Makefile.am we want to use AM_CPPFLAGS and friends.
23 SAVED_CFLAGS="$CFLAGS"
24 SAVED_CPPFLAGS="$CPPFLAGS"
25 SAVED_LDFLAGS="$LDFLAGS"
26 
27 # Checks for programs.
28 AC_PROG_CC
29 AC_PROG_CPP
30 AC_PROG_INSTALL
31 AC_PROG_LN_S
32 AC_PROG_MAKE_SET
33 AC_PROG_RANLIB
34 AC_PROG_YACC
35 PKG_PROG_PKG_CONFIG
36 AC_USE_SYSTEM_EXTENSIONS
37 
38 # Some functions can be in libbsd.  Thanks to lldpb for the inspiration :)
39 AC_ARG_WITH([libbsd],
40   AS_HELP_STRING([--with-libbsd], [Use libbsd @<:@default=auto@:>@]),
41   [],
42   [with_libbsd=auto])
43 if test x"$with_libbsd" != x"no"; then
44   PKG_CHECK_MODULES([libbsd], [libbsd-overlay libbsd-ctor], [
45     _save_AM_CFLAGS="$AM_CFLAGS"
46     _save_LIBS="$LIBS"
47     AM_CFLAGS="$AM_CFLAGS $libbsd_CFLAGS"
48     LIBS="$LIBS $libbsd_LIBS"
49   ], [
50     if test x"$with_libbsd" = x"yes"; then
51        AC_MSG_FAILURE([*** no libbsd support found])
52     fi
53     with_libbsd=no
54   ])
55 fi
56 
57 AC_REPLACE_FUNCS([
58 	asprintf	\
59 	err		\
60 	freezero	\
61 	getdtablecount	\
62 	getdtablesize	\
63 	getprogname	\
64 	memmem		\
65 	recallocarray	\
66 	setproctitle	\
67 	setprogname	\
68 	strlcat		\
69 	strlcpy		\
70 	strsep		\
71 	strtonum	\
72 	vis		\
73 ])
74 
75 AC_MSG_CHECKING([for sys/queue.h with TAILQ_FOREACH_SAFE and STAILQ_ENTRY])
76 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
77 #include <sys/queue.h>
78 #include <stddef.h>
79 ], [
80 	TAILQ_HEAD(tailhead, entry) head;
81 	struct entry {
82 		TAILQ_ENTRY(entry) entries;
83 	} *np, *nt;
84 	TAILQ_INIT(&head);
85 	TAILQ_FOREACH_SAFE(np, &head, entries, nt) {
86 		/* nop */ ;
87 	}
88 
89 	STAILQ_HEAD(listhead, qentry) qhead = STAILQ_HEAD_INITIALIZER(qhead);
90 	struct qentry {
91 		STAILQ_ENTRY(qentry) entries;
92 	} foo;
93 
94 	return 0;
95 ])], [
96 	AC_MSG_RESULT(yes)
97 	AC_DEFINE([HAVE_QUEUE_H], 1, [QUEUE_H])
98 ], AC_MSG_RESULT(no))
99 
100 AC_CHECK_HEADERS([sys/tree.h])
101 
102 AC_CHECK_DECL(PR_SET_NAME, AC_DEFINE([HAVE_PR_SET_NAME], 1, [pr_set_name]), [],
103 	[[#include <sys/prctl.h>]])
104 
105 AC_CHECK_LIB([crypto], [RAND_add], [], [
106 	AC_MSG_ERROR([requires openssl])
107 ])
108 
109 AC_CHECK_LIB(tls, tls_init, [], [
110 	AC_MSG_ERROR([requires libtls])
111 ])
112 
113 AS_CASE([$host_os],
114 	[*openbsd*], [AC_CHECK_LIB([event], [event_init], [],
115 			[AC_MSG_ERROR([requires libevent])])],
116 	[PKG_CHECK_MODULES([libevent2], [libevent_core >= 2],
117 		[
118 			AC_DEFINE([HAVE_EVENT2], 1, [1 if using event2])
119 			AM_CFLAGS="$libevent2_CFLAGS $AM_CFLAGS"
120 			LIBS="$libevent2_LIBS $LIBS"
121 		], [AC_MSG_ERROR([requires libevent])])])
122 
123 AC_CHECK_LIB(util, imsg_init, [], [
124 	AC_LIBOBJ(fmt_scaled)
125 	AC_LIBOBJ(imsg)
126 	AC_LIBOBJ(imsg-buffer)
127 	AC_LIBOBJ(ohash)
128 ])
129 
130 # Check for readline
131 AS_CASE([$host_os],
132 	[*openbsd*], [
133 		AC_DEFINE([HAVE_READLINE], 1, [1 if readline found])
134 		READLINE_CFLAGS=''
135 		READLINE_LIBS='-lreadline'
136 	], [
137 		PKG_CHECK_MODULES([READLINE], [readline], [
138 			AC_DEFINE([HAVE_READLINE], 1, [])
139 		], [
140 			AC_DEFINE([HAVE_READLINE], 0, [])
141 		])
142 	]
143 )
144 AC_SUBST(READLINE_CFLAGS)
145 AC_SUBST(READLINE_LIBS)
146 
147 # check compiler flags
148 AC_DEFUN([CC_ADD_CHECK_FLAGS], [
149 	AC_MSG_CHECKING([if $CC supports $1 flag])
150 	old_AM_CFLAGS="$AM_CFLAGS"
151 	AM_CFLAGS="$AM_CFLAGS $1"
152 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])],
153 		AC_MSG_RESULT(yes), [
154 			AC_MSG_RESULT(no)
155 			AM_CFLAGS="$old_AM_CFLAGS"
156 		])
157 ])
158 CC_ADD_CHECK_FLAGS([-Wall])
159 CC_ADD_CHECK_FLAGS([-Wextra])
160 CC_ADD_CHECK_FLAGS([-Wmissing-declarations])
161 CC_ADD_CHECK_FLAGS([-Wmissing-prototypes])
162 CC_ADD_CHECK_FLAGS([-Wstrict-prototypes])
163 CC_ADD_CHECK_FLAGS([-Wwrite-strings])
164 CC_ADD_CHECK_FLAGS([-Wno-unused-parameter])
165 CC_ADD_CHECK_FLAGS([-Wpointer-arith])
166 CC_ADD_CHECK_FLAGS([-Wsign-compare])
167 CC_ADD_CHECK_FLAGS([-Wcast-align])
168 
169 # Save our CFLAGS/CPPFLAGS/LDFLAGS for the Makefile and restore the old user
170 # variables.
171 AC_SUBST(AM_CPPFLAGS)
172 CPPFLAGS="$SAVED_CPPFLAGS"
173 AC_SUBST(AM_CFLAGS)
174 CFLAGS="$SAVED_CFLAGS"
175 AC_SUBST(AM_LDFLAGS)
176 LDFLAGS="$SAVED_LDFLAGS"
177 
178 AC_CONFIG_HEADERS([config.h])
179 AC_CONFIG_FILES([
180 	Makefile
181 	compat/Makefile
182 	contrib/Makefile
183 	kamictl/Makefile
184 	kamid/Makefile
185 	kamiftp/Makefile
186 	kamiproxy/Makefile
187 	kamirepl/Makefile
188 	ninepscript/Makefile
189 	regress/Makefile
190 	regress/lisp/Makefile
191 	regress/ninepscript/Makefile
192 ])
193 
194 AC_OUTPUT