1 #!/usr/bin/env perl
2 #
3 # mkindex was written by Omar Polo <op@openbsd.org> and is placed in
4 # the public domain.  The author hereby disclaims copyright to this
5 # source code.
6 
7 use open ":std", ":encoding(UTF-8)";
8 use utf8;
9 use strict;
10 use warnings;
11 use v5.32;
12 use File::Temp qw(tempfile);
13 
14 use OpenBSD::Pledge;
15 use OpenBSD::Unveil;
16 
17 use lib ".";
18 use GotMArc qw(parse san urlencode initpage endpage index_header
19     search thread_header threntry);
20 
21 my $outdir = $ENV{'OUTDIR'};
22 die 'Set $OUTDIR' unless defined $outdir;
23 
24 my $tfh; # thread file handle
25 my $pfh; # page file handle
26 my $page = 0;
27 my @pages;
28 my @files;
29 my $from_day;
30 my $to_day;
31 my $threads_seen = 0;
32 
33 my $last_level = 0;
34 my $last_tid;
35 my $last_date;
36 my $last_from;
37 my $last_subj;
38 
39 my $threads = 0;
40 my $threads_per_page = 100;
41 
42 sub maxs {
43 	my ($a, $b) = @_;
44 	return $a unless defined $b;
45 	return $a gt $b ? $a : $b;
46 }
47 
48 sub mins {
49 	my ($a, $b) = @_;
50 	return $a unless defined $b;
51 	return $a lt $b ? $a : $b;
52 }
53 
54 sub pagename {
55 	my $i = shift;
56 	return $i == 1 && "index.html" || "$i.html";
57 }
58 
59 sub endfile {
60 	say $pfh '</ul></div>';
61 	close($pfh);
62 	push @pages, "$from_day - $to_day";
63 }
64 
65 sub nextfile {
66 	endfile if defined $pfh;
67 	$page += 1;
68 
69 	my $path;
70 	($pfh, $path) = tempfile "/tmp/gotmarc.index.XXXXXXXXXX";
71 	binmode($pfh, ':utf8');
72 	push @files, $path;
73 	say $pfh "<div class='thread'><ul>";
74 }
75 
76 sub nav {
77 	my ($pfh, $n) = @_;
78 	my ($first, $last) = (pagename(1), pagename($page));
79 	my ($next, $prev) = (pagename($n+1), pagename($n-1));
80 
81 	say $pfh "<nav>";
82 	say $pfh "<a href='$first'>First</a>" if $n > 2;
83 	say $pfh "<a href='$prev'>Prev</a>" if $n > 1;
84 	say $pfh "<a href='$next'>Next</a>" if $n < $page;
85 	say $pfh "<a href='$last'>Last</a>" if $n < $page - 1;
86 	say $pfh "</nav>";
87 }
88 
89 sub copyfrom {
90 	my ($path, $fh) = @_;
91 
92 	# there are probably faster ways to do this like File::Copy,
93 	# but it bypasses the bufio cache...
94 	open(my $pfh, '<', $path) or die "can't open $path: $!";
95 	print $fh $_ while <$pfh>;
96 }
97 
98 sub renderpages {
99 	close($pfh);
100 
101 	for (my $i = 1; $i <= $page; $i++) {
102 		my $name = pagename($i);
103 		my $path = shift @files;
104 		my $dest = "$outdir/$name";
105 
106 		open(my $pfh, '>', $dest)
107 		    or die "can't open $dest for writing: $!";
108 
109 		my $title = "Game of Trees Mail Archive | page $i";
110 		my $subtitle = $pages[$i-1];
111 
112 		initpage($pfh, $title);
113 		index_header $pfh, $i, $subtitle;
114 		say $pfh "<main>";
115 
116 		nav $pfh, $i if $page > 1;
117 		search $pfh;
118 		copyfrom($path, $pfh);
119 		nav $pfh, $i if $page > 1;
120 
121 		say $pfh "</main>";
122 		endpage($pfh);
123 
124 		close($pfh);
125 		unlink $path;
126 	}
127 }
128 
129 sub endthread {
130 	say $tfh "</ul></li>" x $last_level;
131 	say $tfh "</ul>\n</div>\n";
132 	endpage($tfh);
133 	close($tfh);
134 
135 	$last_level = 0;
136 }
137 
138 sub nextthread {
139 	endthread if defined $tfh;
140 	my ($mid, $subj) = @_;
141 	my $dest = "$outdir/thread/$mid.html";
142 	open($tfh, '>', $dest) or die "can't open $dest: $!";
143 	initpage($tfh, $subj);
144 	thread_header $tfh, ["Thread: $subj"];
145 	print $tfh "<div class='thread'><ul class='mails'>\n";
146 }
147 
148 sub index_entry {
149 	my ($fh, $mid, $date, $from, $subj) = @_;
150 
151 	# synthetic mail hash
152 	my $mail = {
153 		mid => $mid,
154 		level => 0,
155 		date => $date,
156 		from => $from,
157 		subj => $subj,
158 	};
159 
160 	threntry $fh, "thread", 0, 0, $mail;
161 }
162 
163 unveil($outdir, "rwc") or die "unveil $outdir: $!";
164 
165 # can't use tmppath because File::Temp checks wether /tmp exists.
166 unveil("/tmp", "rwc") or die "unveil /tmp: $!";
167 
168 # fattr for File::Temp
169 pledge("stdio rpath wpath cpath fattr") or die "pledge: $!";
170 
171 nextfile;
172 
173 while (<>) {
174 	my $mail = parse $_;
175 
176 	if ($mail->{level} == 0) {
177 		nextthread $mail->{mid}, $mail->{subj};
178 
179 		$threads++;
180 		if ($threads > $threads_per_page) {
181 			nextfile;
182 			$threads = 0;
183 			$to_day = undef;
184 			$from_day = undef;
185 		}
186 
187 		my $day = $mail->{date} =~ s/ .*//r;
188 		$to_day = mins $day, $to_day;
189 		$from_day = maxs $day, $from_day;
190 	}
191 
192 	$last_level = threntry $tfh, "mail", 0, $last_level, $mail;
193 	$threads_seen = 1;
194 
195 	index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
196 	    if defined $last_tid && $mail->{level} == 0;
197 
198 	# `gt' on dates works because the format used allow for
199 	# lexicographic comparisons.
200 	if ($mail->{level} == 0 || $mail->{date} gt $last_date) {
201 		$last_date = $mail->{date};
202 		$last_from = $mail->{from};
203 	}
204 
205 	if ($mail->{level} == 0) {
206 		$last_tid = $mail->{mid};
207 		$last_subj = $mail->{subj};
208 	}
209 }
210 
211 index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
212     if defined $last_tid;
213 
214 endfile;
215 endthread if $threads_seen;
216 renderpages;