1 #!/usr/bin/env perl
2 #
3 # Copyright (c) 2022, 2023 Omar Polo <op@omarpolo.com>
4 #
5 # Permission to use, copy, modify, and distribute this software for any
6 # purpose with or without fee is hereby granted, provided that the above
7 # copyright notice and this permission notice appear in all copies.
8 #
9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
16 
17 use strict;
18 use warnings;
19 use v5.32;
20 
21 use open ":std", ":encoding(UTF-8)";
22 
23 use Getopt::Long qw(:config bundling require_order);
24 use File::Basename;
25 use File::Find;
26 use File::Temp qw(tempfile);
27 
28 my $store = $ENV{'PLASS_STORE'} // $ENV{'HOME'}.'/.password-store';
29 
30 my $gpg = $ENV{'PLASS_GPG'} // 'gpg';
31 my @gpg_flags = qw(--quiet --compress-algo=none --no-encrypt-to --use-agent);
32 
33 my %subcmd = (
34 	cat	=> [\&cmd_cat,		"entries..."],
35 	edit	=> [\&cmd_edit,		"entry"],
36 	find	=> [\&cmd_find,		"[pattern]"],
37 	mv	=> [\&cmd_mv,		"from to"],
38 	rm	=> [\&cmd_rm,		"entries..."],
39 	tee	=> [\&cmd_tee,		"[-q] entry"],
40     );
41 
42 my $usage = "[-h] command [argument ...]";
43 my $cmd;
44 sub usage {
45 	my $prog = basename $0;
46 	if (defined($cmd) and defined($subcmd{$cmd})) {
47 		say STDERR "Usage: $prog $cmd $usage";
48 	} else {
49 		say STDERR "Usage: $prog $usage";
50 		say STDERR "unknown command $cmd" if defined($cmd);
51 		say STDERR "commands: ", join(' ', sort(keys %subcmd));
52 	}
53 	exit 1;
54 }
55 
56 GetOptions("h|?" => \&usage) or usage();
57 
58 $cmd = shift // 'find';
59 usage() unless defined $subcmd{$cmd};
60 my $fn;
61 ($fn, $usage) = @{$subcmd{$cmd}};
62 chdir $store;
63 $fn->();
64 exit 0;
65 
66 
67 # utils
68 
69 sub name2file {
70 	my $f = shift;
71 	$f .= ".gpg" unless $f =~ m,\.gpg$,;
72 	return $f;
73 }
74 
75 sub mkdirs {
76 	my $dir = shift;
77 	my $parent = dirname $dir;
78 	mkdirs($parent) unless -d $parent || $parent eq '/';
79 	mkdir $dir or die "mkdir $dir: $!"
80 	    unless -d $dir;
81 }
82 
83 sub writepass {
84 	my ($file, $pass) = @_;
85 
86 	mkdirs(dirname $file);
87 
88 	# temporary redirect stdout to $file
89 	open(my $stdout, '>&', STDOUT);
90 	open(STDOUT, '>', $file);
91 
92 	my @args = ($gpg, @gpg_flags, '-e', '-r', recipient(),
93 	    '-o', '-');
94 	open my $fh, '|-', @args;
95 	print $fh "$pass";
96 	close($fh);
97 	my $ok = !$?;
98 
99 	open(STDOUT, '>&', $stdout); # restore stdout
100 
101 	die "failed to run $gpg\n" unless $ok;
102 }
103 
104 sub recipient {
105 	open my $fh, '<', "$store/.gpg-id"
106 	    or die "can't open recipient file";
107 	my $r = <$fh>;
108 	chomp $r;
109 	close($fh);
110 	return $r;
111 }
112 
113 sub passfind {
114 	my $pattern = shift;
115 	my @entries;
116 
117 	find({
118 		wanted => sub {
119 			if (m,/.git$, || m,/.got$,) {
120 				$File::Find::prune = 1;
121 				return;
122 			}
123 			return unless -f && m,.gpg$,;
124 
125 			s,^$store/*,,;
126 			s,.gpg$,,;
127 
128 			return if defined($pattern) && ! m/$pattern/i;
129 			push @entries, $_;
130 		},
131 		no_chdir => 1,
132 		follow_fast => 1,
133 	     }, ($store));
134 	return sort(@entries);
135 }
136 
137 sub got {
138 	# discard stdout
139 	open my $fh, '-|', ('got', @_);
140 	close($fh);
141 	return !$?;
142 }
143 
144 sub got_add {
145 	return got 'add', '-I', shift;
146 }
147 
148 sub got_rm {
149 	got 'remove', '-f', shift
150 	    or exit(1);
151 }
152 
153 sub got_ci {
154 	my $pid = fork;
155 	die "failed to fork: $!" unless defined $pid;
156 
157 	if ($pid != 0) {
158 		wait;
159 		die "failed to commit changes" if $?;
160 		return;
161 	}
162 
163 	open (STDOUT, ">&", \*STDERR)
164 	    or die "can't redirect stdout to stderr";
165 	exec ('got', 'commit', '-m', shift)
166 	    or die "failed to exec got: $!";
167 }
168 
169 
170 # cmds
171 
172 sub cmd_cat {
173 	GetOptions('h|?' => \&usage) or usage;
174 	usage unless @ARGV;
175 
176 	while (@ARGV) {
177 		my $file = name2file(shift @ARGV);
178 		system ($gpg, @gpg_flags, '-d', $file);
179 		die "failed to exec $gpg: $!" if $? == -1;
180 	}
181 }
182 
183 sub cmd_edit {
184 	GetOptions('h|?' => \&usage) or usage;
185 	usage if @ARGV != 1;
186 
187 	my $editor = $ENV{'VISUAL'} // $ENV{'EDITOR'} // 'ed';
188 
189 	my $entry = shift @ARGV;
190 	my $epath = name2file $entry;
191 
192 	my ($fh, $filename) = tempfile "/tmp/plass-XXXXXXXXXX";
193 
194 	open (my $stdout, ">&", STDOUT) or die "can't redirect stdout: $!";
195 
196 	open (STDOUT, ">&", $fh) or die "can't redirect stdout to $filename";
197 	system ($gpg, @gpg_flags, '-d', $epath);
198 	die "$gpg exited with $?\n" if $? != 0;
199 
200 	# restore stdout so the editor can access the TTY if needed.
201 	open (STDOUT, ">&", $stdout) or die "can't restore stdout: $!";
202 
203 	my $oldtime = (stat($fh))[9];
204 
205 	system ($editor, $filename);
206 	die "editor $editor failed\n" if $? != 0;
207 
208 	my $newtime = (stat($filename))[9];
209 
210 	if ($oldtime == $newtime) {
211 		say STDERR "no changes made.";
212 		unlink $filename or die "can't delete $filename: $!\n";
213 		return
214 	}
215 
216 	open(STDIN, '<', $filename) or die "can't redirect stdin: $!";
217 	open(STDOUT, '>', $epath) or die "can't redirect stdout: $!";
218 	system ($gpg, @gpg_flags, '-e', '-r', recipient(), '-o', '-');
219 	unlink $filename or die "can't delete $filename: $!\n";
220 	die "gpg failed" if $? != 0;
221 
222 	got_add $epath;
223 	got_ci "update $entry";
224 }
225 
226 sub cmd_find {
227 	GetOptions('h|?' => \&usage) or usage;
228 	usage if @ARGV > 1;
229 
230 	map { say $_ } passfind(shift @ARGV);
231 }
232 
233 # TODO: handle moving directories?
234 sub cmd_mv {
235 	GetOptions('h|?' => \&usage) or usage;
236 	usage if @ARGV != 2;
237 
238 	my $a = shift @ARGV;
239 	my $b = shift @ARGV;
240 
241 	my $pa = name2file $a;
242 	my $pb = name2file $b;
243 
244 	die "source password doesn't exist" unless -f $pa;
245 	die "target password exists" if -f $pb;
246 
247 	mkdirs(dirname $pb);
248 	rename $pa, $pb or die "can't rename $a to $b: $!";
249 
250 	got_rm $pa;
251 	got_add $pb or die "can't add $pb\n";
252 	got_ci "mv $a $b";
253 }
254 
255 sub cmd_rm {
256 	GetOptions('h|?' => \&usage) or usage;
257 	usage unless @ARGV;
258 
259 	while (@ARGV) {
260 		my $name = shift @ARGV;
261 		my $file = name2file $name;
262 
263 		got_rm $file;
264 		got_ci "-$name";
265 	}
266 }
267 
268 sub cmd_tee {
269 	my $q;
270 	GetOptions(
271 		'h|?' => \&usage,
272 		'q'   => \$q,
273 	    ) or usage;
274 	usage if @ARGV != 1;
275 
276 	my $name = shift @ARGV;
277 	my $file = name2file $name;
278 
279 	my $msg = -f $file ? "update $name" : "+$name";
280 
281 	my $pass = "";
282 	$pass .= $_ while <STDIN>;
283 	die "No content!\n" if $pass eq "";
284 
285 	writepass($file, $pass);
286 
287 	got_add $file;
288 	got_ci $msg;
289 	print $pass unless $q;
290 }