1 # GotMArc was written by Omar Polo <op@openbsd.org> and is placed in
2 # the public domain.  The author hereby disclaims copyright to this
3 # source code.
4 
5 package SMArc;
6 use strict;
7 use warnings;
8 use v5.32;
9 use Exporter;
10 use File::Basename;
11 
12 our @ISA = qw(Exporter);
13 our @EXPORT_OK = qw(san urlencode parse initpage endpage index_header
14     search thread_header threntry thrslice thrnav);
15 
16 sub san {
17 	my $str = shift;
18 	$str =~ s/&/\&amp;/g;
19 	$str =~ s/</\&lt;/g;
20 	$str =~ s/>/\&gt;/g;
21 	return $str;
22 }
23 
24 sub urlencode {
25 	my $str = shift;
26 	unless (defined($str)) {
27 		my ($pkg, $file, $line) = caller 1;
28 		die "bad $pkg / $file:$line";
29 	}
30 	$str =~ s/([^-_~.A-Za-z0-9])/sprintf("%%%2X", ord($1))/ge;
31 	return $str;
32 }
33 
34 sub ssan {
35 	my $str = shift;
36 	$str =~ s/\s+/ /g;
37 	$str =~ s/\s+$//;
38 	return san($str);
39 }
40 
41 sub parse {
42 	my $line = shift;
43 	my ($indent, $fname, $date, $from, $subj) = $line =~ m{
44 		^([^-]*)-			# the indent level
45 		([^ ]+)\s			# filename
46 		(\d{4}-\d\d-\d\d[ ]\d\d:\d\d)	# date
47 		<([^>]+)>			# from
48 		(.*)				# subject
49 	}x or die "can't parse: $line";
50 
51 	my $level = length($indent);
52 	$level = 10 if $indent =~ m/\.\.\d+\.\./;
53 
54 	$from = ssan($from);
55 	$subj = ssan($subj);
56 
57 	my ($time, $id) = split /\./, basename($fname);
58 	my $mid = "$time.$id";
59 
60 	return {level => $level, fname => $fname,
61 	    mid => $mid, date => $date, from => $from, subj => $subj};
62 }
63 
64 sub readall {
65 	my $path = shift;
66 	local $/ = undef;
67 	open my $fh, "<", $path or die "can't open $path: $!";
68 	<$fh>;
69 }
70 
71 my $templates = $ENV{TMPLDIR};
72 die 'undefined $TMPLDIR' unless defined $templates;
73 
74 my $small_logo = readall "$templates/logo-small.html";
75 my $hdr = readall "$templates/head.html";
76 my $foot = readall "$templates/foot.html";
77 my $idxhdr = readall "$templates/index-header.html";
78 my $search = readall "$templates/search.html";
79 
80 sub initpage {
81 	my ($fh, $title) = @_;
82 	say $fh $hdr =~ s/TITLE/$title/r;
83 }
84 
85 sub endpage {
86 	my $fh = shift;
87 	say $fh $foot;
88 }
89 
90 sub index_header {
91 	my ($fh, $page, $subtitle) = @_;
92 	my $html = $idxhdr =~ s/PAGE/$page/r;
93 	$html =~ s/SUBTITLE/$subtitle/;
94 	print $fh $html;
95 }
96 
97 sub search {
98 	my $fh = shift;
99 	my $html = $search =~ s/QUERY//r;
100 	print $fh $html;
101 }
102 
103 sub thread_header {
104 	my ($fh, $e, $mail, $p, $n) = @_;
105 
106 	my @entries = @$e;
107 
108 	my $enctid = urlencode $mail->{tid} if defined $mail;
109 	my $encmid = urlencode $mail->{mid} if defined $mail;
110 
111 	print $fh "<header class='mail-header'>\n";
112 
113 	print $fh "<p>";
114 	print $fh $small_logo;
115 	print $fh "<a href='/'>Index</a>";
116 	print $fh " | <a href='/thread/$enctid.html#$encmid'>Thread</a>"
117 	    if defined $enctid;
118 	print $fh " | <a href='/search'>Search</a>";
119 	print $fh "</p>\n";
120 
121 	say $fh "<dl>";
122 	foreach my $entry (@entries) {
123 		my ($k, $v) = split /: /, $entry, 2;
124 		chomp $v;
125 		say $fh "<dt>$k:</dt><dd>$v</dd>";
126 	}
127 	say $fh "</dl>";
128 
129 	say $fh "<p>Download raw <a href='/text/$encmid.txt'>body</a>.</p>"
130 	    if defined $encmid;
131 
132 	if (defined($p) and defined($n)) {
133 		say $fh "<details>";
134 		say $fh "<summary>Thread</summary>";
135 		thrslice($fh, $mail, $p, $n);
136 		say $fh "</details>";
137 		thrnav($fh, $p, $n, $mail->{mid}, $mail->{tid});
138 	}
139 
140 	say $fh "</header>\n";
141 }
142 
143 sub threntry {
144 	my ($fh, $type, $base, $last_level, $mail, $cur) = @_;
145 	my $level = $mail->{level} - $base;
146 
147 	say $fh "</ul></li>" x ($last_level - $level) if $last_level > $level;
148 	say $fh "<li><ul>" if $last_level < $level;
149 
150 	my $encmid = urlencode $mail->{mid};
151 
152 	print $fh "<li id='$encmid' class='mail'>";
153 	print $fh "<p class='mail-meta'>";
154 	print $fh "<time>$mail->{date}</time> ";
155 	print $fh "<span class='from'>$mail->{from}</span>";
156 	print $fh "<span class='colon'>:</span>";
157 	print $fh "</p>";
158 	print $fh "<p class='subject'>";
159 
160 	my $subj = $mail->{subj};
161 	if (!defined($cur) || $mail->{mid} ne $cur->{mid}) {
162 		print $fh "<a href='/$type/$encmid.html'>$subj</a>";
163 	} else {
164 		print $fh "<span>$subj</span>";
165 	}
166 
167 	print $fh "</p>";
168 	print $fh "</li>";
169 
170 	return $level;
171 }
172 
173 sub min_level {
174 	my $l = 999;
175 	return 0 unless @_;
176 	for (@_) {
177 		$l = $_->{level} if $_->{level} < $l;
178 	}
179 	return $l;
180 }
181 
182 sub thrslice {
183 	my ($fh, $mail, $p, $n) = @_;
184 	my @prev = @{$p};
185 	my @next = @{$n};
186 	my @thread = (@prev, $mail, @next);
187 	return unless @thread;
188 	my $base = min_level @thread;
189 	my $level = 0;
190 	print $fh "<div class='thread'>";
191 	print $fh "<ul class='mails'>";
192 	$level = threntry $fh, "mail", $base, $level, $_, $mail for @thread;
193 	print $fh "</ul></li>" x $level;
194 	print $fh "</ul></div>";
195 }
196 
197 sub thrnav {
198 	my ($fh, $p, $n) = @_;
199 	my @prev = @{$p};
200 	my @next = @{$n};
201 
202 	return if !@prev && !@next;
203 	print $fh "<nav>";
204 
205 	if (@prev) {
206 		my $mail = $prev[-1];
207 		my $encmid = $mail->{mid};
208 		say $fh "<a href='/mail/$encmid.html'>Previous in thread</a>";
209 	} else {
210 		say $fh "<span>Previous in thread</span>";
211 	}
212 
213 	if (@next) {
214 		my $mail = $next[0];
215 		my $encmid = $mail->{mid};
216 		say $fh "<a href='/mail/$encmid.html'>Next in thread</a>";
217 	} else {
218 		say $fh "<span>Next in thread</span>";
219 	}
220 
221 	print $fh "</nav>";
222 }
223 
224 1;