1 /* -*- mode: fundamental; indent-tabs-mode: t; -*- */
2 %{
3 
4 /*
5  * Copyright (c) 2021 Omar Polo <op@omarpolo.com>
6  *
7  * Permission to use, copy, modify, and distribute this software for any
8  * purpose with or without fee is hereby granted, provided that the above
9  * copyright notice and this permission notice appear in all copies.
10  *
11  * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
12  * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
13  * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
14  * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
15  * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
16  * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
17  * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
18  */
19 
20 #include <err.h>
21 #include <stdarg.h>
22 #include <stdio.h>
23 #include <string.h>
24 
25 #include "gmid.h"
26 
27 /*
28  * #define YYDEBUG 1
29  * int yydebug = 1;
30  */
31 
32 struct vhost *host;
33 size_t ihost;
34 struct location *loc;
35 size_t iloc;
36 
37 int goterror = 0;
38 const char *config_path;
39 
40 void		 yyerror(const char*, ...);
41 int		 parse_portno(const char*);
42 void		 parse_conf(const char*);
43 char		*ensure_absolute_path(char*);
44 int		 check_block_code(int);
45 char		*check_block_fmt(char*);
46 int		 check_strip_no(int);
47 
48 %}
49 
50 /* for bison: */
51 /* %define parse.error verbose */
52 
53 %union {
54 	char		*str;
55 	int		 num;
56 }
57 
58 %token TIPV6 TPORT TPROTOCOLS TMIME TDEFAULT TTYPE
59 %token TCHROOT TUSER TSERVER
60 %token TLOCATION TCERT TKEY TROOT TCGI TLANG TINDEX TAUTO
61 %token TSTRIP TBLOCK TRETURN TENTRYPOINT
62 %token TERR
63 
64 %token <str>	TSTRING
65 %token <num>	TNUM
66 %token <num>	TBOOL
67 
68 %%
69 
70 conf		: options vhosts ;
71 
72 options		: /* empty */
73 		| options option
74 		;
75 
76 option		: TIPV6 TBOOL		{ conf.ipv6 = $2; }
77 		| TPORT TNUM		{ conf.port = $2; }
78 		| TPROTOCOLS TSTRING {
79 			if (tls_config_parse_protocols(&conf.protos, $2) == -1)
80 				errx(1, "invalid protocols string \"%s\"", $2);
81 		}
82 		| TMIME TSTRING TSTRING	{ add_mime(&conf.mime, $2, $3); }
83 		| TCHROOT TSTRING	{ conf.chroot = $2; }
84 		| TUSER TSTRING		{ conf.user = $2; }
85 		;
86 
87 vhosts		: /* empty */
88 		| vhosts vhost
89 		;
90 
91 vhost		: TSERVER TSTRING '{' servopts locations '}' {
92 			host->locations[0].match = xstrdup("*");
93 			host->domain = $2;
94 
95 			if (strstr($2, "xn--") != NULL) {
96 				warnx("%s:%d \"%s\" looks like punycode: "
97 				    "you should use the decoded hostname.",
98 				    config_path, yylineno, $2);
99 			}
100 
101 			if (host->cert == NULL || host->key == NULL ||
102 			    host->dir == NULL)
103 				errx(1, "invalid vhost definition: %s", $2);
104 
105 			if (++ihost == HOSTSLEN)
106 				errx(1, "too much vhosts defined");
107 
108 			host++;
109 			loc = &host->locations[0];
110 			iloc = 0;
111 		}
112 		| error '}'		{ yyerror("error in server directive"); }
113 		;
114 
115 servopts	: /* empty */
116 		| servopts servopt
117 		;
118 
119 servopt		: TCERT TSTRING		{ host->cert = ensure_absolute_path($2); }
120 		| TKEY TSTRING		{ host->key  = ensure_absolute_path($2); }
121 		| TROOT TSTRING		{ host->dir  = ensure_absolute_path($2); }
122 		| TCGI TSTRING		{
123 			/* drop the starting '/', if any */
124 			if (*$2 == '/')
125 				memmove($2, $2+1, strlen($2));
126 			host->cgi = $2;
127 		}
128 		| TENTRYPOINT TSTRING {
129 			if (host->entrypoint != NULL)
130 				yyerror("`entrypoint' specified more than once");
131 			while (*$2 == '/')
132 				memmove($2, $2+1, strlen($2));
133 			host->entrypoint = $2;
134 		}
135 		| locopt
136 		;
137 
138 locations	: /* empty */
139 		| locations location
140 		;
141 
142 location	: TLOCATION TSTRING '{' locopts '}' {
143 			loc->match = $2;
144 			if (++iloc == LOCLEN)
145 				errx(1, "too much location rules defined");
146 			loc++;
147 		}
148 		| error '}'
149 		;
150 
151 locopts		: /* empty */
152 		| locopts locopt
153 		;
154 
155 locopt		: TDEFAULT TTYPE TSTRING {
156 			if (loc->default_mime != NULL)
157 				yyerror("`default type' specified more than once");
158 			loc->default_mime = $3;
159 		}
160 		| TLANG TSTRING {
161 			if (loc->lang != NULL)
162 				yyerror("`lang' specified more than once");
163 			loc->lang = $2;
164 		}
165 		| TINDEX TSTRING {
166 			if (loc->index != NULL)
167 				yyerror("`index' specified more than once");
168 			loc->index = $2;
169 		}
170 		| TAUTO TINDEX TBOOL	{ loc->auto_index = $3 ? 1 : -1; }
171 		| TBLOCK TRETURN TNUM TSTRING {
172 			if (loc->block_fmt != NULL)
173 				yyerror("`block' rule specified more than once");
174 			loc->block_fmt = check_block_fmt($4);
175 			loc->block_code = check_block_code($3);
176 		}
177 		| TBLOCK TRETURN TNUM {
178 			if (loc->block_fmt != NULL)
179 				yyerror("`block' rule specified more than once");
180 			loc->block_fmt = xstrdup("temporary failure");
181 			loc->block_code = check_block_code($3);
182 			if ($3 >= 30 && $3 < 40)
183 				yyerror("missing `meta' for block return %d", $3);
184 		}
185 		| TBLOCK {
186 			if (loc->block_fmt != NULL)
187 				yyerror("`block' rule specified more than once");
188 			loc->block_fmt = xstrdup("temporary failure");
189 			loc->block_code = 40;
190 		}
191 		| TSTRIP TNUM		{ loc->strip = check_strip_no($2); }
192 		;
193 
194 %%
195 
196 void
197 yyerror(const char *msg, ...)
198 {
199 	va_list ap;
200 
201 	goterror = 1;
202 
203 	va_start(ap, msg);
204 	fprintf(stderr, "%s:%d: ", config_path, yylineno);
205 	vfprintf(stderr, msg, ap);
206 	va_end(ap);
207 }
208 
209 int
210 parse_portno(const char *p)
211 {
212 	const char *errstr;
213 	int n;
214 
215 	n = strtonum(p, 0, UINT16_MAX, &errstr);
216 	if (errstr != NULL)
217 		errx(1, "port number is %s: %s", errstr, p);
218 	return n;
219 }
220 
221 void
222 parse_conf(const char *path)
223 {
224 	host = &hosts[0];
225 	ihost = 0;
226 	loc = &hosts[0].locations[0];
227 	iloc = 0;
228 
229 	config_path = path;
230 	if ((yyin = fopen(path, "r")) == NULL)
231 		fatal("cannot open config %s", path);
232 	yyparse();
233 	fclose(yyin);
234 
235 	if (goterror)
236 		exit(1);
237 }
238 
239 char *
240 ensure_absolute_path(char *path)
241 {
242 	if (path == NULL || *path != '/')
243 		yyerror("not an absolute path");
244 	return path;
245 }
246 
247 int
248 check_block_code(int n)
249 {
250 	if (n < 10 || n >= 70 || (n >= 20 && n <= 29))
251 		yyerror("invalid block code %d", n);
252 	return n;
253 }
254 
255 char *
256 check_block_fmt(char *fmt)
257 {
258 	char *s;
259 
260 	for (s = fmt; *s; ++s) {
261 		if (*s != '%')
262 			continue;
263 		switch (*++s) {
264 		case '%':
265 		case 'p':
266 		case 'q':
267 		case 'P':
268 		case 'N':
269 			break;
270 		default:
271 			yyerror("invalid format specifier %%%c", *s);
272 		}
273 	}
274 
275 	return fmt;
276 }
277 
278 int
279 check_strip_no(int n)
280 {
281 	if (n <= 0)
282 		yyerror("invalid strip number %d", n);
283 	return n;
284 }