1 #!/usr/bin/env perl
2 #
3 # mkindex was written by Omar Polo <op@openbsd.org> and is placed in
4 # the public domain.  The author hereby disclaims copyright to this
5 # source code.
6 
7 use open ":std", ":encoding(UTF-8)";
8 use utf8;
9 use strict;
10 use warnings;
11 use v5.32;
12 use File::Temp qw(tempfile);
13 
14 use SMArc qw(parse san urlencode initpage endpage index_header
15     search thread_header threntry);
16 
17 my $outdir = $ENV{'OUTDIR'};
18 die 'Set $OUTDIR' unless defined $outdir;
19 
20 my $tfh; # thread file handle
21 my $pfh; # page file handle
22 my $page = 0;
23 my @pages;
24 my @files;
25 my $from_day;
26 my $to_day;
27 my $threads_seen = 0;
28 
29 my $last_level = 0;
30 my $last_tid;
31 my $last_date;
32 my $last_from;
33 my $last_subj;
34 
35 my $threads = 0;
36 my $threads_per_page = 100;
37 
38 sub maxs {
39 	my ($a, $b) = @_;
40 	return $a unless defined $b;
41 	return $a gt $b ? $a : $b;
42 }
43 
44 sub mins {
45 	my ($a, $b) = @_;
46 	return $a unless defined $b;
47 	return $a lt $b ? $a : $b;
48 }
49 
50 sub pagename {
51 	my $i = shift;
52 	return $i == 1 && "index.html" || "$i.html";
53 }
54 
55 sub endfile {
56 	say $pfh '</ul></div>';
57 	close($pfh);
58 	push @pages, "$from_day - $to_day";
59 }
60 
61 sub nextfile {
62 	endfile if defined $pfh;
63 	$page += 1;
64 
65 	my $path;
66 	($pfh, $path) = tempfile "/tmp/smarc.index.XXXXXXXXXX";
67 	binmode($pfh, ':utf8');
68 	push @files, $path;
69 	say $pfh "<div class='thread'><ul>";
70 }
71 
72 sub nav {
73 	my ($pfh, $n) = @_;
74 	my ($first, $last) = (pagename(1), pagename($page));
75 	my ($next, $prev) = (pagename($n+1), pagename($n-1));
76 
77 	say $pfh "<nav>";
78 	say $pfh "<a href='$first'>First</a>" if $n > 2;
79 	say $pfh "<a href='$prev'>Prev</a>" if $n > 1;
80 	say $pfh "<a href='$next'>Next</a>" if $n < $page;
81 	say $pfh "<a href='$last'>Last</a>" if $n < $page - 1;
82 	say $pfh "</nav>";
83 }
84 
85 sub copyfrom {
86 	my ($path, $fh) = @_;
87 
88 	# there are probably faster ways to do this like File::Copy,
89 	# but it bypasses the bufio cache...
90 	open(my $pfh, '<', $path) or die "can't open $path: $!";
91 	print $fh $_ while <$pfh>;
92 }
93 
94 sub renderpages {
95 	close($pfh);
96 
97 	for (my $i = 1; $i <= $page; $i++) {
98 		my $name = pagename($i);
99 		my $path = shift @files;
100 		my $dest = "$outdir/$name";
101 
102 		open(my $pfh, '>', $dest)
103 		    or die "can't open $dest for writing: $!";
104 
105 		my $title = "page $i";
106 		my $subtitle = $pages[$i-1];
107 
108 		initpage($pfh, $title);
109 		index_header $pfh, $i, $subtitle;
110 		say $pfh "<main>";
111 
112 		nav $pfh, $i if $page > 1;
113 		search $pfh;
114 		copyfrom($path, $pfh);
115 		nav $pfh, $i if $page > 1;
116 
117 		say $pfh "</main>";
118 		endpage($pfh);
119 
120 		close($pfh);
121 		unlink $path;
122 	}
123 }
124 
125 sub endthread {
126 	say $tfh "</ul></li>" x $last_level;
127 	say $tfh "</ul>\n</div>\n";
128 	endpage($tfh);
129 	close($tfh);
130 
131 	$last_level = 0;
132 }
133 
134 sub nextthread {
135 	endthread if defined $tfh;
136 	my ($mid, $subj) = @_;
137 	my $dest = "$outdir/thread/$mid.html";
138 	open($tfh, '>', $dest) or die "can't open $dest: $!";
139 	initpage($tfh, $subj);
140 	thread_header $tfh, ["Thread: $subj"];
141 	print $tfh "<div class='thread'><ul class='mails'>\n";
142 }
143 
144 sub index_entry {
145 	my ($fh, $mid, $date, $from, $subj) = @_;
146 
147 	# synthetic mail hash
148 	my $mail = {
149 		mid => $mid,
150 		level => 0,
151 		date => $date,
152 		from => $from,
153 		subj => $subj,
154 	};
155 
156 	threntry $fh, "thread", 0, 0, $mail;
157 }
158 
159 if (`uname` =~ "OpenBSD") {
160 	use OpenBSD::Pledge;
161 	use OpenBSD::Unveil;
162 
163 	unveil($outdir, "rwc") or die "unveil $outdir: $!";
164 
165 	# can't use tmppath because File::Temp checks wether /tmp exists.
166 	unveil("/tmp", "rwc") or die "unveil /tmp: $!";
167 
168 	# fattr for File::Temp
169 	pledge("stdio rpath wpath cpath fattr") or die "pledge: $!";
170 }
171 
172 nextfile;
173 
174 while (<>) {
175 	my $mail = parse $_;
176 
177 	if ($mail->{level} == 0) {
178 		nextthread $mail->{mid}, $mail->{subj};
179 
180 		$threads++;
181 		if ($threads > $threads_per_page) {
182 			nextfile;
183 			$threads = 0;
184 			$to_day = undef;
185 			$from_day = undef;
186 		}
187 
188 		my $day = $mail->{date} =~ s/ .*//r;
189 		$to_day = mins $day, $to_day;
190 		$from_day = maxs $day, $from_day;
191 	}
192 
193 	$last_level = threntry $tfh, "mail", 0, $last_level, $mail;
194 	$threads_seen = 1;
195 
196 	index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
197 	    if defined $last_tid && $mail->{level} == 0;
198 
199 	# `gt' on dates works because the format used allow for
200 	# lexicographic comparisons.
201 	if ($mail->{level} == 0 || $mail->{date} gt $last_date) {
202 		$last_date = $mail->{date};
203 		$last_from = $mail->{from};
204 	}
205 
206 	if ($mail->{level} == 0) {
207 		$last_tid = $mail->{mid};
208 		$last_subj = $mail->{subj};
209 	}
210 }
211 
212 index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
213     if defined $last_tid;
214 
215 endfile;
216 endthread if $threads_seen;
217 renderpages;