1 AC_INIT([kamid], [0.1], [kamid@omarpolo.com], [],
2 	[https://kamid.omarpolo.com])
3 AC_CONFIG_AUX_DIR(etc)
4 AC_CONFIG_LIBOBJ_DIR(compat)
5 AM_INIT_AUTOMAKE([foreign subdir-objects])
6 
7 KAMID_RELEASE=No
8 
9 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
10 AC_SUBST(VERSION)
11 AC_SUBST(KAMID_RELEASE)
12 
13 AC_CANONICAL_HOST
14 
15 # When CFLAGS isn't set at this stage and gcc is detected by the macro below,
16 # autoconf will automatically use CFLAGS="-O2 -g". Prevent that by using an
17 # empty default.
18 : ${CFLAGS=""}
19 
20 # Save user CPPFLAGS, CFLAGS and LDFLAGS. We need to change them because
21 # AC_CHECK_HEADER doesn't give us any other way to update the include
22 # paths. But for Makefile.am we want to use AM_CPPFLAGS and friends.
23 SAVED_CFLAGS="$CFLAGS"
24 SAVED_CPPFLAGS="$CPPFLAGS"
25 SAVED_LDFLAGS="$LDFLAGS"
26 
27 # Checks for programs.
28 AC_PROG_CC
29 AC_PROG_CPP
30 AC_PROG_INSTALL
31 AC_PROG_LN_S
32 AC_PROG_MAKE_SET
33 AC_PROG_YACC
34 PKG_PROG_PKG_CONFIG
35 AC_USE_SYSTEM_EXTENSIONS
36 
37 # Some functions can be in libbsd.  Thanks to lldpb for the inspiration :)
38 AC_ARG_WITH([libbsd],
39   AS_HELP_STRING([--with-libbsd], [Use libbsd @<:@default=auto@:>@]),
40   [],
41   [with_libbsd=auto])
42 if test x"$with_libbsd" != x"no"; then
43   PKG_CHECK_MODULES([libbsd], [libbsd-overlay libbsd-ctor], [
44     _save_AM_CFLAGS="$AM_CFLAGS"
45     _save_LIBS="$LIBS"
46     AM_CFLAGS="$AM_CFLAGS $libbsd_CFLAGS"
47     LIBS="$LIBS $libbsd_LIBS"
48   ], [
49     if test x"$with_libbsd" = x"yes"; then
50        AC_MSG_FAILURE([*** no libbsd support found])
51     fi
52     with_libbsd=no
53   ])
54 fi
55 
56 AC_REPLACE_FUNCS([
57 	asprintf	\
58 	err		\
59 	freezero	\
60 	getdtablecount	\
61 	getdtablesize	\
62 	getprogname	\
63 	memmem		\
64 	recallocarray	\
65 	setproctitle	\
66 	setprogname	\
67 	strlcat		\
68 	strlcpy		\
69 	strsep		\
70 	strtonum	\
71 	vis		\
72 ])
73 
74 AC_MSG_CHECKING([for sys/queue.h with TAILQ_FOREACH_SAFE and STAILQ_ENTRY])
75 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
76 #include <sys/queue.h>
77 #include <stddef.h>
78 ], [
79 	TAILQ_HEAD(tailhead, entry) head;
80 	struct entry {
81 		TAILQ_ENTRY(entry) entries;
82 	} *np, *nt;
83 	TAILQ_INIT(&head);
84 	TAILQ_FOREACH_SAFE(np, &head, entries, nt) {
85 		/* nop */ ;
86 	}
87 
88 	STAILQ_HEAD(listhead, qentry) qhead = STAILQ_HEAD_INITIALIZER(qhead);
89 	struct qentry {
90 		STAILQ_ENTRY(qentry) entries;
91 	} foo;
92 
93 	return 0;
94 ])], [
95 	AC_MSG_RESULT(yes)
96 	AC_DEFINE([HAVE_QUEUE_H], 1, [QUEUE_H])
97 ], AC_MSG_RESULT(no))
98 
99 AC_CHECK_HEADERS([sys/tree.h])
100 
101 AC_CHECK_DECL(PR_SET_NAME, AC_DEFINE([HAVE_PR_SET_NAME], 1, [pr_set_name]), [],
102 	[[#include <sys/prctl.h>]])
103 
104 AC_CHECK_LIB([crypto], [RAND_add], [], [
105 	AC_MSG_ERROR([requires openssl])
106 ])
107 
108 AC_CHECK_LIB(tls, tls_init, [], [
109 	AC_MSG_ERROR([requires libtls])
110 ])
111 
112 AS_CASE([$host_os],
113 	[*openbsd*], [AC_CHECK_LIB([event], [event_init], [],
114 			[AC_MSG_ERROR([requires libevent])])],
115 	[PKG_CHECK_MODULES([libevent2], [libevent_core >= 2],
116 		[
117 			AC_DEFINE([HAVE_EVENT2], 1, [1 if using event2])
118 			AM_CFLAGS="$libevent2_CFLAGS $AM_CFLAGS"
119 			LIBS="$libevent2_LIBS $LIBS"
120 		], [AC_MSG_ERROR([requires libevent])])])
121 
122 AC_CHECK_LIB(util, imsg_init, [], [
123 	AC_LIBOBJ(fmt_scaled)
124 	AC_LIBOBJ(imsg)
125 	AC_LIBOBJ(imsg-buffer)
126 	AC_LIBOBJ(ohash)
127 ])
128 
129 # Check for readline
130 AS_CASE([$host_os],
131 	[*openbsd*], [
132 		AC_DEFINE([HAVE_READLINE], 1, [1 if readline found])
133 		READLINE_CFLAGS=''
134 		READLINE_LIBS='-lreadline'
135 	], [
136 		PKG_CHECK_MODULES([READLINE], [readline], [
137 			AC_DEFINE([HAVE_READLINE], 1, [])
138 		], [
139 			AC_DEFINE([HAVE_READLINE], 0, [])
140 		])
141 	]
142 )
143 AC_SUBST(READLINE_CFLAGS)
144 AC_SUBST(READLINE_LIBS)
145 
146 # check compiler flags
147 AC_DEFUN([CC_ADD_CHECK_FLAGS], [
148 	AC_MSG_CHECKING([if $CC supports $1 flag])
149 	old_AM_CFLAGS="$AM_CFLAGS"
150 	AM_CFLAGS="$AM_CFLAGS $1"
151 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])],
152 		AC_MSG_RESULT(yes), [
153 			AC_MSG_RESULT(no)
154 			AM_CFLAGS="$old_AM_CFLAGS"
155 		])
156 ])
157 CC_ADD_CHECK_FLAGS([-Wall])
158 CC_ADD_CHECK_FLAGS([-Wextra])
159 CC_ADD_CHECK_FLAGS([-Wmissing-declarations])
160 CC_ADD_CHECK_FLAGS([-Wmissing-prototypes])
161 CC_ADD_CHECK_FLAGS([-Wstrict-prototypes])
162 CC_ADD_CHECK_FLAGS([-Wwrite-strings])
163 CC_ADD_CHECK_FLAGS([-Wno-unused-parameter])
164 CC_ADD_CHECK_FLAGS([-Wpointer-arith])
165 CC_ADD_CHECK_FLAGS([-Wsign-compare])
166 CC_ADD_CHECK_FLAGS([-Wcast-align])
167 
168 # Save our CFLAGS/CPPFLAGS/LDFLAGS for the Makefile and restore the old user
169 # variables.
170 AC_SUBST(AM_CPPFLAGS)
171 CPPFLAGS="$SAVED_CPPFLAGS"
172 AC_SUBST(AM_CFLAGS)
173 CFLAGS="$SAVED_CFLAGS"
174 AC_SUBST(AM_LDFLAGS)
175 LDFLAGS="$SAVED_LDFLAGS"
176 
177 AC_CONFIG_HEADERS([config.h])
178 AC_CONFIG_FILES([
179 	Makefile
180 	contrib/Makefile
181 	kamictl/Makefile
182 	kamid/Makefile
183 	kamiftp/Makefile
184 	kamirepl/Makefile
185 	ninepscript/Makefile
186 	regress/Makefile
187 	regress/lisp/Makefile
188 	regress/ninepscript/Makefile
189 ])
190 
191 AC_OUTPUT