1 #!/usr/bin/env perl
2 #
3 # Copyright (c) 2022 Omar Polo <op@omarpolo.com>
4 #
5 # Permission to use, copy, modify, and distribute this software for any
6 # purpose with or without fee is hereby granted, provided that the above
7 # copyright notice and this permission notice appear in all copies.
8 #
9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
16 
17 use strict;
18 use warnings;
19 use v5.32;
20 
21 use open ":std", ":encoding(UTF-8)";
22 
23 use Getopt::Long qw(:config bundling require_order);
24 use File::Basename;
25 use File::Find;
26 
27 my $store = $ENV{'PLASS_STORE'} // $ENV{'HOME'}.'/.password-store';
28 
29 my $got = $ENV{'PLASS_GOT'} // 'got';
30 
31 my $gpg = $ENV{'PLASS_GPG'} // 'gpg';
32 my @gpg_flags = qw(--quiet --compress-algo=none --no-encrypt-to --use-agent);
33 
34 my $default_chars = $ENV{'PLASS_CHARS'} // '!-~';
35 my $default_length = $ENV{'PLASS_LENGTH'};
36 if (!defined($default_length) || $default_length <= 0) {
37 	$default_length = 32;
38 }
39 
40 my %subcmd = (
41 	cat	=> [\&cmd_cat,		"entries..."],
42 	find	=> [\&cmd_find,		"[pattern]"],
43 	gen	=> [\&cmd_gen,		"[-nq] [-c chars] [-l length] entry"],
44 	mv	=> [\&cmd_mv,		"from to"],
45 	rm	=> [\&cmd_rm,		"entries..."],
46 	tee	=> [\&cmd_tee,		"[-q] entry"],
47     );
48 
49 my $usage = "[-h] command [argument ...]";
50 my $cmd;
51 sub usage {
52 	my $prog = basename $0;
53 	if (defined($cmd) and defined($subcmd{$cmd})) {
54 		say STDERR "Usage: $prog $cmd $usage";
55 	} else {
56 		say STDERR "Usage: $prog $usage";
57 		say STDERR "unknown command $cmd" if defined($cmd);
58 		say STDERR "commands: ", join(' ', sort(keys %subcmd));
59 	}
60 	exit 1;
61 }
62 
63 GetOptions("h|?" => \&usage) or usage();
64 
65 $cmd = shift // 'find';
66 usage() unless defined $subcmd{$cmd};
67 my $fn;
68 ($fn, $usage) = @{$subcmd{$cmd}};
69 chdir $store;
70 $fn->();
71 exit 0;
72 
73 
74 # utils
75 
76 sub name2file {
77 	my $f = shift;
78 	$f .= ".gpg" unless $f =~ m,\.gpg$,;
79 	return $f;
80 }
81 
82 # tr -cd -- $chars < /dev/random | dd bs=$len count=1 status=none
83 sub gen {
84 	my ($chars, $length) = @_;
85 	my $pass = "";
86 
87 	open(my $fh, '<:raw', '/dev/random')
88 	    or die "can't open /dev/random: $!";
89 	my $l = $length;
90 	while ($l >= 0) {
91 		read($fh, my $t, $length * 4)
92 		    or die "failed to read /dev/random: $!";
93 		$t =~ s/[^$chars]//g;
94 		$l -= length($t);
95 		$pass .= $t;
96 	}
97 	close($fh);
98 
99 	return substr($pass, 0, $length);
100 }
101 
102 sub readpass {
103 	# todo some stty black magic to avoid echo
104 	print shift if -t;
105 	my $pass = <>;
106 	die "failed to read stdin: $!" unless defined($pass);
107 	chomp $pass;
108 	return $pass;
109 }
110 
111 sub mkdirs {
112 	my $dir = shift;
113 	my $parent = dirname $dir;
114 	mkdirs($parent) unless -d $parent || $parent eq '/';
115 	mkdir $dir or die "mkdir $dir: $!"
116 	    unless -d $dir;
117 }
118 
119 sub writepass {
120 	my ($file, $pass) = @_;
121 
122 	mkdirs(dirname $file);
123 
124 	# temporary redirect stdout to $file
125 	open(my $stdout, '>&', STDOUT);
126 	open(STDOUT, '>', $file);
127 
128 	my @args = ($gpg, @gpg_flags, '-e', '-r', recipient(),
129 	    '-o', '-');
130 	open my $fh, '|-', @args;
131 	say $fh "$pass";
132 	close($fh);
133 	my $ok = !$?;
134 
135 	open(STDOUT, '>&', $stdout); # restore stdout
136 
137 	die "failed to run $gpg\n" unless $ok;
138 }
139 
140 sub recipient {
141 	open my $fh, '<', "$store/.gpg-id"
142 	    or die "can't open recipient file";
143 	my $r = <$fh>;
144 	chomp $r;
145 	close($fh);
146 	return $r;
147 }
148 
149 sub passfind {
150 	my $pattern = shift;
151 	my @entries;
152 
153 	find({
154 		wanted => sub {
155 			if (m,/.git$, || m,/.got$,) {
156 				$File::Find::prune = 1;
157 				return;
158 			}
159 
160 			return if defined($pattern) && ! m/$pattern/;
161 			return unless -f && m,.gpg$,;
162 
163 			s,^$store/*,,;
164 			s,.gpg$,,;
165 			push @entries, $_;
166 		},
167 		no_chdir => 1,
168 		follow_fast => 1,
169 	     }, ($store));
170 	return sort(@entries);
171 }
172 
173 sub got {
174 	# discard stdout
175 	open my $fh, '-|', ($got, @_);
176 	close($fh);
177 	return !$?;
178 }
179 
180 sub got_add {
181 	return got 'add', '-I', shift;
182 }
183 
184 sub got_rm {
185 	got 'remove', '-f', shift
186 	    or exit(1);
187 }
188 
189 sub got_ci {
190 	my $pid = fork;
191 	die "failed to fork: $!" unless defined $pid;
192 
193 	if ($pid != 0) {
194 		wait;
195 		die "failed to commit changes" if $?;
196 		return;
197 	}
198 
199 	open (STDOUT, ">&", \*STDERR)
200 	    or die "can't redirect stdout to stderr";
201 	exec ($got, 'commit', '-m', shift)
202 	    or die "failed to exec $got: $!";
203 }
204 
205 
206 # cmds
207 
208 sub cmd_cat {
209 	GetOptions('h|?' => \&usage) or usage;
210 	usage unless @ARGV;
211 
212 	while (@ARGV) {
213 		my $file = name2file(shift @ARGV);
214 		system ($gpg, @gpg_flags, '-d', $file);
215 		die "failed to exec $gpg: $!" if $? == -1;
216 	}
217 }
218 
219 sub cmd_find {
220 	GetOptions('h|?' => \&usage) or usage;
221 	usage if @ARGV > 1;
222 
223 	map { say $_ } passfind(shift @ARGV);
224 }
225 
226 sub cmd_gen {
227 	my $chars = $default_chars;
228 	my $length = $default_length;
229 	my $nop;
230 	my $q;
231 
232 	GetOptions(
233 		'c=s' => sub { $chars = $_[1] },
234 		'h|?' => \&usage,
235 		'l=i' => sub { $length = $_[1] },
236 		'n'   => \$nop,
237 		'q'   => \$q,
238 	    ) or usage;
239 
240 	my $pass = gen($chars, $length);
241 	if ($nop) {
242 		say $pass;
243 		return;
244 	}
245 
246 	usage if @ARGV != 1;
247 
248 	my $name = shift @ARGV;
249 	my $file = name2file $name;
250 	my $renamed = -f $file;
251 
252 	writepass($file, $pass);
253 	got_add $file;
254 	got_ci($renamed ? "update $name" : "+$name");
255 	say $pass unless $q;
256 }
257 
258 # TODO: handle moving directories?
259 sub cmd_mv {
260 	GetOptions('h|?' => \&usage) or usage;
261 	usage if @ARGV != 2;
262 
263 	my $a = shift @ARGV;
264 	my $b = shift @ARGV;
265 
266 	my $pa = name2file $a;
267 	my $pb = name2file $b;
268 
269 	die "source password doesn't exist" unless -f $pa;
270 	die "target password exists" if -f $pb;
271 
272 	mkdirs(dirname $pb);
273 	rename $pa, $pb or die "can't rename $a to $b: $!";
274 
275 	got_rm $pa;
276 	got_add $pb or die "can't add $pb\n";
277 	got_ci "mv $a $b";
278 }
279 
280 sub cmd_rm {
281 	GetOptions('h|?' => \&usage) or usage;
282 	usage unless @ARGV;
283 
284 	while (@ARGV) {
285 		my $name = shift @ARGV;
286 		my $file = name2file $name;
287 
288 		got_rm $file;
289 		got_ci "-$name";
290 	}
291 }
292 
293 sub cmd_tee {
294 	my $q;
295 	GetOptions(
296 		'h|?' => \&usage,
297 		'q'   => \$q,
298 	    ) or usage;
299 	usage if @ARGV != 1;
300 
301 	my $name = shift @ARGV;
302 	my $file = name2file $name;
303 
304 	my $pass = readpass "Enter the password: ";
305 	writepass($file, $pass);
306 
307 	got_add $file;
308 	got_ci (-f $file ? "update $name" : "+$name");
309 	say $pass unless $q;
310 }