1 #!/usr/bin/env perl
2 
3 use open ":std", ":encoding(UTF-8)";
4 use utf8;
5 use strict;
6 use warnings;
7 use v5.32;
8 
9 use OpenBSD::Pledge;
10 use OpenBSD::Unveil;
11 
12 use lib ".";
13 use GotMArc qw(san $logo mid2path initpage endpage);
14 
15 my $outdir = $ENV{'OUTDIR'};
16 die 'Set $OUTDIR' unless defined $outdir;
17 
18 unveil("/usr/local/bin/mshow", "rx") or die "unveil mshow: $!";
19 unveil($outdir, "rwc") or die "unveil $outdir: $!";
20 unveil(".", "rwc") or die "unveil .: $!";
21 pledge("stdio rpath wpath cpath proc exec") or die "pledge: $!";
22 
23 my $tid;
24 while (<>) {
25 	chomp;
26 
27 	m/^([^ ]+) <([^>]+)> (.+)(\d{4}-\d{2}-\d{2} \d{2}:\d{2}) <([^>]+)> (.*)/;
28 	die "can't parse: $_" unless defined $1;
29 	my ($fname, $mid, $indent, $date, $from, $subj) = ($1, $2, $3, $4, $5, $6);
30 	$subj = san($subj);
31 	$subj =~ s/\s+/ /g;
32 	$subj =~ s/\s+$//;
33 
34 	$mid = mid2path($mid);
35 
36 	my $level = length($indent) - 1;
37 	$level = 10 if $indent =~ m/\.\.\d{2}\.\./;
38 
39 	$tid = $mid if $level == 0;
40 	die "unknown tid" unless defined $tid;
41 
42 	my $dest = "$outdir/mail/$mid.html";
43 	next if -f $dest;
44 
45 	open(my $fh, '>', "$dest") or die "can't open $dest: $!";
46 
47 	initpage $fh, $subj;
48 
49 	# prepare the parts listing file
50 	$ENV{'MESSAGE_ID'} = $mid;
51 	open(my $parts, '+>', "parts.html")
52 	    or die "can't create parts.html: $!";
53 
54 	open(my $mshow, "-|", "mshow", "-nNA", "text/plain", $fname)
55 	    or die "can't exec mshow: $!";
56 
57 	open(my $text, '>', "$outdir/text/$mid.txt")
58 	    or die "can't open $outdir/text/$mid.txt: $!";
59 
60 	print $fh "<header class='mail-header'>";
61 	print $fh "<p>";
62 	print $fh $logo;
63 	print $fh "<a href='/'>Index</a>";
64 	print $fh " | ";
65 	print $fh "<a href='/thread/$tid.html#$mid'>Thread</a>";
66 	print $fh "</p>";
67 	print $fh "<dl>";
68 	while (<$mshow>) {
69 		chomp;
70 		say $text $_;
71 		last if /^$/;
72 		my ($h, $v) = m/^([-A-Za-z]+): (.*)/;
73 		die "bogus line? $fname : $_" unless (defined $h and defined $v);
74 
75 		# drop the (1 day ago) string
76 		$v =~ s/\(.*\)//g if ($h eq "Date");
77 
78 		print $fh "<dt>", san($h), ":</dt>";
79 		print $fh "<dd>", san($v), "</dd>";
80 	}
81 	print $fh "</dl>";
82 	print $fh "<p>Download raw <a href='/text/$mid.txt'>body</a>.</p>";
83 	print $fh "</header>";
84 
85 	print $fh "<pre>";
86 	while (<$mshow>) {
87 		print $text $_;
88 		print $fh san($_);
89 	}
90 	print $fh "</pre>";
91 
92 	# generate the listing for the exported parts
93 	my $part_seen = 0;
94 	while (<$parts>) {
95 		if (!$part_seen) {
96 			$part_seen = 1;
97 			say $fh "<ul class='parts'>";
98 		}
99 		print $fh $_;
100 	}
101 	say $fh "</ul>" if $part_seen;
102 
103 	endpage $fh;
104 
105 	close($text);
106 	close($mshow);
107 	close($parts);
108 	close($fh);
109 }
110 
111 unlink "parts.html";