1 AC_INIT([telescope], [0.1.1], [telescope@omarpolo.com], [telescope], [gemini://telescope.omarpolo.com])
2 AC_CONFIG_LIBOBJ_DIR(compat)
3 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects])
4 AC_PROG_CC_C99
5 AC_USE_SYSTEM_EXTENSIONS
6 
7 PKG_PROG_PKG_CONFIG
8 
9 AC_REPLACE_FUNCS([
10 	asprintf \
11 	err \
12 	freezero \
13 	getdtablecount \
14 	getdtablesize \
15 	getprogname \
16 	memmem \
17 	recallocarray \
18 	strlcat \
19 	strlcpy \
20 	strsep \
21 	strtonum \
22 	setproctitle \
23 ])
24 
25 AC_CHECK_DECL(PR_SET_NAME, AC_DEFINE([HAVE_PR_SET_NAME], 1, [pr_set_name]), [],
26 	[[#include <sys/prctl.h>]])
27 
28 AC_SEARCH_LIBS([initscr], [ncursesw ncurses], [], [
29 	AC_MSG_ERROR([requires either ncursesw or ncurses library])
30 ])
31 
32 AC_CHECK_LIB(tls, tls_init, [], [
33 	AC_MSG_ERROR([requires libtls])
34 ])
35 
36 AC_CHECK_LIB(event, event_init, [], [
37 	AC_MSG_ERROR([requires libevent])
38 ])
39 
40 AC_CHECK_LIB(util, imsg_init, [], [
41 	AC_LIBOBJ(imsg)
42 	AC_LIBOBJ(imsg-buffer)
43 	AC_LIBOBJ(ohash)
44 ])
45 
46 AC_CHECK_FUNCS([asr_run])
47 
48 # check compiler flags
49 AC_DEFUN([CC_ADD_CHECK_FLAGS], [
50 	AC_MSG_CHECKING([if $CC supports $1 flag])
51 	old_CFLAGS="$CFLAGS"
52 	CFLAGS="$CFLAGS $1"
53 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
54 		AC_MSG_RESULT(yes),
55 		AC_MSG_RESULT(no)
56 		CFLAGS="$old_CFLAGS")
57 ])
58 CC_ADD_CHECK_FLAGS([-Wall])
59 CC_ADD_CHECK_FLAGS([-Wextra])
60 CC_ADD_CHECK_FLAGS([-Wmissing-prototypes])
61 CC_ADD_CHECK_FLAGS([-Wstrict-prototypes])
62 CC_ADD_CHECK_FLAGS([-Wwrite-strings])
63 CC_ADD_CHECK_FLAGS([-Wno-unused-parameter])
64 
65 AC_CONFIG_HEADERS([config.h])
66 AC_CONFIG_FILES([
67 	Makefile
68 ])
69 
70 AC_OUTPUT