1 #!/usr/bin/env perl
2 #
3 # Copyright (c) 2022 Omar Polo <op@omarpolo.com>
4 #
5 # Permission to use, copy, modify, and distribute this software for any
6 # purpose with or without fee is hereby granted, provided that the above
7 # copyright notice and this permission notice appear in all copies.
8 #
9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
16 
17 use strict;
18 use warnings;
19 use v5.32;
20 
21 use open ":std", ":encoding(UTF-8)";
22 
23 use Getopt::Long qw(:config bundling require_order);
24 use File::Basename;
25 use File::Find;
26 
27 my $store = $ENV{'PLASS_STORE'} // $ENV{'HOME'}.'/.password-store';
28 
29 my $got = $ENV{'PLASS_GOT'} // 'got';
30 my $tog = $ENV{'PLASS_TOG'} // 'tog';
31 
32 my $gpg = $ENV{'PLASS_GPG'} // 'gpg2';
33 my @gpg_flags = qw(--quiet --compress-algo=none --no-encrypt-to);
34 
35 my $default_chars = $ENV{'PLASS_CHARS'} // '!-~';
36 my $default_length = $ENV{'PLASS_LENGTH'};
37 if (!defined($default_length) || $default_length lt 0) {
38 	$default_length = 32;
39 }
40 
41 my %subcmd = (
42 	cat	=> [\&cmd_cat,		"entries..."],
43 	find	=> [\&cmd_find,		"[pattern]"],
44 	gen	=> [\&cmd_gen,		"[-nq] [-c chars] [-l length] entry"],
45 	got	=> [\&cmd_got,		"args ..."],
46 	mv	=> [\&cmd_mv,		"from to"],
47 	rm	=> [\&cmd_rm,		"entries..."],
48 	tee	=> [\&cmd_tee,		"[-q] entry"],
49 	tog	=> [\&cmd_tog,		"args ..."],
50     );
51 
52 my $usage = "[-h] [command argument ...]";
53 my $cmd;
54 sub usage {
55 	my $prog = basename $0;
56 	if (defined($cmd)) {
57 		say STDERR "Usage: $prog $cmd $usage";
58 	} else {
59 		say STDERR "Usage: $prog $usage";
60 		say STDERR "commands: ", join(' ', sort(keys %subcmd));
61 	}
62 	exit 1;
63 }
64 
65 GetOptions("h|?" => \&usage) or usage();
66 
67 $cmd = shift // 'find';
68 usage() unless defined $subcmd{$cmd};
69 my $fn;
70 ($fn, $usage) = @{$subcmd{$cmd}};
71 chdir $store;
72 $fn->();
73 exit 0;
74 
75 
76 # utils
77 
78 sub name2file {
79 	my $f = shift;
80 	$f .= ".gpg" unless $f =~ m,\.gpg$,;
81 	return $f;
82 }
83 
84 # tr -cd -- $chars < /dev/random | dd bs=$len count=1 status=none
85 sub gen {
86 	my ($chars, $length) = @_;
87 	my $pass = "";
88 
89 	open(my $fh, '<:raw', '/dev/random')
90 	    or die "can't open /dev/random: $!";
91 	my $l = $length;
92 	while ($l gt 0) {
93 		read($fh, my $t, $length * 4)
94 		    or die "failed to read /dev/random: $!";
95 		$t =~ s/[^$chars]//g;
96 		$l -= length($t);
97 		$pass .= $t;
98 	}
99 	close($fh);
100 
101 	return substr($pass, 0, $length);
102 }
103 
104 sub readpass {
105 	# todo some stty black magic to avoid echo
106 	print shift if -t;
107 	my $pass = <>;
108 	die "failed to read stdin: $!" unless defined($pass);
109 	chomp $pass;
110 	return $pass;
111 }
112 
113 sub mkdirs {
114 	my $dir = shift;
115 	my $parent = dirname $dir;
116 	mkdirs($parent) unless -d $parent || $parent eq '/';
117 	mkdir $dir or die "mkdir $dir: $!"
118 	    unless -d $dir;
119 }
120 
121 sub writepass {
122 	my ($file, $pass) = @_;
123 
124 	mkdirs(dirname $file);
125 
126 	my @args = ($gpg, @gpg_flags, '-e', '-r', recipient(),
127 	    '-o', $file);
128 	open my $fh, '|-', @args;
129 	say $fh "$pass";
130 	close($fh);
131 }
132 
133 sub recipient {
134 	open my $fh, '<', "$store/.gpg-id"
135 	    or die "can't open recipient file";
136 	my $r = <$fh>;
137 	chomp $r;
138 	close($fh);
139 	return $r;
140 }
141 
142 sub passfind {
143 	my $pattern = shift;
144 	my @entries;
145 
146 	find({
147 		wanted => sub {
148 			if (m,/.git$, || m,/.got$,) {
149 				$File::Find::prune = 1;
150 				return;
151 			}
152 
153 			return if defined($pattern) && ! m/$pattern/;
154 			return unless -f && m,.gpg$,;
155 
156 			s,^$store/*,,;
157 			s,.gpg$,,;
158 			push @entries, $_;
159 		},
160 		no_chdir => 1,
161 		follow_fast => 1,
162 	     }, ($store));
163 	return sort(@entries);
164 }
165 
166 sub got {
167 	# discard stdout
168 	open my $fh, '-|', ($got, @_);
169 	close($fh);
170 	return !$?;
171 }
172 
173 sub got_add {
174 	return got 'add', '-I', shift;
175 }
176 
177 sub got_rm {
178 	got 'remove', '-f', shift
179 	    or exit(1);
180 }
181 
182 sub got_ci {
183 	my $pid = fork;
184 	die "failed to fork: $!" unless defined $pid;
185 
186 	if ($pid ne 0) {
187 		wait;
188 		die "failed to commit changes" if $?;
189 		return;
190 	}
191 
192 	open (STDOUT, ">&", \*STDERR)
193 	    or die "can't redirect stdout to stderr";
194 	exec ($got, 'commit', '-m', shift)
195 	    or die "failed to exec $got: $!";
196 }
197 
198 
199 # cmds
200 
201 sub cmd_cat {
202 	GetOptions('h|?' => \&usage) or usage;
203 	usage unless @ARGV;
204 
205 	while (@ARGV) {
206 		my $file = name2file(shift @ARGV);
207 		system ($gpg, @gpg_flags, '-d', $file);
208 		die "failed to exec $gpg: $!" if $? == -1;
209 	}
210 }
211 
212 sub cmd_find {
213 	GetOptions('h|?' => \&usage) or usage;
214 	usage if @ARGV gt 1;
215 
216 	map { say $_ } passfind(shift @ARGV);
217 }
218 
219 sub cmd_gen {
220 	my $chars = $default_chars;
221 	my $length = $default_length;
222 	my $nop;
223 	my $q;
224 
225 	GetOptions(
226 		'c=s' => sub { $chars = $_[1] },
227 		'h|?' => \&usage,
228 		'l=i' => sub { $length = $_[1] },
229 		'n'   => \$nop,
230 		'q'   => \$q,
231 	    ) or usage;
232 	usage if @ARGV ne 1;
233 
234 	my $name = shift @ARGV;
235 	my $file = name2file $name;
236 	my $renamed = -f $file;
237 
238 	my $pass = gen($chars, $length);
239 
240 	unless ($nop) {
241 		writepass($file, $pass);
242 		got_add $file;
243 		got_ci($renamed ? "update $name" : "+$name");
244 	}
245 	say $pass unless $q;
246 }
247 
248 sub cmd_got {
249 	exec $got, @ARGV;
250 }
251 
252 # TODO: handle moving directories?
253 sub cmd_mv {
254 	GetOptions('h|?' => \&usage) or usage;
255 	usage if @ARGV ne 2;
256 
257 	my $a = shift @ARGV;
258 	my $b = shift @ARGV;
259 
260 	my $pa = name2file $a;
261 	my $pb = name2file $b;
262 
263 	die "source password doesn't exist" unless -f $pa;
264 	die "target password exists" if -f $pb;
265 
266 	rename $pa, $pb or die "can't rename $a to $b: $!";
267 
268 	got_rm $pa;
269 	got_add $pb or die "can't add $pb\n";
270 	got_ci "mv $a $b";
271 }
272 
273 sub cmd_rm {
274 	GetOptions('h|?' => \&usage) or usage;
275 	usage unless @ARGV;
276 
277 	while (@ARGV) {
278 		my $name = shift @ARGV;
279 		my $file = name2file $name;
280 
281 		got_rm $file;
282 		got_ci "-$name";
283 	}
284 }
285 
286 sub cmd_tee {
287 	my $q;
288 	GetOptions(
289 		'h|?' => \&usage,
290 		'q'   => \$q,
291 	    ) or usage;
292 	usage if @ARGV ne 1;
293 
294 	my $name = shift @ARGV;
295 	my $file = name2file $name;
296 
297 	my $pass = readpass "Enter the password: ";
298 	writepass($file, $pass);
299 
300 	got_add $file;
301 	got_ci (-f $file ? "update $name" : "+$name");
302 	say $pass unless $q;
303 }
304 
305 sub cmd_tog {
306 	exec $tog, @ARGV;
307 }