1 #!/usr/bin/env perl
2 #
3 # Copyright (c) 2022 Omar Polo <op@omarpolo.com>
4 #
5 # Permission to use, copy, modify, and distribute this software for any
6 # purpose with or without fee is hereby granted, provided that the above
7 # copyright notice and this permission notice appear in all copies.
8 #
9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
16 
17 use strict;
18 use warnings;
19 use v5.32;
20 
21 use open ":std", ":encoding(UTF-8)";
22 
23 use Getopt::Long qw(:config bundling require_order);
24 use File::Basename;
25 use File::Find;
26 
27 my $store = $ENV{'PLASS_STORE'} // $ENV{'HOME'}.'/.password-store';
28 
29 my $got = $ENV{'PLASS_GOT'} // 'got';
30 my $tog = $ENV{'PLASS_TOG'} // 'tog';
31 
32 my $gpg = $ENV{'PLASS_GPG'} // 'gpg2';
33 my @gpg_flags = qw(--quiet --compress-algo=none --no-encrypt-to);
34 
35 my $default_chars = $ENV{'PLASS_CHARS'} // '!-~';
36 my $default_length = $ENV{'PLASS_LENGTH'};
37 if (!defined($default_length) || $default_length lt 0) {
38 	$default_length = 32;
39 }
40 
41 my $usage = "[-h] [command argument ...]";
42 my $cmd;
43 sub usage {
44 	my $prog = basename $0;
45 	if (defined($cmd)) {
46 		say STDERR "Usage: $prog $cmd $usage";
47 	} else {
48 		say STDERR "Usage: $prog $usage";
49 	}
50 	exit 1;
51 }
52 
53 GetOptions("h|?" => \&usage) or usage();
54 
55 $cmd = shift // 'find';
56 
57 my %subcmd = (
58 	cat	=> [\&cmd_cat,		"entries..."],
59 	find	=> [\&cmd_find,		"[pattern]"],
60 	gen	=> [\&cmd_gen,		"[-nq] [-c chars] [-l length] entry"],
61 	got	=> [\&cmd_got,		"args ..."],
62 	mv	=> [\&cmd_mv,		"from to"],
63 	rm	=> [\&cmd_rm,		"entries..."],
64 	tee	=> [\&cmd_tee,		"[-q] entry"],
65 	tog	=> [\&cmd_tog,		"args ..."],
66     );
67 usage() unless defined $subcmd{$cmd};
68 my $fn;
69 ($fn, $usage) = @{$subcmd{$cmd}};
70 chdir $store;
71 $fn->();
72 exit 0;
73 
74 
75 # utils
76 
77 sub name2file {
78 	my $f = shift;
79 	$f .= ".gpg" unless $f =~ m,\.gpg$,;
80 	return $f;
81 }
82 
83 # tr -cd -- $chars < /dev/random | dd bs=$len count=1 status=none
84 sub gen {
85 	my ($chars, $length) = @_;
86 	my $pass = "";
87 
88 	open(my $fh, '<:raw', '/dev/random')
89 	    or die "can't open /dev/random: $!";
90 	my $l = $length;
91 	while ($l gt 0) {
92 		read($fh, my $t, $length * 4)
93 		    or die "failed to read /dev/random: $!";
94 		$t =~ s/[^$chars]//g;
95 		$l -= length($t);
96 		$pass .= $t;
97 	}
98 	close($fh);
99 
100 	return substr($pass, 0, $length);
101 }
102 
103 sub readpass {
104 	# todo some stty black magic to avoid echo
105 	print shift if -t;
106 	my $pass = <>;
107 	die "failed to read stdin: $!" unless defined($pass);
108 	chomp $pass;
109 	return $pass;
110 }
111 
112 sub mkdirs {
113 	my $dir = shift;
114 	my $parent = dirname $dir;
115 	mkdirs($parent) unless -d $parent || $parent eq '/';
116 	mkdir $dir or die "mkdir $dir: $!"
117 	    unless -d $dir;
118 }
119 
120 sub writepass {
121 	my ($file, $pass) = @_;
122 
123 	mkdirs(dirname $file);
124 
125 	my @args = ($gpg, @gpg_flags, '-e', '-r', recipient(),
126 	    '-o', $file);
127 	open my $fh, '|-', @args;
128 	say $fh "$pass";
129 	close($fh);
130 }
131 
132 sub recipient {
133 	open my $fh, '<', "$store/.gpg-id"
134 	    or die "can't open recipient file";
135 	my $r = <$fh>;
136 	chomp $r;
137 	close($fh);
138 	return $r;
139 }
140 
141 sub passfind {
142 	my $pattern = shift;
143 	my @entries;
144 
145 	find({
146 		wanted => sub {
147 			if (m,/.git$, || m,/.got$,) {
148 				$File::Find::prune = 1;
149 				return;
150 			}
151 
152 			return if defined($pattern) && ! m/$pattern/;
153 			return unless -f && m,.gpg$,;
154 
155 			s,^$store/*,,;
156 			s,.gpg$,,;
157 			push @entries, $_;
158 		},
159 		no_chdir => 1,
160 		follow_fast => 1,
161 	     }, ($store));
162 	return sort(@entries);
163 }
164 
165 sub got {
166 	# discard stdout
167 	open my $fh, '-|', ($got, @_);
168 	close($fh);
169 	return !$?;
170 }
171 
172 sub got_add {
173 	return got 'add', '-I', shift;
174 }
175 
176 sub got_rm {
177 	got 'remove', '-f', shift
178 	    or exit(1);
179 }
180 
181 sub got_ci {
182 	my $pid = fork;
183 	die "failed to fork: $!" unless defined $pid;
184 
185 	if ($pid ne 0) {
186 		wait;
187 		die "failed to commit changes" if $?;
188 		return;
189 	}
190 
191 	open (STDOUT, ">&", \*STDERR)
192 	    or die "can't redirect stdout to stderr";
193 	exec ($got, 'commit', '-m', shift)
194 	    or die "failed to exec $got: $!";
195 }
196 
197 
198 # cmds
199 
200 sub cmd_cat {
201 	GetOptions('h|?' => \&usage) or usage;
202 	usage unless @ARGV;
203 
204 	while (@ARGV) {
205 		my $file = name2file(shift @ARGV);
206 		system ($gpg, @gpg_flags, '-d', $file);
207 		die "failed to exec $gpg: $!" if $? == -1;
208 	}
209 }
210 
211 sub cmd_find {
212 	GetOptions('h|?' => \&usage) or usage;
213 	usage if @ARGV gt 1;
214 
215 	map { say $_ } passfind(shift @ARGV);
216 }
217 
218 sub cmd_gen {
219 	my $chars = $default_chars;
220 	my $length = $default_length;
221 	my $nop;
222 	my $q;
223 
224 	GetOptions(
225 		'c=s' => sub { $chars = $_[1] },
226 		'h|?' => \&usage,
227 		'l=i' => sub { $length = $_[1] },
228 		'n'   => \$nop,
229 		'q'   => \$q,
230 	    ) or usage;
231 	usage if @ARGV ne 1;
232 
233 	my $name = shift @ARGV;
234 	my $file = name2file $name;
235 	my $renamed = -f $file;
236 
237 	my $pass = gen($chars, $length);
238 
239 	unless ($nop) {
240 		writepass($file, $pass);
241 		got_add $file;
242 		got_ci($renamed ? "update $name" : "+$name");
243 	}
244 	say $pass unless $q;
245 }
246 
247 sub cmd_got {
248 	exec $got, @ARGV;
249 }
250 
251 # TODO: handle moving directories?
252 sub cmd_mv {
253 	GetOptions('h|?' => \&usage) or usage;
254 	usage if @ARGV ne 2;
255 
256 	my $a = shift @ARGV;
257 	my $b = shift @ARGV;
258 
259 	my $pa = name2file $a;
260 	my $pb = name2file $b;
261 
262 	die "source password doesn't exist" unless -f $pa;
263 	die "target password exists" if -f $pb;
264 
265 	rename $pa, $pb or die "can't rename $a to $b: $!";
266 
267 	got_rm $pa;
268 	got_add $pb or die "can't add $pb\n";
269 	got_ci "mv $a $b";
270 }
271 
272 sub cmd_rm {
273 	GetOptions('h|?' => \&usage) or usage;
274 	usage unless @ARGV;
275 
276 	while (@ARGV) {
277 		my $name = shift @ARGV;
278 		my $file = name2file $name;
279 
280 		got_rm $file;
281 		got_ci "-$name";
282 	}
283 }
284 
285 sub cmd_tee {
286 	my $q;
287 	GetOptions(
288 		'h|?' => \&usage,
289 		'q'   => \$q,
290 	    ) or usage;
291 	usage if @ARGV ne 1;
292 
293 	my $name = shift @ARGV;
294 	my $file = name2file $name;
295 
296 	my $pass = readpass "Enter the password: ";
297 	writepass($file, $pass);
298 
299 	got_add $file;
300 	got_ci (-f $file ? "update $name" : "+$name");
301 	say $pass unless $q;
302 }
303 
304 sub cmd_tog {
305 	exec $tog, @ARGV;
306 }