1 AC_INIT([telescope], [0.1], [telescope@omarpolo.com], [telescope], [gemini://telescope.omarpolo.com])
2 AC_CONFIG_LIBOBJ_DIR(compat)
3 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects])
4 AC_PROG_CC
5 
6 PKG_PROG_PKG_CONFIG
7 
8 AC_REPLACE_FUNCS([
9 	asprintf \
10 	err \
11 	freezero \
12 	getdtablecount \
13 	getdtablesize \
14 	getprogname \
15 	memmem \
16 	recallocarray \
17 	strlcat \
18 	strlcpy \
19 	strtonum \
20 	setproctitle \
21 ])
22 
23 AC_CHECK_DECL(PR_SET_NAME, AC_DEFINE([HAVE_PR_SET_NAME], 1, [pr_set_name]), [],
24 	[[#include <sys/prctl.h>]])
25 
26 AC_SEARCH_LIBS([initscr], [ncursesw ncurses], [], [
27 	AC_MSG_ERROR([requires either ncursesw or ncurses library])
28 ])
29 
30 AC_CHECK_LIB(tls, tls_init, [], [
31 	AC_MSG_ERROR([requires libtls])
32 ])
33 
34 AC_CHECK_LIB(event, event_init, [], [
35 	AC_MSG_ERROR([requires libevent])
36 ])
37 
38 AC_CHECK_LIB(util, imsg_init, [], [
39 	AC_LIBOBJ(imsg)
40 	AC_LIBOBJ(imsg-buffer)
41 	AC_LIBOBJ(ohash)
42 ])
43 
44 AC_CHECK_FUNCS([asr_run])
45 
46 # check compiler flags
47 AC_DEFUN([CC_ADD_CHECK_FLAGS], [
48 	AC_MSG_CHECKING([if $CC supports $1 flag])
49 	old_CFLAGS="$CFLAGS"
50 	CFLAGS="$CFLAGS $1"
51 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
52 		AC_MSG_RESULT(yes),
53 		AC_MSG_RESULT(no)
54 		CFLAGS="$old_CFLAGS")
55 ])
56 CC_ADD_CHECK_FLAGS([-Wall])
57 CC_ADD_CHECK_FLAGS([-Wextra])
58 CC_ADD_CHECK_FLAGS([-Wmissing-prototypes])
59 CC_ADD_CHECK_FLAGS([-Wstrict-prototypes])
60 CC_ADD_CHECK_FLAGS([-Wwrite-strings])
61 CC_ADD_CHECK_FLAGS([-Wno-unused-parameter])
62 
63 AC_CONFIG_HEADERS([config.h])
64 AC_CONFIG_FILES([
65 	Makefile
66 ])
67 
68 AC_OUTPUT