1 # GotMArc was written by Omar Polo <op@openbsd.org> and is placed in
2 # the public domain.  The author hereby disclaims copyright to this
3 # source code.
4 
5 package GotMArc;
6 use strict;
7 use warnings;
8 use v5.32;
9 use Exporter;
10 use File::Basename;
11 
12 our @ISA = qw(Exporter);
13 our @EXPORT_OK = qw(san urlencode parse initpage endpage index_header
14     thread_header threntry thrslice thrnav);
15 
16 sub san {
17 	my $str = shift;
18 	$str =~ s/&/\&amp;/g;
19 	$str =~ s/</\&lt;/g;
20 	$str =~ s/>/\&gt;/g;
21 	return $str;
22 }
23 
24 sub urlencode {
25 	my $str = shift;
26 	unless (defined($str)) {
27 		my ($pkg, $file, $line) = caller 1;
28 		die "bad $pkg / $file:$line";
29 	}
30 	$str =~ s/([^-_~.A-Za-z0-9])/sprintf("%%%2X", ord($1))/ge;
31 	return $str;
32 }
33 
34 sub ssan {
35 	my $str = shift;
36 	$str =~ s/\s+/ /g;
37 	$str =~ s/\s+$//;
38 	return san($str);
39 }
40 
41 sub parse {
42 	my $line = shift;
43 	my ($indent, $fname, $date, $from, $subj) = $line =~ m{
44 		^([^-]*)-			# the indent level
45 		([^ ]+)\s			# filename
46 		(\d{4}-\d\d-\d\d[ ]\d\d:\d\d)	# date
47 		<([^>]+)>			# from
48 		(.*)				# subject
49 	}x or die "can't parse: $line";
50 
51 	my $level = length($indent);
52 	$level = 10 if $indent =~ m/\.\.\d+\.\./;
53 
54 	$from = ssan($from);
55 	$subj = ssan($subj);
56 
57 	my ($time, $id) = split /\./, basename($fname);
58 	my $mid = "$time.$id";
59 
60 	return {level => $level, fname => $fname,
61 	    mid => $mid, date => $date, from => $from, subj => $subj};
62 }
63 
64 sub readall {
65 	my $path = shift;
66 	local $/ = undef;
67 	open my $fh, "<", $path or die "can't open $path: $!";
68 	<$fh>;
69 }
70 
71 my $small_logo = readall "logo-small.html";
72 my $hdr = readall "head.html";
73 my $foot = readall "foot.html";
74 my $idxhdr = readall "index-header.html";
75 
76 sub initpage {
77 	my ($fh, $title) = @_;
78 	say $fh $hdr =~ s/TITLE/$title/r;
79 }
80 
81 sub endpage {
82 	my $fh = shift;
83 	say $fh $foot;
84 }
85 
86 sub index_header {
87 	my ($fh, $page, $subtitle) = @_;
88 	my $html = $idxhdr =~ s/PAGE/$page/r;
89 	$html =~ s/SUBTITLE/$subtitle/;
90 	print $fh $html;
91 }
92 
93 sub thread_header {
94 	my ($fh, $e, $mail, $p, $n) = @_;
95 
96 	my @entries = @$e;
97 
98 	my $enctid = urlencode $mail->{tid} if defined $mail;
99 	my $encmid = urlencode $mail->{mid} if defined $mail;
100 
101 	print $fh "<header class='mail-header'>\n";
102 
103 	print $fh "<p>";
104 	print $fh $small_logo;
105 	print $fh "<a href='/'>Index</a>";
106 	print $fh " | <a href='/thread/$enctid.html#$encmid'>Thread</a>"
107 	    if defined $enctid;
108 	print $fh " | <a href='/search'>Search</a>";
109 	print $fh "</p>\n";
110 
111 	say $fh "<dl>";
112 	foreach my $entry (@entries) {
113 		my ($k, $v) = split /: /, $entry, 2;
114 		chomp $v;
115 		say $fh "<dt>$k:</dt><dd>$v</dd>";
116 	}
117 	say $fh "</dl>";
118 
119 	say $fh "<p>Download raw <a href='/text/$encmid.txt'>body</a>.</p>"
120 	    if defined $encmid;
121 
122 	if (defined($p) and defined($n)) {
123 		say $fh "<details>";
124 		say $fh "<summary>Thread</summary>";
125 		thrslice($fh, $mail, $p, $n);
126 		say $fh "</details>";
127 		thrnav($fh, $p, $n, $mail->{mid}, $mail->{tid});
128 	}
129 
130 	say $fh "</header>\n";
131 }
132 
133 sub threntry {
134 	my ($fh, $type, $base, $last_level, $mail, $cur) = @_;
135 	my $level = $mail->{level} - $base;
136 
137 	say $fh "</ul></li>" x ($last_level - $level) if $last_level > $level;
138 	say $fh "<li><ul>" if $last_level < $level;
139 
140 	my $encmid = urlencode $mail->{mid};
141 
142 	print $fh "<li id='$encmid' class='mail'>";
143 	print $fh "<p class='mail-meta'>";
144 	print $fh "<time>$mail->{date}</time> ";
145 	print $fh "<span class='from'>$mail->{from}</span>";
146 	print $fh "<span class='colon'>:</span>";
147 	print $fh "</p>";
148 	print $fh "<p class='subject'>";
149 
150 	my $subj = $mail->{subj};
151 	if (!defined($cur) || $mail->{mid} ne $cur->{mid}) {
152 		print $fh "<a href='/$type/$encmid.html'>$subj</a>";
153 	} else {
154 		print $fh "<span>$subj</span>";
155 	}
156 
157 	print $fh "</p>";
158 	print $fh "</li>";
159 
160 	return $level;
161 }
162 
163 sub min_level {
164 	my $l = 999;
165 	return 0 unless @_;
166 	for (@_) {
167 		$l = $_->{level} if $_->{level} < $l;
168 	}
169 	return $l;
170 }
171 
172 sub thrslice {
173 	my ($fh, $mail, $p, $n) = @_;
174 	my @prev = @{$p};
175 	my @next = @{$n};
176 	my @thread = (@prev, $mail, @next);
177 	return unless @thread;
178 	my $base = min_level @thread;
179 	my $level = 0;
180 	print $fh "<div class='thread'>";
181 	print $fh "<ul class='mails'>";
182 	$level = threntry $fh, "mail", $base, $level, $_, $mail for @thread;
183 	print $fh "</ul></li>" x $level;
184 	print $fh "</ul></div>";
185 }
186 
187 sub thrnav {
188 	my ($fh, $p, $n) = @_;
189 	my @prev = @{$p};
190 	my @next = @{$n};
191 
192 	return if !@prev && !@next;
193 	print $fh "<nav>";
194 
195 	if (@prev) {
196 		my $mail = $prev[-1];
197 		my $encmid = $mail->{mid};
198 		say $fh "<a href='/mail/$encmid.html'>Previous in thread</a>";
199 	} else {
200 		say $fh "<span>Previous in thread</span>";
201 	}
202 
203 	if (@next) {
204 		my $mail = $next[0];
205 		my $encmid = $mail->{mid};
206 		say $fh "<a href='/mail/$encmid.html'>Next in thread</a>";
207 	} else {
208 		say $fh "<span>Next in thread</span>";
209 	}
210 
211 	print $fh "</nav>";
212 }
213 
214 1;