Blob

Date:
Message:
first revision of a parser for the configuration file There is only the code to do the parsing, not actually applying them. The accepted syntax is as follows: # `set' to, hum, set options set max-redirect = 5 set new-tab-url = "about:blank" # change the styling style tabline foreground white style tabline background black style line.title2 { prefix "## " cont " " attr bold } # keybindings management bind global-map "1 G" beginning-of-buffer bind minibuffer-map "C-c" minibuffer-abort unbind minibuffer-map "C-g"
Actions:
History | Blame | Raw File
1 AC_INIT([telescope], [0.2], [telescope@omarpolo.com], [telescope], [gemini://telescope.omarpolo.com])

2 AC_CONFIG_LIBOBJ_DIR(compat)

3 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects])

4 AC_PROG_CC_C99

5 AC_USE_SYSTEM_EXTENSIONS

6 AC_PROG_YACC

8 PKG_PROG_PKG_CONFIG

10 AC_REPLACE_FUNCS([

11 	asprintf \

12 	err \

13 	freezero \

14 	getdtablecount \

15 	getdtablesize \

16 	getprogname \

17 	memmem \

18 	recallocarray \

19 	strlcat \

20 	strlcpy \

21 	strsep \

22 	strtonum \

23 	setproctitle \

24 ])

26 AC_MSG_CHECKING([for sys/queue.h with TAILQ_FOREACH_SAFE])

27 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([

28 #include <sys/queue.h>

29 #include <stddef.h>

30 ], [

31 	TAILQ_HEAD(tailhead, entry) head;

32 	struct entry {

33 		TAILQ_ENTRY(entry) entries;

34 	} *np, *nt;

35 	TAILQ_INIT(&head);

36 	TAILQ_FOREACH_SAFE(np, &head, entries, nt) {

37 		/* nop */ ;

38 	}

39 	return 0;

40 ])], [

41 	AC_MSG_RESULT(yes)

42 	AC_DEFINE([HAVE_QUEUE_H], 1, [QUEUE_H])

43 ], AC_MSG_RESULT(no))

45 AC_CHECK_DECL(PR_SET_NAME, AC_DEFINE([HAVE_PR_SET_NAME], 1, [pr_set_name]), [],

46 	[[#include <sys/prctl.h>]])

48 AC_SEARCH_LIBS([initscr], [ncursesw ncurses], [], [

49 	AC_MSG_ERROR([requires either ncursesw or ncurses library])

50 ])

52 AC_CHECK_LIB(tls, tls_init, [], [

53 	AC_MSG_ERROR([requires libtls])

54 ])

56 AC_CHECK_LIB(event, event_init, [], [

57 	AC_MSG_ERROR([requires libevent])

58 ])

60 AC_CHECK_LIB(util, imsg_init, [], [

61 	AC_LIBOBJ(imsg)

62 	AC_LIBOBJ(imsg-buffer)

63 	AC_LIBOBJ(ohash)

64 ])

66 AC_CHECK_FUNCS([asr_run])

68 # check compiler flags

69 AC_DEFUN([CC_ADD_CHECK_FLAGS], [

70 	AC_MSG_CHECKING([if $CC supports $1 flag])

71 	old_CFLAGS="$CFLAGS"

72 	CFLAGS="$CFLAGS $1"

73 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],

74 		AC_MSG_RESULT(yes),

75 		AC_MSG_RESULT(no)

76 		CFLAGS="$old_CFLAGS")

77 ])

78 CC_ADD_CHECK_FLAGS([-Wall])

79 CC_ADD_CHECK_FLAGS([-Wextra])

80 CC_ADD_CHECK_FLAGS([-Wmissing-prototypes])

81 CC_ADD_CHECK_FLAGS([-Wstrict-prototypes])

82 CC_ADD_CHECK_FLAGS([-Wwrite-strings])

83 CC_ADD_CHECK_FLAGS([-Wno-unused-parameter])

85 AC_CONFIG_HEADERS([config.h])

86 AC_CONFIG_FILES([

87 	Makefile

88 ])

90 AC_OUTPUT