1 #!/usr/bin/env perl
2 #
3 # mkindex was written by Omar Polo <op@openbsd.org> and is placed in
4 # the public domain.  The author hereby disclaims copyright to this
5 # source code.
6 
7 use open ":std", ":encoding(UTF-8)";
8 use utf8;
9 use strict;
10 use warnings;
11 use v5.32;
12 
13 use OpenBSD::Pledge;
14 use OpenBSD::Unveil;
15 
16 use lib ".";
17 use GotMArc qw(parse san initpage endpage index_header thread_header);
18 
19 my $outdir = $ENV{'OUTDIR'};
20 die 'Set $OUTDIR' unless defined $outdir;
21 
22 my $tfh; # thread file handle
23 my $pfh; # page file handle
24 my $page = 0;
25 my @pages;
26 my $from_day;
27 my $to_day;
28 my $threads_seen = 0;
29 my $last_level = 0;
30 my $threads = 0;
31 my $threads_per_page = 100;
32 
33 sub maxs {
34 	my ($a, $b) = @_;
35 	return $a unless defined $b;
36 	return $a gt $b ? $a : $b;
37 }
38 
39 sub mins {
40 	my ($a, $b) = @_;
41 	return $a unless defined $b;
42 	return $a lt $b ? $a : $b;
43 }
44 
45 sub pagename {
46 	my $i = shift;
47 	return $i == 1 && "index.html" || "$i.html";
48 }
49 
50 sub endfile {
51 	say $pfh '</ul></div>';
52 	close($pfh);
53 	push @pages, "$from_day - $to_day";
54 }
55 
56 sub nextfile {
57 	endfile if defined $pfh;
58 	$page += 1;
59 	my $path = pagename($page);
60 
61 	# XXX: mkstemp would be better...
62 	open($pfh, '>', "/tmp/$path")
63 	    or die "can't open $path: $!";
64 	say $pfh "<div class='thread'><ul>";
65 }
66 
67 sub nav {
68 	my ($pfh, $n) = @_;
69 	my ($first, $last) = (pagename(1), pagename($page));
70 	my ($next, $prev) = (pagename($n+1), pagename($n-1));
71 
72 	say $pfh "<nav>";
73 	say $pfh "<a href='$first'>First</a>" if $n > 2;
74 	say $pfh "<a href='$prev'>Prev</a>" if $n > 1;
75 	say $pfh "<a href='$next'>Next</a>" if $n < $page;
76 	say $pfh "<a href='$last'>Last</a>" if $n < $page - 1;
77 	say $pfh "</nav>";
78 }
79 
80 sub copyfrom {
81 	my ($path, $fh) = @_;
82 
83 	# there are probably faster ways to do this like File::Copy,
84 	# but it bypasses the bufio cache...
85 	open(my $pfh, '<', $path) or die "can't open $path: $!";
86 	print $fh $_ while (<$pfh>);
87 }
88 
89 sub renderpages {
90 	close($pfh);
91 
92 	for (my $i = 1; $i <= $page; $i++) {
93 		my $name = pagename($i);
94 		my $path = "/tmp/$name";
95 		my $dest = "$outdir/$name";
96 
97 		open(my $pfh, '>', $dest)
98 		    or die "can't open $dest for writing: $!";
99 
100 		my $title = "Game of Trees Mail Archive | page $i";
101 		my $subtitle = $pages[$i-1];
102 
103 		initpage($pfh, $title);
104 		index_header $pfh, $i, $subtitle;
105 		say $pfh "<main>";
106 
107 		nav $pfh, $i if $page > 1;
108 		copyfrom($path, $pfh);
109 		nav $pfh, $i if $page > 1;
110 
111 		say $pfh "</main>";
112 		endpage($pfh);
113 
114 		close($pfh);
115 		unlink $path;
116 	}
117 }
118 
119 sub endthread {
120 	say $tfh "</ul></li>" x $last_level;
121 	say $tfh "</ul>\n</div>\n";
122 	endpage($tfh);
123 	close($tfh);
124 
125 	$last_level = 0;
126 }
127 
128 sub nextthread {
129 	endthread if defined $tfh;
130 	my ($mid, $subj) = @_;
131 	my $dest = "$outdir/thread/$mid.html";
132 	open($tfh, '>', $dest) or die "can't open $dest: $!";
133 	initpage($tfh, $subj);
134 	thread_header $tfh, undef, undef, ["Thread: $subj"];
135 	print $tfh "<div class='thread'><ul class='mails'>\n";
136 }
137 
138 sub entry {
139 	my ($fh, $type, $mid, $date, $from, $subj) = @_;
140 	print $fh "<li id='$mid' class='mail'>";
141 	print $fh "<p class='mail-meta'>";
142 	print $fh "<time>$date</time> ";
143 	print $fh "<span class='from'>$from</span>";
144 	print $fh "<span class='colon'>:</span>";
145 	print $fh "</p>";
146 	print $fh "<p class='subject'>";
147 	print $fh "<a href='/$type/$mid.html'>$subj</a>";
148 	print $fh "</p>";
149 	print $fh "</li>\n";
150 }
151 
152 sub thread_entry {
153 	my ($fh, $mid, $level, $date, $from, $subj) = @_;
154 
155 	say $fh "</ul>\n</li>" x ($last_level - $level) if $last_level > $level;
156 	say $fh "<li>\n<ul>" if $last_level < $level;
157 
158 	entry $fh, "mail", $mid, $date, $from, $subj;
159 }
160 
161 unveil($outdir, "rwc") or die "unveil $outdir: $!";
162 unveil(".", "r") or die "unveil .: $!";
163 unveil("/tmp", "rwc") or die "unveil /tmp: $!";
164 
165 pledge("stdio rpath wpath cpath") or die "pledge: $!";
166 
167 nextfile;
168 
169 while (<>) {
170 	my ($level, $fname, $mid, $date, $from, $subj) = parse;
171 
172 	if ($level == 0) {
173 		nextthread $mid, $subj;
174 
175 		$threads++;
176 		if ($threads > $threads_per_page) {
177 			nextfile;
178 			$threads = 0;
179 			$to_day = undef;
180 			$from_day = undef;
181 		}
182 
183 		my $day = $date =~ s/ .*//r;
184 		$to_day = mins $day, $to_day;
185 		$from_day = maxs $day, $from_day;
186 
187 		entry $pfh, "thread", $mid, $date, $from, $subj;
188 	}
189 
190 	thread_entry $tfh, $mid, $level, $date, $from, $subj;
191 	$last_level = $level;
192 	$threads_seen = 1;
193 }
194 
195 endfile;
196 endthread if $threads_seen;
197 renderpages;