1 /* -*- mode: fundamental; indent-tabs-mode: t; -*- */
2 %{
3 
4 /*
5  * Copyright (c) 2021 Omar Polo <op@omarpolo.com>
6  *
7  * Permission to use, copy, modify, and distribute this software for any
8  * purpose with or without fee is hereby granted, provided that the above
9  * copyright notice and this permission notice appear in all copies.
10  *
11  * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
12  * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
13  * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
14  * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
15  * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
16  * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
17  * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
18  */
19 
20 #include <errno.h>
21 #include <stdarg.h>
22 #include <stdio.h>
23 #include <string.h>
24 
25 #include "gmid.h"
26 
27 /*
28  * #define YYDEBUG 1
29  * int yydebug = 1;
30  */
31 
32 struct vhost *host;
33 struct location *loc;
34 
35 int goterror = 0;
36 
37 static struct vhost	*new_vhost(void);
38 static struct location	*new_location(void);
39 
40 void		 yyerror(const char*, ...);
41 int		 parse_portno(const char*);
42 void		 parse_conf(const char*);
43 char		*ensure_absolute_path(char*);
44 int		 check_block_code(int);
45 char		*check_block_fmt(char*);
46 int		 check_strip_no(int);
47 int		 check_prefork_num(int);
48 void		 advance_loc(void);
49 
50 %}
51 
52 /* for bison: */
53 /* %define parse.error verbose */
54 
55 %union {
56 	char		*str;
57 	int		 num;
58 }
59 
60 %token TIPV6 TPORT TPROTOCOLS TMIME TDEFAULT TTYPE
61 %token TCHROOT TUSER TSERVER TPREFORK
62 %token TLOCATION TCERT TKEY TROOT TCGI TENV TLANG TLOG TINDEX TAUTO
63 %token TSTRIP TBLOCK TRETURN TENTRYPOINT TREQUIRE TCLIENT TCA
64 %token TERR
65 
66 %token <str>	TSTRING
67 %token <num>	TNUM
68 %token <num>	TBOOL
69 
70 %%
71 
72 conf		: options vhosts ;
73 
74 options		: /* empty */
75 		| options option
76 		;
77 
78 option		: TCHROOT TSTRING	{ conf.chroot = $2; }
79 		| TIPV6 TBOOL		{ conf.ipv6 = $2; }
80 		| TMIME TSTRING TSTRING	{ add_mime(&conf.mime, $2, $3); }
81 		| TPORT TNUM		{ conf.port = $2; }
82 		| TPREFORK TNUM		{ conf.prefork = check_prefork_num($2); }
83 		| TPROTOCOLS TSTRING {
84 			if (tls_config_parse_protocols(&conf.protos, $2) == -1)
85 				yyerror("invalid protocols string \"%s\"", $2);
86 		}
87 		| TUSER TSTRING		{ conf.user = $2; }
88 		;
89 
90 vhosts		: /* empty */
91 		| vhosts vhost
92 		;
93 
94 vhost		: TSERVER TSTRING {
95 			host = new_vhost();
96 			TAILQ_INSERT_HEAD(&hosts, host, vhosts);
97 
98 			loc = new_location();
99 			TAILQ_INSERT_HEAD(&host->locations, loc, locations);
100 
101 			loc->match = xstrdup("*");
102 			host->domain = $2;
103 
104 			if (strstr($2, "xn--") != NULL) {
105 				warnx("%s:%d \"%s\" looks like punycode: "
106 				    "you should use the decoded hostname.",
107 				    config_path, yylineno, $2);
108 			}
109 		} '{' servopts locations '}' {
110 
111 			if (host->cert == NULL || host->key == NULL ||
112 			    host->dir == NULL)
113 				yyerror("invalid vhost definition: %s", $2);
114 		}
115 		| error '}'		{ yyerror("error in server directive"); }
116 		;
117 
118 servopts	: /* empty */
119 		| servopts servopt
120 		;
121 
122 servopt		: TCERT TSTRING		{ host->cert = ensure_absolute_path($2); }
123 		| TCGI TSTRING		{
124 			/* drop the starting '/', if any */
125 			if (*$2 == '/')
126 				memmove($2, $2+1, strlen($2));
127 			host->cgi = $2;
128 		}
129 		| TENTRYPOINT TSTRING {
130 			if (host->entrypoint != NULL)
131 				yyerror("`entrypoint' specified more than once");
132 			while (*$2 == '/')
133 				memmove($2, $2+1, strlen($2));
134 			host->entrypoint = $2;
135 		}
136 		| TENV TSTRING TSTRING {
137 			struct envlist *e;
138 
139 			e = xcalloc(1, sizeof(*e));
140 			e->name = $2;
141 			e->value = $3;
142 			if (TAILQ_EMPTY(&host->env))
143 				TAILQ_INSERT_HEAD(&host->env, e, envs);
144 			else
145 				TAILQ_INSERT_TAIL(&host->env, e, envs);
146 		}
147 		| TKEY TSTRING		{ host->key  = ensure_absolute_path($2); }
148 		| TROOT TSTRING		{ host->dir  = ensure_absolute_path($2); }
149 		| locopt
150 		;
151 
152 locations	: /* empty */
153 		| locations location
154 		;
155 
156 location	: TLOCATION { advance_loc(); } TSTRING '{' locopts '}'	{
157 			/* drop the starting '/' if any */
158 			if (*$3 == '/')
159 				memmove($3, $3+1, strlen($3));
160 			loc->match = $3;
161 		}
162 		| error '}'
163 		;
164 
165 locopts		: /* empty */
166 		| locopts locopt
167 		;
168 
169 locopt		: TAUTO TINDEX TBOOL	{ loc->auto_index = $3 ? 1 : -1; }
170 		| TBLOCK TRETURN TNUM TSTRING {
171 			if (loc->block_fmt != NULL)
172 				yyerror("`block' rule specified more than once");
173 			loc->block_fmt = check_block_fmt($4);
174 			loc->block_code = check_block_code($3);
175 		}
176 		| TBLOCK TRETURN TNUM {
177 			if (loc->block_fmt != NULL)
178 				yyerror("`block' rule specified more than once");
179 			loc->block_fmt = xstrdup("temporary failure");
180 			loc->block_code = check_block_code($3);
181 			if ($3 >= 30 && $3 < 40)
182 				yyerror("missing `meta' for block return %d", $3);
183 		}
184 		| TBLOCK {
185 			if (loc->block_fmt != NULL)
186 				yyerror("`block' rule specified more than once");
187 			loc->block_fmt = xstrdup("temporary failure");
188 			loc->block_code = 40;
189 		}
190 		| TDEFAULT TTYPE TSTRING {
191 			if (loc->default_mime != NULL)
192 				yyerror("`default type' specified more than once");
193 			loc->default_mime = $3;
194 		}
195 		| TINDEX TSTRING {
196 			if (loc->index != NULL)
197 				yyerror("`index' specified more than once");
198 			loc->index = $2;
199 		}
200 		| TLANG TSTRING {
201 			if (loc->lang != NULL)
202 				yyerror("`lang' specified more than once");
203 			loc->lang = $2;
204 		}
205 		| TLOG TBOOL	{ loc->disable_log = !$2; }
206 		| TREQUIRE TCLIENT TCA TSTRING {
207 			if (loc->reqca != NULL)
208 				yyerror("`require client ca' specified more than once");
209 			if (*$4 != '/')
210 				yyerror("path to certificate must be absolute: %s", $4);
211 			if ((loc->reqca = load_ca($4)) == NULL)
212 				yyerror("couldn't load ca cert: %s", $4);
213 			free($4);
214 		}
215 		| TSTRIP TNUM		{ loc->strip = check_strip_no($2); }
216 		;
217 
218 %%
219 
220 static struct vhost *
221 new_vhost(void)
222 {
223 	return xcalloc(1, sizeof(struct vhost));
224 }
225 
226 static struct location *
227 new_location(void)
228 {
229 	return xcalloc(1, sizeof(struct location));
230 }
231 
232 void
233 yyerror(const char *msg, ...)
234 {
235 	va_list ap;
236 
237 	goterror = 1;
238 
239 	va_start(ap, msg);
240 	fprintf(stderr, "%s:%d: ", config_path, yylineno);
241 	vfprintf(stderr, msg, ap);
242 	fprintf(stderr, "\n");
243 	va_end(ap);
244 }
245 
246 int
247 parse_portno(const char *p)
248 {
249 	const char *errstr;
250 	int n;
251 
252 	n = strtonum(p, 0, UINT16_MAX, &errstr);
253 	if (errstr != NULL)
254 		yyerror("port number is %s: %s", errstr, p);
255 	return n;
256 }
257 
258 void
259 parse_conf(const char *path)
260 {
261 	config_path = path;
262 	if ((yyin = fopen(path, "r")) == NULL)
263 		fatal("cannot open config: %s: %s", path, strerror(errno));
264 	yyparse();
265 	fclose(yyin);
266 
267 	if (goterror)
268 		exit(1);
269 
270 	if (TAILQ_FIRST(&hosts)->domain == NULL)
271 		fatal("no vhost defined in %s", path);
272 }
273 
274 char *
275 ensure_absolute_path(char *path)
276 {
277 	if (path == NULL || *path != '/')
278 		yyerror("not an absolute path");
279 	return path;
280 }
281 
282 int
283 check_block_code(int n)
284 {
285 	if (n < 10 || n >= 70 || (n >= 20 && n <= 29))
286 		yyerror("invalid block code %d", n);
287 	return n;
288 }
289 
290 char *
291 check_block_fmt(char *fmt)
292 {
293 	char *s;
294 
295 	for (s = fmt; *s; ++s) {
296 		if (*s != '%')
297 			continue;
298 		switch (*++s) {
299 		case '%':
300 		case 'p':
301 		case 'q':
302 		case 'P':
303 		case 'N':
304 			break;
305 		default:
306 			yyerror("invalid format specifier %%%c", *s);
307 		}
308 	}
309 
310 	return fmt;
311 }
312 
313 int
314 check_strip_no(int n)
315 {
316 	if (n <= 0)
317 		yyerror("invalid strip number %d", n);
318 	return n;
319 }
320 
321 int
322 check_prefork_num(int n)
323 {
324 	if (n <= 0 || n >= PROC_MAX)
325 		yyerror("invalid prefork number %d", n);
326 	return n;
327 }
328 
329 void
330 advance_loc(void)
331 {
332 	loc = new_location();
333 	TAILQ_INSERT_TAIL(&host->locations, loc, locations);
334 }