1 AC_INIT([telescope], [0.7.1-current], [telescope@omarpolo.com], [telescope], [gemini://telescope.omarpolo.com])
2 AC_CONFIG_AUX_DIR(etc)
3 AC_CONFIG_LIBOBJ_DIR(compat)
4 AC_CANONICAL_HOST
5 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects])
6 AC_PROG_CC_C99
7 AC_USE_SYSTEM_EXTENSIONS
8 AC_PROG_YACC
9 
10 PKG_PROG_PKG_CONFIG
11 
12 AC_ARG_VAR(HOSTCC, [The C compiler on the host.])
13 AC_ARG_VAR(HOSTCFLAGS, [CFLAGS for the host compiler])
14 
15 test -z "${HOSTCC}"     && HOSTCC='$(CC)'
16 test -z "${HOSTCFLAGS}" && HOSTCFLAGS='$(CFLAGS)'
17 
18 AC_ARG_WITH([libimsg],
19 	AS_HELP_STRING([--with-libimsg],
20 		[Build with imsg-compat library (default: disabled)]))
21 
22 AC_ARG_WITH([libbsd],
23 	AS_HELP_STRING([--with-libbsd],
24 		[Build with libbsd library (default: disabled)]))
25 
26 AS_IF([test "x$with_libbsd" = "xyes"], [
27 	PKG_CHECK_MODULES([libbsd], [libbsd-overlay libbsd-ctor], [
28 		CFLAGS="$libbsd_CFLAGS $CFLAGS"
29 		LIBS="$libbsd_LIBS $LIBS"
30 	])
31 ])
32 
33 AC_REPLACE_FUNCS([
34 	asprintf \
35 	err \
36 	explicit_bzero \
37 	freezero \
38 	getdtablecount \
39 	getdtablesize \
40 	getprogname \
41 	memmem \
42 	recallocarray \
43 	strcasestr \
44 	strlcat \
45 	strlcpy \
46 	strsep \
47 	strtonum \
48 	setproctitle \
49 ])
50 
51 AC_MSG_CHECKING([for sys/queue.h with TAILQ_FOREACH_SAFE])
52 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
53 #include <sys/queue.h>
54 #include <stddef.h>
55 ], [
56 	TAILQ_HEAD(tailhead, entry) head;
57 	struct entry {
58 		TAILQ_ENTRY(entry) entries;
59 	} *np, *nt;
60 	TAILQ_INIT(&head);
61 	TAILQ_FOREACH_SAFE(np, &head, entries, nt) {
62 		/* nop */ ;
63 	}
64 	return 0;
65 ])], [
66 	AC_MSG_RESULT(yes)
67 	AC_DEFINE([HAVE_QUEUE_H], 1, [QUEUE_H])
68 ], AC_MSG_RESULT(no))
69 
70 AC_CHECK_DECL(PR_SET_NAME, AC_DEFINE([HAVE_PR_SET_NAME], 1, [pr_set_name]), [],
71 	[[#include <sys/prctl.h>]])
72 
73 AC_SEARCH_LIBS([initscr], [ncursesw ncurses], [], [
74 	AC_MSG_ERROR([requires either ncursesw or ncurses library])
75 ])
76 
77 AC_SEARCH_LIBS([keyname], [ncursesw ncurses tinfow tinfo], [], [
78 	AC_MSG_ERROR([requires either ncursesw or ncurses library with terminfo support])
79 ])
80 
81 AC_CHECK_LIB(tls, tls_init, [], [
82 	AC_MSG_ERROR([requires libtls])
83 ])
84 
85 case "$host_os" in
86 	*openbsd*)
87 		AC_CHECK_LIB([event], [event_init], [],
88 			[AC_MSG_ERROR([requires libevent])])
89 		;;
90 	*)
91 		PKG_CHECK_MODULES([libevent2], [libevent_core >= 2], [
92 			AC_DEFINE([HAVE_EVENT2], 1, [1 if using event2])
93 			CFLAGS="$libevent2_CFLAGS $CFLAGS"
94 			LIBS="$libevent2_LIBS $LIBS"
95 		], [AC_MSG_ERROR([requires libevent])])
96 		;;
97 esac
98 
99 AS_IF([test "x$with_libimsg" = "xyes"], [
100 	PKG_CHECK_MODULES([libimsg], [libimsg], [
101 		CFLAGS="$libimsg_CFLAGS $CFLAGS"
102 		LIBS="$libimsg_LIBS $LIBS"
103 	])
104 ])
105 
106 AC_SEARCH_LIBS([imsg_init], [util], [
107 		AC_DEFINE([HAVE_IMSG], 1,
108 			[Define to 1 if you have imsg functions (-lutil or -limsg).])
109 	], [
110 		AC_LIBOBJ(imsg)
111 		AC_LIBOBJ(imsg-buffer)
112 	]
113 )
114 
115 AC_CHECK_LIB(util, ohash_init, [], [
116 	AC_LIBOBJ(ohash)
117 	AC_LIBOBJ(fmt_scaled)
118 ])
119 
120 AC_CHECK_FUNCS([asr_run])
121 
122 # don't check for landlock: it currently unusable.
123 dnl AC_CHECK_HEADERS([linux/landlock.h])
124 
125 # check compiler flags
126 AC_DEFUN([CC_ADD_CHECK_FLAGS], [
127 	AC_MSG_CHECKING([if $CC supports $1 flag])
128 	old_CFLAGS="$CFLAGS"
129 	CFLAGS="$CFLAGS $1"
130 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
131 		AC_MSG_RESULT(yes),
132 		AC_MSG_RESULT(no)
133 		CFLAGS="$old_CFLAGS")
134 ])
135 CC_ADD_CHECK_FLAGS([-Wall])
136 CC_ADD_CHECK_FLAGS([-Wextra])
137 CC_ADD_CHECK_FLAGS([-Wmissing-declarations])
138 CC_ADD_CHECK_FLAGS([-Wmissing-prototypes])
139 CC_ADD_CHECK_FLAGS([-Wstrict-prototypes])
140 CC_ADD_CHECK_FLAGS([-Wwrite-strings])
141 CC_ADD_CHECK_FLAGS([-Wno-unused-parameter])
142 CC_ADD_CHECK_FLAGS([-Wpointer-arith])
143 CC_ADD_CHECK_FLAGS([-Wsign-compare])
144 CC_ADD_CHECK_FLAGS([-Wcast-align])
145 
146 AC_CONFIG_HEADERS([config.h])
147 AC_CONFIG_FILES([
148 	Makefile
149 	test/Makefile
150 	pages/about_about.gmi
151 	pages/about_blank.gmi
152 	pages/about_crash.gmi
153 	pages/about_help.gmi
154 	pages/about_license.gmi
155 	pages/about_new.gmi
156 	pages/bookmarks.gmi
157 ])
158 
159 AC_OUTPUT