1 #!/usr/bin/env perl
2 #
3 # mkindex was written by Omar Polo <op@openbsd.org> and is placed in
4 # the public domain.  The author hereby disclaims copyright to this
5 # source code.
6 
7 use open ":std", ":encoding(UTF-8)";
8 use utf8;
9 use strict;
10 use warnings;
11 use v5.32;
12 use File::Temp qw(tempfile);
13 
14 use OpenBSD::Pledge;
15 use OpenBSD::Unveil;
16 
17 use GotMArc qw(parse san urlencode initpage endpage index_header
18     search thread_header threntry);
19 
20 my $outdir = $ENV{'OUTDIR'};
21 die 'Set $OUTDIR' unless defined $outdir;
22 
23 my $tfh; # thread file handle
24 my $pfh; # page file handle
25 my $page = 0;
26 my @pages;
27 my @files;
28 my $from_day;
29 my $to_day;
30 my $threads_seen = 0;
31 
32 my $last_level = 0;
33 my $last_tid;
34 my $last_date;
35 my $last_from;
36 my $last_subj;
37 
38 my $threads = 0;
39 my $threads_per_page = 100;
40 
41 sub maxs {
42 	my ($a, $b) = @_;
43 	return $a unless defined $b;
44 	return $a gt $b ? $a : $b;
45 }
46 
47 sub mins {
48 	my ($a, $b) = @_;
49 	return $a unless defined $b;
50 	return $a lt $b ? $a : $b;
51 }
52 
53 sub pagename {
54 	my $i = shift;
55 	return $i == 1 && "index.html" || "$i.html";
56 }
57 
58 sub endfile {
59 	say $pfh '</ul></div>';
60 	close($pfh);
61 	push @pages, "$from_day - $to_day";
62 }
63 
64 sub nextfile {
65 	endfile if defined $pfh;
66 	$page += 1;
67 
68 	my $path;
69 	($pfh, $path) = tempfile "/tmp/gotmarc.index.XXXXXXXXXX";
70 	binmode($pfh, ':utf8');
71 	push @files, $path;
72 	say $pfh "<div class='thread'><ul>";
73 }
74 
75 sub nav {
76 	my ($pfh, $n) = @_;
77 	my ($first, $last) = (pagename(1), pagename($page));
78 	my ($next, $prev) = (pagename($n+1), pagename($n-1));
79 
80 	say $pfh "<nav>";
81 	say $pfh "<a href='$first'>First</a>" if $n > 2;
82 	say $pfh "<a href='$prev'>Prev</a>" if $n > 1;
83 	say $pfh "<a href='$next'>Next</a>" if $n < $page;
84 	say $pfh "<a href='$last'>Last</a>" if $n < $page - 1;
85 	say $pfh "</nav>";
86 }
87 
88 sub copyfrom {
89 	my ($path, $fh) = @_;
90 
91 	# there are probably faster ways to do this like File::Copy,
92 	# but it bypasses the bufio cache...
93 	open(my $pfh, '<', $path) or die "can't open $path: $!";
94 	print $fh $_ while <$pfh>;
95 }
96 
97 sub renderpages {
98 	close($pfh);
99 
100 	for (my $i = 1; $i <= $page; $i++) {
101 		my $name = pagename($i);
102 		my $path = shift @files;
103 		my $dest = "$outdir/$name";
104 
105 		open(my $pfh, '>', $dest)
106 		    or die "can't open $dest for writing: $!";
107 
108 		my $title = "page $i";
109 		my $subtitle = $pages[$i-1];
110 
111 		initpage($pfh, $title);
112 		index_header $pfh, $i, $subtitle;
113 		say $pfh "<main>";
114 
115 		nav $pfh, $i if $page > 1;
116 		search $pfh;
117 		copyfrom($path, $pfh);
118 		nav $pfh, $i if $page > 1;
119 
120 		say $pfh "</main>";
121 		endpage($pfh);
122 
123 		close($pfh);
124 		unlink $path;
125 	}
126 }
127 
128 sub endthread {
129 	say $tfh "</ul></li>" x $last_level;
130 	say $tfh "</ul>\n</div>\n";
131 	endpage($tfh);
132 	close($tfh);
133 
134 	$last_level = 0;
135 }
136 
137 sub nextthread {
138 	endthread if defined $tfh;
139 	my ($mid, $subj) = @_;
140 	my $dest = "$outdir/thread/$mid.html";
141 	open($tfh, '>', $dest) or die "can't open $dest: $!";
142 	initpage($tfh, $subj);
143 	thread_header $tfh, ["Thread: $subj"];
144 	print $tfh "<div class='thread'><ul class='mails'>\n";
145 }
146 
147 sub index_entry {
148 	my ($fh, $mid, $date, $from, $subj) = @_;
149 
150 	# synthetic mail hash
151 	my $mail = {
152 		mid => $mid,
153 		level => 0,
154 		date => $date,
155 		from => $from,
156 		subj => $subj,
157 	};
158 
159 	threntry $fh, "thread", 0, 0, $mail;
160 }
161 
162 unveil($outdir, "rwc") or die "unveil $outdir: $!";
163 
164 # can't use tmppath because File::Temp checks wether /tmp exists.
165 unveil("/tmp", "rwc") or die "unveil /tmp: $!";
166 
167 # fattr for File::Temp
168 pledge("stdio rpath wpath cpath fattr") or die "pledge: $!";
169 
170 nextfile;
171 
172 while (<>) {
173 	my $mail = parse $_;
174 
175 	if ($mail->{level} == 0) {
176 		nextthread $mail->{mid}, $mail->{subj};
177 
178 		$threads++;
179 		if ($threads > $threads_per_page) {
180 			nextfile;
181 			$threads = 0;
182 			$to_day = undef;
183 			$from_day = undef;
184 		}
185 
186 		my $day = $mail->{date} =~ s/ .*//r;
187 		$to_day = mins $day, $to_day;
188 		$from_day = maxs $day, $from_day;
189 	}
190 
191 	$last_level = threntry $tfh, "mail", 0, $last_level, $mail;
192 	$threads_seen = 1;
193 
194 	index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
195 	    if defined $last_tid && $mail->{level} == 0;
196 
197 	# `gt' on dates works because the format used allow for
198 	# lexicographic comparisons.
199 	if ($mail->{level} == 0 || $mail->{date} gt $last_date) {
200 		$last_date = $mail->{date};
201 		$last_from = $mail->{from};
202 	}
203 
204 	if ($mail->{level} == 0) {
205 		$last_tid = $mail->{mid};
206 		$last_subj = $mail->{subj};
207 	}
208 }
209 
210 index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
211     if defined $last_tid;
212 
213 endfile;
214 endthread if $threads_seen;
215 renderpages;