1 ;;; a68-mode.el --- Major mode for editing Algol 68 code -*- lexical-binding: t; -*-
2 
3 ;; Copyright (C) 2011 Jose E. Marchesi
4 ;; Copyright (C) 2021 Omar Polo <op@omarpolo.com>
5 
6 ;; Author: Jose E. Marchesi
7 ;;         Omar Polo <op@omarpolo.com>
8 ;; Maintainer: Omar Polo
9 ;; URL: https://git.omarpolo.com/a68-mode
10 ;; Keywords: languages
11 ;; Version: 0
12 ;; Package-Requires: ((emacs "24.3"))
13 
14 ;; This file is NOT part of GNU Emacs.
15 
16 ;; This program is free software; you can redistribute it and/or modify
17 ;; it under the terms of the GNU General Public License as published by
18 ;; the Free Software Foundation; either version 3, or (at your option)
19 ;; any later version.
20 
21 ;; This program is distributed in the hope that it will be useful,
22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
24 ;; GNU General Public License for more details.
25 
26 ;; You should have received a copy of the GNU General Public License
27 ;; along with this program; see the file COPYING.  If not, write to the
28 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
29 ;; Boston, MA 02110-1301, USA.
30 
31 ;;; Commentary:
32 
33 ;; A major mode for editing Algol 68 code.
34 ;;
35 ;; This is an improved and modernized version of the a68-mode written
36 ;; by Jose E. Marchesi.  The original code was taken from
37 ;;
38 ;; https://github.com/lachrymology/me/blob/master/.emacs.d/extras/algol-mode.el
39 ;;
40 ;; TODO: support quote and dot stropping.
41 
42 ;;; Code:
43 
44 (require 'font-lock)
45 (require 'smie)
46 (require 'syntax)
47 
48 (eval-when-compile
49   (require 'rx))
50 
51 (defgroup a68 nil
52   "Major mode for editing Algol68 code."
53   :prefix "a68-"
54   :group 'languages)
55 
56 (defcustom a68-indent-level 3
57   "Indentation step for Algol 68."
58   :type 'integer
59   :safe #'integerp)
60 
61 (defcustom a68-comment-style "#"
62   "Default comment style used by e.g. `comment-dwim'."
63   :type '(choice (const "#")
64                  (const "CO")
65                  (const "COMMENT"))
66   :safe #'consp)
67 
68 (defvar a68-mode-hook '()
69   "Hook run when entering Algol68 mode.")
70 
71 (defvar a68-mode-map
72   (let ((map (make-sparse-keymap)))
73     (define-key map (kbd "C-j") #'newline-and-indent)
74     ;; (define-key map (kbd "RET") #'a68-electric-terminate-line)
75     map)
76   "Keymap for Algol 68 major mode.")
77 
78 (defconst a68-font-lock-keywords
79   (list
80    (cons (rx word-start
81              (or "DECS" "PROGRAM" "CONTEXT" "USE" "FINISH" "KEEP"
82                  "ALIEN"
83                  "MODE" "OP" "PRIO" "PROC"
84                  "OF" "AT" "IS" "ISNT" "EMPTY" "SKIP"
85                  "PR" "PRAGMAT"
86                  "CASE" "IN" "OUSE" "OUT" "ESAC"
87                  "FOR" "FORALL" "FROM" "TO" "BY" "WHILE" "DO" "OD"
88                  "IF" "THEN" "ELIF" "THEN" "ELSE" "FI"
89                  "PAR" "BEGIN" "END" "GOTO" "EXIT"
90                  "LWB" "UPB" "NOT" "ABS" "BIN" "REPR" "LENG"
91                  "SHORTEN" "ODD" "SIGN" "ROUND" "ENTIER" "AND" "OR"
92                  "DIV" "OVER" "MOD" "ELEM" "SHL" "SHR" "OVERAB" "DIVAB" "MODAB"
93                  "REF")
94              word-end)
95          'font-lock-keyword-face)
96    (cons (rx word-start
97              (or "TRUE" "FALSE")
98              word-end)
99          'font-lock-constant-face)
100    ;; only valid for bold stropping
101    (cons (concat "\\<[A-Z]+\\>") 'font-lock-type-face)
102    (cons "\\('\\w*'\\)"
103          'font-lock-variable-name-face))
104   "Highlighting expressions for Algol 68 mode.")
105 
106 (defvar a68--keywords-regexp
107   (regexp-opt '("+" "*" ";" ">" "<" ":=" "=" "," ":")))
108 
109 (defvar a68--smie-grammar
110   (smie-prec2->grammar
111    (smie-bnf->prec2 '((id)
112                       (expr ("-" expr)
113                             (expr "+" expr)
114                             (expr "*" expr)
115                             (expr "/" expr)
116                             (expr "=" expr)
117                             (expr "/=" expr)
118                             (expr ":=" expr)
119                             (expr ":=:" expr)
120                             (expr ":/=:" expr)
121                             ("BEGIN" exprs "END")
122                             ("(" exprs ")")
123                             ;; why all the repetitions?  copied from
124                             ;; sh-script.el
125                             ("IF" exprs "THEN" exprs "FI")
126                             ("IF" exprs "THEN" exprs "ELSE" exprs "FI")
127                             ("IF" exprs "THEN" exprs
128                              "ELIF" exprs "THEN" exprs "FI")
129                             ("IF" exprs "THEN" exprs
130                              "ELIF" exprs "THEN" exprs
131                              "ELSE" exprs "FI")
132                             ("IF" exprs "THEN" exprs
133                              "ELIF" exprs "THEN" exprs
134                              "ELIF" exprs "THEN" exprs
135                              "ELSE" exprs "FI")
136                             ("CASE" exprs "IN" exprs "ESAC")
137                             ("CASE" exprs "IN" exprs "OUT" exprs "ESAC"))
138                       (exprs (exprs "," exprs)
139                              (exprs ";" exprs)
140                              (exprs ":" exprs)
141                              (expr))
142                       (loop ("FOR" exprs "FROM" exprs "TO" exprs
143                              "BY" exprs "DO" exprs "OD")
144                             ("FOR" exprs "FROM" exprs "TO" exprs
145                              "DO" exprs "OD")
146                             ("FOR" exprs "BY" exprs "TO" exprs
147                              "DO" exprs "OD")
148                             ;; ("TO" exprs "DO" exprs "OD")
149                             ("WHILE" exprs "DO" exprs "OD")))
150                     '((assoc ";" "," ":"))
151                     '((assoc "=" "/=" ":=" ":=:" ":/=:"
152                              "+" "-" "*" "/")))))
153 
154 (defun a68--smie-rules (kind token)
155   (pcase (cons kind token)
156     (`(:elem . basic) a68-indent-level)
157     ;; (`(,_ . ",") (smie-rule-separator kind))
158     (`(,_ . ",") (smie-rule-separator kind))
159     (`(,_ . ";") (when (smie-rule-parent-p)
160                    (smie-rule-parent)))
161     (`(:after . ":=") a68-indent-level)
162     (`(:after . "=") a68-indent-level)
163     (`(:before . ,(or `"BEGIN" '"(")) (when (smie-rule-hanging-p)
164                                         (smie-rule-parent)))
165     (`(:before . "IF")
166      (and (not (smie-rule-bolp))
167           (smie-rule-prev-p "ELSE")
168           (smie-rule-parent)))))
169 
170 (defun a68--smie-forward-token ()
171   (forward-comment (point-max))
172   (cond
173    ((looking-at a68--keywords-regexp)
174     (goto-char (match-end 0))
175     (match-string-no-properties 0))
176    (t (buffer-substring-no-properties (point)
177                                       (progn (skip-syntax-forward "w_")
178                                              (point))))))
179 
180 (defun a68--smie-backward-token ()
181   (forward-comment (- (point)))
182   (cond
183    ((looking-back a68--keywords-regexp (- (point) 2) t)
184     (goto-char (match-beginning 0))
185     (match-string-no-properties 0))
186    (t (buffer-substring-no-properties (point)
187                                       (progn (skip-syntax-backward "w_")
188                                              (point))))))
189 
190 (defvar a68-mode-syntax-table
191   (let ((st (make-syntax-table)))
192     (modify-syntax-entry ?# "<" st)
193     (modify-syntax-entry ?# ">" st)
194     (modify-syntax-entry ?\\ "." st)
195     (modify-syntax-entry ?, "." st)
196     (modify-syntax-entry ?: "." st)
197     ;; define parentheses to match
198     (modify-syntax-entry ?\( "()" st)
199     (modify-syntax-entry ?\) ")(" st)
200     st))
201 
202 (defvar a68-mode-abbrev-table nil
203   "Abbreviation table used in `a68-mode' buffers.")
204 
205 (define-abbrev-table 'a68-mode-abbrev-table
206   '())
207 
208 ;;;###autoload
209 (define-derived-mode a68-mode prog-mode "Algol68"
210   "Major mode for editing Alogl68 files."
211   :abbrev-table a68-mode-abbrev-table
212   (setq-local font-lock-defaults '(a68-font-lock-keywords))
213   (smie-setup a68--smie-grammar #'a68--smie-rules
214               :forward-token #'a68--smie-forward-token
215               :backward-token #'a68--smie-backward-token)
216   (setq-local comment-start a68-comment-style)
217   (setq-local comment-end a68-comment-style)
218   (setq-local syntax-propertize-function
219               (syntax-propertize-rules
220                ((rx (group bow "COMMENT" eow)
221                     (group (*? anychar))
222                     (group bow "COMMENT" eow))
223                 (1 "<")
224                 (3 ">"))
225                ((rx (group bow "CO" eow)
226                     (group (*? anychar))
227                     (group bow "CO" eow))
228                 (1 "<")
229                 (3 ">"))
230                ;; ((rx (group "#\\[^!\\]")
231                ;;      (group (*? anychar))
232                ;;      (group "#"))
233                ;;  (1 "<")
234                ;;  (3 ">"))
235                )))
236 
237 ;;;###autoload
238 (add-to-list 'auto-mode-alist '("\\.a68\\'" . a68-mode))
239 
240 (provide 'a68-mode)
241 ;;; a68-mode.el ends here