1 /* -*- mode: fundamental; indent-tabs-mode: t; -*- */
2 %{
3 
4 /*
5  * Copyright (c) 2021 Omar Polo <op@omarpolo.com>
6  *
7  * Permission to use, copy, modify, and distribute this software for any
8  * purpose with or without fee is hereby granted, provided that the above
9  * copyright notice and this permission notice appear in all copies.
10  *
11  * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
12  * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
13  * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
14  * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
15  * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
16  * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
17  * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
18  */
19 
20 #include <err.h>
21 #include <stdarg.h>
22 #include <stdio.h>
23 #include <string.h>
24 
25 #include "gmid.h"
26 
27 /*
28  * #define YYDEBUG 1
29  * int yydebug = 1;
30  */
31 
32 struct vhost *host;
33 size_t ihost;
34 struct location *loc;
35 size_t iloc;
36 
37 int goterror = 0;
38 
39 void		 yyerror(const char*, ...);
40 int		 parse_portno(const char*);
41 void		 parse_conf(const char*);
42 char		*ensure_absolute_path(char*);
43 int		 check_block_code(int);
44 char		*check_block_fmt(char*);
45 int		 check_strip_no(int);
46 int		 check_prefork_num(int);
47 
48 %}
49 
50 /* for bison: */
51 /* %define parse.error verbose */
52 
53 %union {
54 	char		*str;
55 	int		 num;
56 }
57 
58 %token TIPV6 TPORT TPROTOCOLS TMIME TDEFAULT TTYPE
59 %token TCHROOT TUSER TSERVER TPREFORK
60 %token TLOCATION TCERT TKEY TROOT TCGI TLANG TINDEX TAUTO
61 %token TSTRIP TBLOCK TRETURN TENTRYPOINT
62 %token TERR
63 
64 %token <str>	TSTRING
65 %token <num>	TNUM
66 %token <num>	TBOOL
67 
68 %%
69 
70 conf		: options vhosts ;
71 
72 options		: /* empty */
73 		| options option
74 		;
75 
76 option		: TIPV6 TBOOL		{ conf.ipv6 = $2; }
77 		| TPORT TNUM		{ conf.port = $2; }
78 		| TPROTOCOLS TSTRING {
79 			if (tls_config_parse_protocols(&conf.protos, $2) == -1)
80 				errx(1, "invalid protocols string \"%s\"", $2);
81 		}
82 		| TMIME TSTRING TSTRING	{ add_mime(&conf.mime, $2, $3); }
83 		| TCHROOT TSTRING	{ conf.chroot = $2; }
84 		| TUSER TSTRING		{ conf.user = $2; }
85 		| TPREFORK TNUM		{ conf.prefork = check_prefork_num($2); }
86 		;
87 
88 vhosts		: /* empty */
89 		| vhosts vhost
90 		;
91 
92 vhost		: TSERVER TSTRING '{' servopts locations '}' {
93 			host->locations[0].match = xstrdup("*");
94 			host->domain = $2;
95 
96 			if (strstr($2, "xn--") != NULL) {
97 				warnx("%s:%d \"%s\" looks like punycode: "
98 				    "you should use the decoded hostname.",
99 				    config_path, yylineno, $2);
100 			}
101 
102 			if (host->cert == NULL || host->key == NULL ||
103 			    host->dir == NULL)
104 				errx(1, "invalid vhost definition: %s", $2);
105 
106 			if (++ihost == HOSTSLEN)
107 				errx(1, "too much vhosts defined");
108 
109 			host++;
110 			loc = &host->locations[0];
111 			iloc = 0;
112 		}
113 		| error '}'		{ yyerror("error in server directive"); }
114 		;
115 
116 servopts	: /* empty */
117 		| servopts servopt
118 		;
119 
120 servopt		: TCERT TSTRING		{ host->cert = ensure_absolute_path($2); }
121 		| TKEY TSTRING		{ host->key  = ensure_absolute_path($2); }
122 		| TROOT TSTRING		{ host->dir  = ensure_absolute_path($2); }
123 		| TCGI TSTRING		{
124 			/* drop the starting '/', if any */
125 			if (*$2 == '/')
126 				memmove($2, $2+1, strlen($2));
127 			host->cgi = $2;
128 		}
129 		| TENTRYPOINT TSTRING {
130 			if (host->entrypoint != NULL)
131 				yyerror("`entrypoint' specified more than once");
132 			while (*$2 == '/')
133 				memmove($2, $2+1, strlen($2));
134 			host->entrypoint = $2;
135 		}
136 		| locopt
137 		;
138 
139 locations	: /* empty */
140 		| locations location
141 		;
142 
143 location	: TLOCATION TSTRING '{' locopts '}' {
144 			loc->match = $2;
145 			if (++iloc == LOCLEN)
146 				errx(1, "too much location rules defined");
147 			loc++;
148 		}
149 		| error '}'
150 		;
151 
152 locopts		: /* empty */
153 		| locopts locopt
154 		;
155 
156 locopt		: TDEFAULT TTYPE TSTRING {
157 			if (loc->default_mime != NULL)
158 				yyerror("`default type' specified more than once");
159 			loc->default_mime = $3;
160 		}
161 		| TLANG TSTRING {
162 			if (loc->lang != NULL)
163 				yyerror("`lang' specified more than once");
164 			loc->lang = $2;
165 		}
166 		| TINDEX TSTRING {
167 			if (loc->index != NULL)
168 				yyerror("`index' specified more than once");
169 			loc->index = $2;
170 		}
171 		| TAUTO TINDEX TBOOL	{ loc->auto_index = $3 ? 1 : -1; }
172 		| TBLOCK TRETURN TNUM TSTRING {
173 			if (loc->block_fmt != NULL)
174 				yyerror("`block' rule specified more than once");
175 			loc->block_fmt = check_block_fmt($4);
176 			loc->block_code = check_block_code($3);
177 		}
178 		| TBLOCK TRETURN TNUM {
179 			if (loc->block_fmt != NULL)
180 				yyerror("`block' rule specified more than once");
181 			loc->block_fmt = xstrdup("temporary failure");
182 			loc->block_code = check_block_code($3);
183 			if ($3 >= 30 && $3 < 40)
184 				yyerror("missing `meta' for block return %d", $3);
185 		}
186 		| TBLOCK {
187 			if (loc->block_fmt != NULL)
188 				yyerror("`block' rule specified more than once");
189 			loc->block_fmt = xstrdup("temporary failure");
190 			loc->block_code = 40;
191 		}
192 		| TSTRIP TNUM		{ loc->strip = check_strip_no($2); }
193 		;
194 
195 %%
196 
197 void
198 yyerror(const char *msg, ...)
199 {
200 	va_list ap;
201 
202 	goterror = 1;
203 
204 	va_start(ap, msg);
205 	fprintf(stderr, "%s:%d: ", config_path, yylineno);
206 	vfprintf(stderr, msg, ap);
207 	fprintf(stderr, "\n");
208 	va_end(ap);
209 }
210 
211 int
212 parse_portno(const char *p)
213 {
214 	const char *errstr;
215 	int n;
216 
217 	n = strtonum(p, 0, UINT16_MAX, &errstr);
218 	if (errstr != NULL)
219 		errx(1, "port number is %s: %s", errstr, p);
220 	return n;
221 }
222 
223 void
224 parse_conf(const char *path)
225 {
226 	host = &hosts[0];
227 	ihost = 0;
228 	loc = &hosts[0].locations[0];
229 	iloc = 0;
230 
231 	config_path = path;
232 	if ((yyin = fopen(path, "r")) == NULL)
233 		fatal("cannot open config %s", path);
234 	yyparse();
235 	fclose(yyin);
236 
237 	if (goterror)
238 		exit(1);
239 }
240 
241 char *
242 ensure_absolute_path(char *path)
243 {
244 	if (path == NULL || *path != '/')
245 		yyerror("not an absolute path");
246 	return path;
247 }
248 
249 int
250 check_block_code(int n)
251 {
252 	if (n < 10 || n >= 70 || (n >= 20 && n <= 29))
253 		yyerror("invalid block code %d", n);
254 	return n;
255 }
256 
257 char *
258 check_block_fmt(char *fmt)
259 {
260 	char *s;
261 
262 	for (s = fmt; *s; ++s) {
263 		if (*s != '%')
264 			continue;
265 		switch (*++s) {
266 		case '%':
267 		case 'p':
268 		case 'q':
269 		case 'P':
270 		case 'N':
271 			break;
272 		default:
273 			yyerror("invalid format specifier %%%c", *s);
274 		}
275 	}
276 
277 	return fmt;
278 }
279 
280 int
281 check_strip_no(int n)
282 {
283 	if (n <= 0)
284 		yyerror("invalid strip number %d", n);
285 	return n;
286 }
287 
288 int
289 check_prefork_num(int n)
290 {
291 	if (n <= 0)
292 		yyerror("invalid prefork number %d", n);
293 	return n;
294 }