1 #!/usr/bin/env perl
2 
3 use open ":std", ":encoding(UTF-8)";
4 use utf8;
5 use strict;
6 use warnings;
7 use v5.32;
8 
9 use OpenBSD::Pledge;
10 use OpenBSD::Unveil;
11 
12 use lib ".";
13 use GotMArc qw(parse san initpage endpage index_header thread_header);
14 
15 my $outdir = $ENV{'OUTDIR'};
16 die 'Set $OUTDIR' unless defined $outdir;
17 
18 my $tfh; # thread file handle
19 my $pfh; # page file handle
20 my $page = 0;
21 my @pages;
22 my $from_day;
23 my $to_day;
24 my $threads_seen = 0;
25 my $last_level = 0;
26 my $threads = 0;
27 my $threads_per_page = 100;
28 
29 sub maxs {
30 	my ($a, $b) = @_;
31 	return $a unless defined $b;
32 	return $a gt $b ? $a : $b;
33 }
34 
35 sub mins {
36 	my ($a, $b) = @_;
37 	return $a unless defined $b;
38 	return $a lt $b ? $a : $b;
39 }
40 
41 sub pagename {
42 	my $i = shift;
43 	return $i == 1 && "index.html" || "$i.html";
44 }
45 
46 sub endfile {
47 	say $pfh '</ul></div>';
48 	close($pfh);
49 	push @pages, "$from_day - $to_day";
50 }
51 
52 sub nextfile {
53 	endfile if defined $pfh;
54 	$page += 1;
55 	my $path = pagename($page);
56 
57 	# XXX: mkstemp would be better...
58 	open($pfh, '>', "/tmp/$path")
59 	    or die "can't open $path: $!";
60 	say $pfh "<div class='thread'><ul>";
61 }
62 
63 sub nav {
64 	my ($pfh, $n) = @_;
65 	my ($first, $last) = (pagename(1), pagename($page));
66 	my ($next, $prev) = (pagename($n+1), pagename($n-1));
67 
68 	say $pfh "<nav>";
69 	say $pfh "<a href='$first'>First</a>" if $n > 2;
70 	say $pfh "<a href='$prev'>Prev</a>" if $n > 1;
71 	say $pfh "<a href='$next'>Next</a>" if $n < $page;
72 	say $pfh "<a href='$last'>Last</a>" if $n < $page - 1;
73 	say $pfh "</nav>";
74 }
75 
76 sub copyfrom {
77 	my ($path, $fh) = @_;
78 
79 	# there are probably faster ways to do this like File::Copy,
80 	# but it bypasses the bufio cache...
81 	open(my $pfh, '<', $path) or die "can't open $path: $!";
82 	print $fh $_ while (<$pfh>);
83 }
84 
85 sub renderpages {
86 	close($pfh);
87 
88 	for (my $i = 1; $i <= $page; $i++) {
89 		my $name = pagename($i);
90 		my $path = "/tmp/$name";
91 		my $dest = "$outdir/$name";
92 
93 		open(my $pfh, '>', $dest)
94 		    or die "can't open $dest for writing: $!";
95 
96 		my $title = "Game of Trees Mail Archive | page $i";
97 		my $subtitle = $pages[$i-1];
98 
99 		initpage($pfh, $title);
100 		index_header $pfh, $i, $subtitle;
101 		say $pfh "<main>";
102 
103 		nav $pfh, $i if $page > 1;
104 		copyfrom($path, $pfh);
105 		nav $pfh, $i if $page > 1;
106 
107 		say $pfh "</main>";
108 		endpage($pfh);
109 
110 		close($pfh);
111 		unlink $path;
112 	}
113 }
114 
115 sub endthread {
116 	say $tfh "</ul></li>" x $last_level;
117 	say $tfh "</ul>\n</div>\n";
118 	endpage($tfh);
119 	close($tfh);
120 
121 	$last_level = 0;
122 }
123 
124 sub nextthread {
125 	endthread if defined $tfh;
126 	my ($mid, $subj) = @_;
127 	my $dest = "$outdir/thread/$mid.html";
128 	open($tfh, '>', $dest) or die "can't open $dest: $!";
129 	initpage($tfh, $subj);
130 	thread_header $tfh, undef, undef, ["Thread: $subj"];
131 	print $tfh "<div class='thread'><ul class='mails'>\n";
132 }
133 
134 sub entry {
135 	my ($fh, $type, $mid, $date, $from, $subj) = @_;
136 	print $fh "<li id='$mid' class='mail'>";
137 	print $fh "<p class='mail-meta'>";
138 	print $fh "<time>$date</time> ";
139 	print $fh "<span class='from'>$from</span>";
140 	print $fh "<span class='colon'>:</span>";
141 	print $fh "</p>";
142 	print $fh "<p class='subject'>";
143 	print $fh "<a href='/$type/$mid.html'>$subj</a>";
144 	print $fh "</p>";
145 	print $fh "</li>\n";
146 }
147 
148 sub thread_entry {
149 	my ($fh, $mid, $level, $date, $from, $subj) = @_;
150 
151 	say $fh "</ul>\n</li>" x ($last_level - $level) if $last_level > $level;
152 	say $fh "<li>\n<ul>" if $last_level < $level;
153 
154 	entry $fh, "mail", $mid, $date, $from, $subj;
155 }
156 
157 unveil($outdir, "rwc") or die "unveil $outdir: $!";
158 unveil(".", "r") or die "unveil .: $!";
159 unveil("/tmp", "rwc") or die "unveil /tmp: $!";
160 
161 pledge("stdio rpath wpath cpath") or die "pledge: $!";
162 
163 nextfile;
164 
165 while (<>) {
166 	my ($level, $fname, $mid, $date, $from, $subj) = parse;
167 
168 	if ($level == 0) {
169 		nextthread $mid, $subj;
170 
171 		$threads++;
172 		if ($threads > $threads_per_page) {
173 			nextfile;
174 			$threads = 0;
175 			$to_day = undef;
176 			$from_day = undef;
177 		}
178 
179 		my $day = $date =~ s/ .*//r;
180 		$to_day = mins $day, $to_day;
181 		$from_day = maxs $day, $from_day;
182 
183 		entry $pfh, "thread", $mid, $date, $from, $subj;
184 	}
185 
186 	thread_entry $tfh, $mid, $level, $date, $from, $subj;
187 	$last_level = $level;
188 	$threads_seen = 1;
189 }
190 
191 endfile;
192 endthread if $threads_seen;
193 renderpages;