1 #!/usr/bin/env perl
2 #
3 # smingest was written by Omar Polo <op@openbsd.org> and is placed in the
4 # public domain.  The author hereby disclaims copyright to this source
5 # code.
6 
7 use strict;
8 use warnings;
9 use v5.32;
10 use utf8;
11 
12 use Date::Parse;
13 use File::Basename;
14 
15 die "usage: $0 dbpath\n" if @ARGV != 1;
16 my $dbpath = shift @ARGV;
17 
18 open(my $sqlite, "|-", "sqlite3", $dbpath) or die "can't spawn sqlite3";
19 
20 if (`uname` =~ "OpenBSD") {
21 	use OpenBSD::Pledge;
22 	use OpenBSD::Unveil;
23 
24 	unveil("/usr/local/bin/mshow", "rx") or die "unveil mshow: $!";
25 	pledge("stdio proc exec") or die "pledge: $!";
26 }
27 
28 say $sqlite ".import --csv /dev/stdin email"
29     or die "can't speak to sqlite: $!";
30 
31 while (<>) {
32 	chomp;
33 
34 	open(my $fh, "-|", "mshow", "-Atext/plain", "-NF", $_)
35 	    or die "can't run mshow $_: $!";
36 
37 	my $f = $_;
38 	my ($time, $id) = split /\./, basename $_;
39 	my $mid = "$time.$id";
40 	$mid =~ s/"/""/g;
41 
42 	my ($from, $subj, $date) = ('', '', undef);
43 	while (<$fh>) {
44 		chomp;
45 		last if /^$/;
46 		s/"/""/g;
47 		$from = s/.*?: //r if /^From:/;
48 		$subj = s/.*?: //r if /^Subject:/;
49 		$date = str2time(s/.*?: //r) if /^Date:/;
50 	}
51 	$date //= time;
52 	$from =~ s/ +<.*>//;
53 
54 	# leave open for the body
55 	print $sqlite "\"$mid\",\"$from\",\"$date\",\"$subj\",\"";
56 
57 	while (<$fh>) {
58 		s/"/""/g;
59 		print $sqlite $_;
60 	}
61 	say $sqlite '"';
62 
63 	close $fh;
64 }
65 
66 close $sqlite;
67 die "sqlite3 exited with $?\n" unless $? == 0;