1 >                            0 in the zeroth cell
2 +++++++>++++++++++[<+++++>-] 57 in the first cell or "9"
3 +++++++>++++++++++[<+++++>-] 57 in second cell or "9"
4 ++++++++++                   10 in third cell
5 >+++++++++                    9 in fourth cell
6 
7 ##########################################
8 ### create ASCII chars in higher cells ###
9 ##########################################
10 
11 >>++++++++[<++++>-]               " "
12 >++++++++++++++[<+++++++>-]        b
13 +>+++++++++++[<++++++++++>-]       o
14 ++>+++++++++++++++++++[<++++++>-]  t
15 ++>+++++++++++++++++++[<++++++>-]  t
16 >++++++++++++[<+++++++++>-]        l
17 +>++++++++++[<++++++++++>-]        e
18 +>+++++++++++++++++++[<++++++>-]   s
19 >++++++++[<++++>-]                " "
20 +>+++++++++++[<++++++++++>-]       o
21 ++>++++++++++[<++++++++++>-]       f
22 >++++++++[<++++>-]                " "
23 >++++++++++++++[<+++++++>-]        b
24 +>++++++++++[<++++++++++>-]        e
25 +>++++++++++[<++++++++++>-]        e
26 >+++++++++++++++++++[<++++++>-]    r
27 >++++++++[<++++>-]                " "
28 +>+++++++++++[<++++++++++>-]       o
29 >+++++++++++[<++++++++++>-]        n
30 >++++++++[<++++>-]                " "
31 ++>+++++++++++++++++++[<++++++>-]  t
32 ++++>++++++++++[<++++++++++>-]     h
33 +>++++++++++[<++++++++++>-]        e
34 >++++++++[<++++>-]                " "
35 ++>+++++++++++++[<+++++++++>-]     w
36 +>++++++++++++[<++++++++>-]        a
37 >++++++++++++[<+++++++++>-]        l
38 >++++++++++++[<+++++++++>-]        l
39 >+++++[<++>-]                      LF
40 ++>+++++++++++++++++++[<++++++>-]  t
41 +>++++++++++++[<++++++++>-]        a
42 +++>+++++++++++++[<++++++++>-]     k
43 +>++++++++++[<++++++++++>-]        e
44 >++++++++[<++++>-]                " "
45 +>+++++++++++[<++++++++++>-]       o
46 >+++++++++++[<++++++++++>-]        n
47 +>++++++++++[<++++++++++>-]        e
48 >++++++++[<++++>-]                " "
49 >++++++++++[<++++++++++>-]         d
50 +>+++++++++++[<++++++++++>-]       o
51 ++>+++++++++++++[<+++++++++>-]     w
52 >+++++++++++[<++++++++++>-]        n
53 >++++++++[<++++>-]                " "
54 +>++++++++++++[<++++++++>-]        a
55 >+++++++++++[<++++++++++>-]        n
56 >++++++++++[<++++++++++>-]         d
57 >++++++++[<++++>-]                " "
58 ++>+++++++++++[<++++++++++>-]      p
59 +>++++++++++++[<++++++++>-]        a
60 +>+++++++++++++++++++[<++++++>-]   s
61 +>+++++++++++++++++++[<++++++>-]   s
62 >++++++++[<++++>-]                " "
63 +>+++++++++++++[<++++++++>-]       i
64 ++>+++++++++++++++++++[<++++++>-]  t
65 >++++++++[<++++>-]                " "
66 +>++++++++++++[<++++++++>-]        a
67 >+++++++++++++++++++[<++++++>-]    r
68 +>+++++++++++[<++++++++++>-]       o
69 >+++++++++++++[<+++++++++>-]       u
70 >+++++++++++[<++++++++++>-]        n
71 >++++++++++[<++++++++++>-]         d
72 >+++++[<++>-]                      LF
73 +++++++++++++                      CR
74 
75 [<]>>>>      go back to fourth cell
76 
77 #################################
78 ### initiate the display loop ###
79 #################################
80 
81 [            loop
82  <           back to cell 3
83  [            loop
84   [>]<<       go to last cell and back to LF
85   ..          output 2 newlines
86   [<]>        go to first cell
87 
88  ###################################
89  #### begin display of characters###
90  ###################################
91  #
92  #.>.>>>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>
93  #X X     b o t t l e s   o f   b e e r  
94  #.>.>.>.>.>.>.>.>.>.>.>.
95  #o n   t h e   w a l l N
96  #[<]>    go to first cell
97  #.>.>>>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>>>>>>>>>>>>>.>
98  #X X     b o t t l e s   o f   b e e r             N
99  #.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>
100  #t a k e   o n e   d o w n   a n d   p a s s   
101  #.>.>.>.>.>.>.>.>.>.
102  #i t   a r o u n d N
103  #####
104 
105   [<]>>      go to cell 2
106   -          subtract 1 from cell 2
107   <          go to cell 1
108 
109  ########################
110  ### display last line ##
111  ########################
112  #
113  #.>.>>>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>
114  #X X     b o t t l e s   o f   b e e r  
115  #.>.>.>.>.>.>.>.>.>.>.
116  #o n   t h e   w a l l
117  #####
118 
119   [<]>>>-      go to cell 3/subtract 1
120  ]            end loop when cell 3 is 0
121  ++++++++++   add 10 to cell 3
122  <++++++++++  back to cell 2/add 10
123  <-           back to cell 1/subtract 1
124  [>]<.        go to last line/carriage return
125  [<]>         go to first line
126 
127 ########################
128 ### correct last line ##
129 ########################
130 #
131 #.>.>>>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>
132 #X X     b o t t l e s   o f   b e e r  
133 #.>.>.>.>.>.>.>.>.>.>.
134 #o n   t h e   w a l l
135 #####
136 
137  [<]>>>>-    go to cell 4/subtract 1
138 ]           end loop when cell 4 is 0
139 
140 ##############################################################
141 ### By this point verses 99\10 are displayed but to work   ###
142 ### with the lower numbered verses in a more readable way  ###
143 ### we initiate a new loop for verses 9{CODE} that will not    ###
144 ### use the fourth cell at all                             ###
145 ##############################################################
146 
147 +           add 1 to cell four (to keep it non\zero)
148 <--         back to cell 3/subtract 2
149 
150 [            loop
151  [>]<<       go to last cell and back to LF
152  ..          output 2 newlines
153  [<]>        go to first cell
154 
155  ###################################
156  #### begin display of characters###
157  ###################################
158  #
159  #>.>>>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>
160  # X     b o t t l e s   o f   b e e r  
161  #.>.>.>.>.>.>.>.>.>.>.>.
162  #o n   t h e   w a l l N
163  #[<]>    go to first cell
164  #>.>>>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>>>>>>>>>>>>>.>
165  # X     b o t t l e s   o f   b e e r             N
166  #.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>
167  #t a k e   o n e   d o w n   a n d   p a s s   
168  #.>.>.>.>.>.>.>.>.>.
169  #i t   a r o u n d N
170  #####
171 
172  [<]>>       go to cell 2
173  -           subtract 1 from cell 2
174 
175  ########################
176  ### display last line ##
177  ########################
178  #
179  #.>>>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>
180  #X     b o t t l e s   o f   b e e r  
181  #.>.>.>.>.>.>.>.>.>.>.
182  #o n   t h e   w a l l
183  #####
184 
185  [<]>>>-     go to cell 3/subtract 1
186 ]            end loop when cell 3 is 0
187 +            add 1 to cell 3 to keep it non\zero
188 
189 [>]<.        go to last line/carriage return
190 [<]>         go to first line
191 
192 ########################
193 ### correct last line ##
194 ########################
195 #
196 #>.>>>.>.>.>.>.>.>.>>.>.>.>.>.>.>.>.>.>
197 # X     b o t t l e    o f   b e e r  
198 #.>.>.>.>.>.>.>.>.>.>.<<<<.
199 #o n   t h e   w a l l
200 #####
201 
202 [>]<<       go to last cell and back to LF
203 ..          output 2 newlines
204 [<]>        go to first line
205 
206 #########################
207 ### the final verse    ##
208 #########################
209 #
210 #>.>>>.>.>.>.>.>.>.>>.>.>.>.>.>.>.>.>.>
211 # X     b o t t l e    o f   b e e r  
212 #.>.>.>.>.>.>.>.>.>.>.>.
213 #o n   t h e   w a l l N
214 #[<]>        go to first cell
215 #>.>>>.>.>.>.>.>.>.>>.>.>.>.>.>.>.>.>>>>>>>>>>>>>.>
216 # X     b o t t l e    o f   b e e r             N
217 #.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>
218 #t a k e   o n e   d o w n   a n d   p a s s   
219 #.>.>.>.>.>.>.>.>.>.
220 #i t   a r o u n d N
221 #[>]<        go to last line
222 #<<<.<<.<<<.
223 #   n  o    
224 #[<]>>>>     go to fourth cell
225 #>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>.>
226 #   b o t t l e s   o f   b e e r  
227 #.>.>.>.>.>.>.>.>.>.>.>.
228 #o n   t h e   w a l l N
229 #####fin##
230