1 #!/usr/bin/env perl
2 #
3 # Copyright (c) 2022, 2023 Omar Polo <op@omarpolo.com>
4 #
5 # Permission to use, copy, modify, and distribute this software for any
6 # purpose with or without fee is hereby granted, provided that the above
7 # copyright notice and this permission notice appear in all copies.
8 #
9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
16 
17 use strict;
18 use warnings;
19 use v5.32;
20 
21 use open ":std", ":encoding(UTF-8)";
22 
23 use Getopt::Long qw(:config bundling require_order);
24 use File::Basename;
25 use File::Find;
26 use File::Temp qw(tempfile);
27 
28 my $store = $ENV{'PLASS_STORE'} // $ENV{'HOME'}.'/.password-store';
29 
30 my $gpg = $ENV{'PLASS_GPG'} // 'gpg';
31 my @gpg_flags = qw(--quiet --compress-algo=none --no-encrypt-to --use-agent);
32 
33 my %subcmd = (
34 	cat	=> [\&cmd_cat,		"entries..."],
35 	edit	=> [\&cmd_edit,		"entry"],
36 	find	=> [\&cmd_find,		"[pattern]"],
37 	mv	=> [\&cmd_mv,		"from to"],
38 	rm	=> [\&cmd_rm,		"entries..."],
39 	tee	=> [\&cmd_tee,		"[-q] entry"],
40     );
41 
42 my $usage = "[-h] command [argument ...]";
43 my $cmd;
44 sub usage {
45 	my $prog = basename $0;
46 	if (defined($cmd) and defined($subcmd{$cmd})) {
47 		say STDERR "Usage: $prog $cmd $usage";
48 	} else {
49 		say STDERR "Usage: $prog $usage";
50 		say STDERR "unknown command $cmd" if defined($cmd);
51 		say STDERR "commands: ", join(' ', sort(keys %subcmd));
52 	}
53 	exit 1;
54 }
55 
56 GetOptions("h|?" => \&usage) or usage();
57 
58 $cmd = shift // 'find';
59 usage() unless defined $subcmd{$cmd};
60 my $fn;
61 ($fn, $usage) = @{$subcmd{$cmd}};
62 chdir $store;
63 $fn->();
64 exit 0;
65 
66 
67 # utils
68 
69 sub name2file {
70 	my $f = shift;
71 	$f .= ".gpg" unless $f =~ m,\.gpg$,;
72 	return $f;
73 }
74 
75 sub mkdirs {
76 	my $dir = shift;
77 	my $parent = dirname $dir;
78 	mkdirs($parent) unless -d $parent || $parent eq '/';
79 	mkdir $dir or die "mkdir $dir: $!"
80 	    unless -d $dir;
81 }
82 
83 sub edit {
84 	my ($editor, $fh, $tempfile, $epath) = @_;
85 
86 	open (my $stdout, ">&", STDOUT) or die "can't redirect stdout: $!";
87 	open (STDOUT, ">&", $fh) or die "can't redirect stdout to $tempfile";
88 	system ($gpg, @gpg_flags, '-d', $epath);
89 	die "$gpg exited with $?\n" if $? != 0;
90 	open (STDOUT, ">&", $stdout) or die "can't restore stdout: $!";
91 
92 	my $oldtime = (stat($fh))[9];
93 	close($fh);
94 
95 	system ($editor, $tempfile);
96 	die "editor $editor failed\n" if $? != 0;
97 
98 	my $newtime = (stat($tempfile))[9];
99 	if ($oldtime == $newtime) {
100 		say STDERR "no changes made.";
101 		return
102 	}
103 
104 	open(STDOUT, '>', $epath) or die "can't redirect stdout: $!";
105 	system ($gpg, @gpg_flags, '-e', '-r', recipient(), '-o', '-',
106 	    $tempfile);
107 	die "gpg failed" if $? != 0;
108 }
109 
110 sub recipient {
111 	open my $fh, '<', "$store/.gpg-id"
112 	    or die "can't open recipient file";
113 	my $r = <$fh>;
114 	chomp $r;
115 	close($fh);
116 	return $r;
117 }
118 
119 sub passfind {
120 	my $pattern = shift;
121 	my @entries;
122 
123 	find({
124 		wanted => sub {
125 			if (m,/.git$, || m,/.got$,) {
126 				$File::Find::prune = 1;
127 				return;
128 			}
129 			return unless -f && m,.gpg$,;
130 
131 			s,^$store/*,,;
132 			s,.gpg$,,;
133 
134 			return if defined($pattern) && ! m/$pattern/i;
135 			push @entries, $_;
136 		},
137 		no_chdir => 1,
138 		follow_fast => 1,
139 	     }, ($store));
140 	return sort(@entries);
141 }
142 
143 sub got {
144 	# discard stdout
145 	open my $fh, '-|', ('got', @_);
146 	close($fh);
147 	return !$?;
148 }
149 
150 sub got_add {
151 	return got 'add', '-I', shift;
152 }
153 
154 sub got_rm {
155 	got 'remove', '-f', shift
156 	    or exit(1);
157 }
158 
159 sub got_ci {
160 	my $pid = fork;
161 	die "failed to fork: $!" unless defined $pid;
162 
163 	if ($pid != 0) {
164 		wait;
165 		die "failed to commit changes" if $?;
166 		return;
167 	}
168 
169 	open (STDOUT, ">&", \*STDERR)
170 	    or die "can't redirect stdout to stderr";
171 	exec ('got', 'commit', '-m', shift)
172 	    or die "failed to exec got: $!";
173 }
174 
175 
176 # cmds
177 
178 sub cmd_cat {
179 	GetOptions('h|?' => \&usage) or usage;
180 	usage unless @ARGV;
181 
182 	while (@ARGV) {
183 		my $file = name2file(shift @ARGV);
184 		system ($gpg, @gpg_flags, '-d', $file);
185 		die "failed to exec $gpg: $!" if $? == -1;
186 	}
187 }
188 
189 sub cmd_edit {
190 	GetOptions('h|?' => \&usage) or usage;
191 	usage if @ARGV != 1;
192 
193 	my $editor = $ENV{'VISUAL'} // $ENV{'EDITOR'} // 'ed';
194 
195 	my $entry = shift @ARGV;
196 	my $epath = name2file $entry;
197 
198 	my ($fh, $tempfile) = tempfile "/tmp/plass-XXXXXXXXXX";
199 	eval { edit $editor, $fh, $tempfile, $epath };
200 	unlink $tempfile;
201 	die "$@\n" if $@;
202 
203 	got_add $epath;
204 	got_ci "update $entry";
205 }
206 
207 sub cmd_find {
208 	GetOptions('h|?' => \&usage) or usage;
209 	usage if @ARGV > 1;
210 
211 	map { say $_ } passfind(shift @ARGV);
212 }
213 
214 # TODO: handle moving directories?
215 sub cmd_mv {
216 	GetOptions('h|?' => \&usage) or usage;
217 	usage if @ARGV != 2;
218 
219 	my $a = shift @ARGV;
220 	my $b = shift @ARGV;
221 
222 	my $pa = name2file $a;
223 	my $pb = name2file $b;
224 
225 	die "source password doesn't exist" unless -f $pa;
226 	die "target password exists" if -f $pb;
227 
228 	mkdirs(dirname $pb);
229 	rename $pa, $pb or die "can't rename $a to $b: $!";
230 
231 	got_rm $pa;
232 	got_add $pb or die "can't add $pb\n";
233 	got_ci "mv $a $b";
234 }
235 
236 sub cmd_rm {
237 	GetOptions('h|?' => \&usage) or usage;
238 	usage unless @ARGV;
239 
240 	while (@ARGV) {
241 		my $name = shift @ARGV;
242 		my $file = name2file $name;
243 
244 		got_rm $file;
245 		got_ci "-$name";
246 	}
247 }
248 
249 sub cmd_tee {
250 	my $q;
251 	GetOptions(
252 		'h|?' => \&usage,
253 		'q'   => \$q,
254 	    ) or usage;
255 	usage if @ARGV != 1;
256 
257 	my $name = shift @ARGV;
258 	my $file = name2file $name;
259 
260 	my $msg = -f $file ? "update $name" : "+$name";
261 	mkdirs(dirname $file);
262 
263 	my @args = ($gpg, @gpg_flags, '-e', '-r', recipient(),
264 	    '--batch', '--yes', '-o', $file);
265 	open my $fh, '|-', @args;
266 
267 	binmode(STDIN) or die "cannot binmode STDIN";
268 	binmode(STDOUT) or die "cannot binmode STDOUT";
269 	binmode($fh) or die "cannot binmode pipe";
270 
271 	local $/ = \1024;
272 	while (<STDIN>) {
273 		print $fh $_;
274 		print $_ unless $q;
275 	}
276 	close($fh);
277 	exit $? if $?;
278 
279 	got_add $file;
280 	got_ci $msg;
281 }