1 # GotMArc was written by Omar Polo <op@openbsd.org> and is placed in
2 # the public domain.  The author hereby disclaims copyright to this
3 # source code.
4 
5 package GotMArc;
6 use strict;
7 use warnings;
8 use v5.32;
9 use Exporter;
10 use File::Basename;
11 
12 our @ISA = qw(Exporter);
13 our @EXPORT_OK = qw(san urlencode parse initpage endpage index_header
14     thread_header threntry thrslice);
15 
16 sub san {
17 	my $str = shift;
18 	$str =~ s/&/\&amp;/g;
19 	$str =~ s/</\&lt;/g;
20 	$str =~ s/>/\&gt;/g;
21 	return $str;
22 }
23 
24 sub urlencode {
25 	my $str = shift;
26 	unless (defined($str)) {
27 		my ($pkg, $file, $line) = caller 1;
28 		die "bad $pkg / $file:$line";
29 	}
30 	$str =~ s/([^-_~.A-Za-z0-9])/sprintf("%%%2X", ord($1))/ge;
31 	return $str;
32 }
33 
34 sub ssan {
35 	my $str = shift;
36 	$str =~ s/\s+/ /g;
37 	$str =~ s/\s+$//;
38 	return san($str);
39 }
40 
41 sub parse {
42 	my $line = shift;
43 	my ($indent, $fname, $date, $from, $subj) = $line =~ m{
44 		^([^-]*)-			# the indent level
45 		([^ ]+)\s			# filename
46 		(\d{4}-\d\d-\d\d[ ]\d\d:\d\d)	# date
47 		<([^>]+)>			# from
48 		(.*)				# subject
49 	}x or die "can't parse: $line";
50 
51 	my $level = length($indent);
52 	$level = 10 if $indent =~ m/\.\.\d+\.\./;
53 
54 	$from = ssan($from);
55 	$subj = ssan($subj);
56 
57 	my ($time, $id) = split /\./, basename($fname);
58 	my $mid = "$time.$id";
59 
60 	return {level => $level, fname => $fname,
61 	    mid => $mid, date => $date, from => $from, subj => $subj};
62 }
63 
64 sub readall {
65 	my $path = shift;
66 	local $/ = undef;
67 	open my $fh, "<", $path or die "can't open $path: $!";
68 	<$fh>;
69 }
70 
71 my $small_logo = readall "logo-small.html";
72 my $hdr = readall "head.html";
73 my $foot = readall "foot.html";
74 my $idxhdr = readall "index-header.html";
75 
76 sub initpage {
77 	my ($fh, $title) = @_;
78 	say $fh $hdr =~ s/TITLE/$title/r;
79 }
80 
81 sub endpage {
82 	my $fh = shift;
83 	say $fh $foot;
84 }
85 
86 sub index_header {
87 	my ($fh, $page, $subtitle) = @_;
88 	my $html = $idxhdr =~ s/PAGE/$page/r;
89 	$html =~ s/SUBTITLE/$subtitle/;
90 	print $fh $html;
91 }
92 
93 sub thread_header {
94 	my ($fh, $e, $mail, $p, $n, $spoiler) = @_;
95 	$spoiler = 0 unless defined $spoiler;
96 
97 	my @entries = @$e;
98 
99 	my $enctid = urlencode $mail->{tid} if defined $mail;
100 	my $encmid = urlencode $mail->{mid} if defined $mail;
101 
102 	print $fh "<header class='mail-header'>\n";
103 
104 	print $fh "<p>";
105 	print $fh $small_logo;
106 	print $fh "<a href='/'>Index</a>";
107 	print $fh " | <a href='/thread/$enctid.html#$encmid'>Thread</a>"
108 	    if defined $enctid;
109 	print $fh " | <a href='/search'>Search</a>";
110 	print $fh "</p>\n";
111 
112 	say $fh "<dl>";
113 	foreach my $entry (@entries) {
114 		my ($k, $v) = split /: /, $entry, 2;
115 		chomp $v;
116 		say $fh "<dt>$k:</dt><dd>$v</dd>";
117 	}
118 	say $fh "</dl>";
119 
120 	say $fh "<p>Download raw <a href='/text/$encmid.txt'>body</a>.</p>"
121 	    if defined $encmid;
122 
123 	say $fh "<details>" if $spoiler;
124 	say $fh "<summary>Thread</summary>" if $spoiler;
125 	thrslice($fh, $mail, $p, $n) if defined $p and defined $n;
126 	say $fh "</details>" if $spoiler;
127 
128 	say $fh "</header>\n";
129 }
130 
131 sub threntry {
132 	my ($fh, $type, $base, $last_level, $mail, $cur) = @_;
133 	my $level = $mail->{level} - $base;
134 
135 	say $fh "</ul></li>" x ($last_level - $level) if $last_level > $level;
136 	say $fh "<li><ul>" if $last_level < $level;
137 
138 	my $encmid = urlencode $mail->{mid};
139 
140 	print $fh "<li id='$encmid' class='mail'>";
141 	print $fh "<p class='mail-meta'>";
142 	print $fh "<time>$mail->{date}</time> ";
143 	print $fh "<span class='from'>$mail->{from}</span>";
144 	print $fh "<span class='colon'>:</span>";
145 	print $fh "</p>";
146 	print $fh "<p class='subject'>";
147 
148 	my $subj = $mail->{subj};
149 	if (!defined($cur) || $mail->{mid} ne $cur->{mid}) {
150 		print $fh "<a href='/$type/$encmid.html'>$subj</a>";
151 	} else {
152 		print $fh "<span>$subj</span>";
153 	}
154 
155 	print $fh "</p>";
156 	print $fh "</li>";
157 
158 	return $level;
159 }
160 
161 sub min_level {
162 	my $l = 999;
163 	return 0 unless @_;
164 	for (@_) {
165 		$l = $_->{level} if $_->{level} < $l;
166 	}
167 	return $l;
168 }
169 
170 sub thrslice {
171 	my ($fh, $mail, $p, $n) = @_;
172 	my @prev = @{$p};
173 	my @next = @{$n};
174 	my @thread = (@prev, $mail, @next);
175 	return unless @thread;
176 	my $base = min_level @thread;
177 	my $level = 0;
178 	print $fh "<div class='thread'>";
179 	print $fh "<ul class='mails'>";
180 	$level = threntry $fh, "mail", $base, $level, $_, $mail for @thread;
181 	print $fh "</ul></li>" x $level;
182 	print $fh "</ul></div>";
183 }
184 
185 1;