1 /* -*- mode: fundamental; indent-tabs-mode: t; -*- */
2 %{
3 
4 /*
5  * Copyright (c) 2021 Omar Polo <op@omarpolo.com>
6  *
7  * Permission to use, copy, modify, and distribute this software for any
8  * purpose with or without fee is hereby granted, provided that the above
9  * copyright notice and this permission notice appear in all copies.
10  *
11  * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
12  * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
13  * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
14  * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
15  * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
16  * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
17  * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
18  */
19 
20 #include <errno.h>
21 #include <stdarg.h>
22 #include <stdio.h>
23 #include <string.h>
24 
25 #include "gmid.h"
26 
27 /*
28  * #define YYDEBUG 1
29  * int yydebug = 1;
30  */
31 
32 struct vhost *host;
33 struct location *loc;
34 
35 int goterror = 0;
36 
37 static struct vhost	*new_vhost(void);
38 static struct location	*new_location(void);
39 
40 void		 yyerror(const char*, ...);
41 int		 parse_portno(const char*);
42 void		 parse_conf(const char*);
43 char		*ensure_absolute_path(char*);
44 int		 check_block_code(int);
45 char		*check_block_fmt(char*);
46 int		 check_strip_no(int);
47 int		 check_prefork_num(int);
48 void		 advance_loc(void);
49 
50 %}
51 
52 /* for bison: */
53 /* %define parse.error verbose */
54 
55 %union {
56 	char		*str;
57 	int		 num;
58 }
59 
60 %token TIPV6 TPORT TPROTOCOLS TMIME TDEFAULT TTYPE TCHROOT TUSER TSERVER
61 %token TPREFORK TLOCATION TCERT TKEY TROOT TCGI TENV TLANG TLOG TINDEX TAUTO
62 %token TSTRIP TBLOCK TRETURN TENTRYPOINT TREQUIRE TCLIENT TCA TALIAS
63 
64 %token TERR
65 
66 %token <str>	TSTRING
67 %token <num>	TNUM
68 %token <num>	TBOOL
69 
70 %%
71 
72 conf		: options vhosts ;
73 
74 options		: /* empty */
75 		| options option
76 		;
77 
78 option		: TCHROOT TSTRING	{ conf.chroot = $2; }
79 		| TIPV6 TBOOL		{ conf.ipv6 = $2; }
80 		| TMIME TSTRING TSTRING	{ add_mime(&conf.mime, $2, $3); }
81 		| TPORT TNUM		{ conf.port = $2; }
82 		| TPREFORK TNUM		{ conf.prefork = check_prefork_num($2); }
83 		| TPROTOCOLS TSTRING {
84 			if (tls_config_parse_protocols(&conf.protos, $2) == -1)
85 				yyerror("invalid protocols string \"%s\"", $2);
86 		}
87 		| TUSER TSTRING		{ conf.user = $2; }
88 		;
89 
90 vhosts		: /* empty */
91 		| vhosts vhost
92 		;
93 
94 vhost		: TSERVER TSTRING {
95 			host = new_vhost();
96 			TAILQ_INSERT_HEAD(&hosts, host, vhosts);
97 
98 			loc = new_location();
99 			TAILQ_INSERT_HEAD(&host->locations, loc, locations);
100 
101 			loc->match = xstrdup("*");
102 			host->domain = $2;
103 
104 			if (strstr($2, "xn--") != NULL) {
105 				warnx("%s:%d \"%s\" looks like punycode: "
106 				    "you should use the decoded hostname.",
107 				    config_path, yylineno, $2);
108 			}
109 		} '{' servopts locations '}' {
110 
111 			if (host->cert == NULL || host->key == NULL ||
112 			    host->dir == NULL)
113 				yyerror("invalid vhost definition: %s", $2);
114 		}
115 		| error '}'		{ yyerror("error in server directive"); }
116 		;
117 
118 servopts	: /* empty */
119 		| servopts servopt
120 		;
121 
122 servopt		: TALIAS TSTRING {
123 			struct alist *a;
124 
125 			a = xcalloc(1, sizeof(*a));
126 			a->alias = $2;
127 			if (TAILQ_EMPTY(&host->aliases))
128 				TAILQ_INSERT_HEAD(&host->aliases, a, aliases);
129 			else
130 				TAILQ_INSERT_TAIL(&host->aliases, a, aliases);
131 		}
132 		| TCERT TSTRING		{ host->cert = ensure_absolute_path($2); }
133 		| TCGI TSTRING		{
134 			/* drop the starting '/', if any */
135 			if (*$2 == '/')
136 				memmove($2, $2+1, strlen($2));
137 			host->cgi = $2;
138 		}
139 		| TENTRYPOINT TSTRING {
140 			if (host->entrypoint != NULL)
141 				yyerror("`entrypoint' specified more than once");
142 			while (*$2 == '/')
143 				memmove($2, $2+1, strlen($2));
144 			host->entrypoint = $2;
145 		}
146 		| TENV TSTRING TSTRING {
147 			struct envlist *e;
148 
149 			e = xcalloc(1, sizeof(*e));
150 			e->name = $2;
151 			e->value = $3;
152 			if (TAILQ_EMPTY(&host->env))
153 				TAILQ_INSERT_HEAD(&host->env, e, envs);
154 			else
155 				TAILQ_INSERT_TAIL(&host->env, e, envs);
156 		}
157 		| TKEY TSTRING		{ host->key  = ensure_absolute_path($2); }
158 		| TROOT TSTRING		{ host->dir  = ensure_absolute_path($2); }
159 		| locopt
160 		;
161 
162 locations	: /* empty */
163 		| locations location
164 		;
165 
166 location	: TLOCATION { advance_loc(); } TSTRING '{' locopts '}'	{
167 			/* drop the starting '/' if any */
168 			if (*$3 == '/')
169 				memmove($3, $3+1, strlen($3));
170 			loc->match = $3;
171 		}
172 		| error '}'
173 		;
174 
175 locopts		: /* empty */
176 		| locopts locopt
177 		;
178 
179 locopt		: TAUTO TINDEX TBOOL	{ loc->auto_index = $3 ? 1 : -1; }
180 		| TBLOCK TRETURN TNUM TSTRING {
181 			if (loc->block_fmt != NULL)
182 				yyerror("`block' rule specified more than once");
183 			loc->block_fmt = check_block_fmt($4);
184 			loc->block_code = check_block_code($3);
185 		}
186 		| TBLOCK TRETURN TNUM {
187 			if (loc->block_fmt != NULL)
188 				yyerror("`block' rule specified more than once");
189 			loc->block_fmt = xstrdup("temporary failure");
190 			loc->block_code = check_block_code($3);
191 			if ($3 >= 30 && $3 < 40)
192 				yyerror("missing `meta' for block return %d", $3);
193 		}
194 		| TBLOCK {
195 			if (loc->block_fmt != NULL)
196 				yyerror("`block' rule specified more than once");
197 			loc->block_fmt = xstrdup("temporary failure");
198 			loc->block_code = 40;
199 		}
200 		| TDEFAULT TTYPE TSTRING {
201 			if (loc->default_mime != NULL)
202 				yyerror("`default type' specified more than once");
203 			loc->default_mime = $3;
204 		}
205 		| TINDEX TSTRING {
206 			if (loc->index != NULL)
207 				yyerror("`index' specified more than once");
208 			loc->index = $2;
209 		}
210 		| TLANG TSTRING {
211 			if (loc->lang != NULL)
212 				yyerror("`lang' specified more than once");
213 			loc->lang = $2;
214 		}
215 		| TLOG TBOOL	{ loc->disable_log = !$2; }
216 		| TREQUIRE TCLIENT TCA TSTRING {
217 			if (loc->reqca != NULL)
218 				yyerror("`require client ca' specified more than once");
219 			if (*$4 != '/')
220 				yyerror("path to certificate must be absolute: %s", $4);
221 			if ((loc->reqca = load_ca($4)) == NULL)
222 				yyerror("couldn't load ca cert: %s", $4);
223 			free($4);
224 		}
225 		| TSTRIP TNUM		{ loc->strip = check_strip_no($2); }
226 		;
227 
228 %%
229 
230 static struct vhost *
231 new_vhost(void)
232 {
233 	return xcalloc(1, sizeof(struct vhost));
234 }
235 
236 static struct location *
237 new_location(void)
238 {
239 	return xcalloc(1, sizeof(struct location));
240 }
241 
242 void
243 yyerror(const char *msg, ...)
244 {
245 	va_list ap;
246 
247 	goterror = 1;
248 
249 	va_start(ap, msg);
250 	fprintf(stderr, "%s:%d: ", config_path, yylineno);
251 	vfprintf(stderr, msg, ap);
252 	fprintf(stderr, "\n");
253 	va_end(ap);
254 }
255 
256 int
257 parse_portno(const char *p)
258 {
259 	const char *errstr;
260 	int n;
261 
262 	n = strtonum(p, 0, UINT16_MAX, &errstr);
263 	if (errstr != NULL)
264 		yyerror("port number is %s: %s", errstr, p);
265 	return n;
266 }
267 
268 void
269 parse_conf(const char *path)
270 {
271 	config_path = path;
272 	if ((yyin = fopen(path, "r")) == NULL)
273 		err(1, "cannot open config: %s", path);
274 	yyparse();
275 	fclose(yyin);
276 
277 	if (goterror)
278 		exit(1);
279 
280 	if (TAILQ_FIRST(&hosts)->domain == NULL)
281 		errx(1, "no vhost defined in %s", path);
282 }
283 
284 char *
285 ensure_absolute_path(char *path)
286 {
287 	if (path == NULL || *path != '/')
288 		yyerror("not an absolute path");
289 	return path;
290 }
291 
292 int
293 check_block_code(int n)
294 {
295 	if (n < 10 || n >= 70 || (n >= 20 && n <= 29))
296 		yyerror("invalid block code %d", n);
297 	return n;
298 }
299 
300 char *
301 check_block_fmt(char *fmt)
302 {
303 	char *s;
304 
305 	for (s = fmt; *s; ++s) {
306 		if (*s != '%')
307 			continue;
308 		switch (*++s) {
309 		case '%':
310 		case 'p':
311 		case 'q':
312 		case 'P':
313 		case 'N':
314 			break;
315 		default:
316 			yyerror("invalid format specifier %%%c", *s);
317 		}
318 	}
319 
320 	return fmt;
321 }
322 
323 int
324 check_strip_no(int n)
325 {
326 	if (n <= 0)
327 		yyerror("invalid strip number %d", n);
328 	return n;
329 }
330 
331 int
332 check_prefork_num(int n)
333 {
334 	if (n <= 0 || n >= PROC_MAX)
335 		yyerror("invalid prefork number %d", n);
336 	return n;
337 }
338 
339 void
340 advance_loc(void)
341 {
342 	loc = new_location();
343 	TAILQ_INSERT_TAIL(&host->locations, loc, locations);
344 }