1 #!/usr/bin/env perl
2 #
3 # mkindex was written by Omar Polo <op@openbsd.org> and is placed in
4 # the public domain.  The author hereby disclaims copyright to this
5 # source code.
6 
7 use open ":std", ":encoding(UTF-8)";
8 use utf8;
9 use strict;
10 use warnings;
11 use v5.32;
12 use File::Temp qw(tempfile);
13 
14 use OpenBSD::Pledge;
15 use OpenBSD::Unveil;
16 
17 use lib ".";
18 use GotMArc qw(parse san urlencode initpage endpage index_header thread_header);
19 
20 my $outdir = $ENV{'OUTDIR'};
21 die 'Set $OUTDIR' unless defined $outdir;
22 
23 my $tfh; # thread file handle
24 my $pfh; # page file handle
25 my $page = 0;
26 my @pages;
27 my @files;
28 my $from_day;
29 my $to_day;
30 my $threads_seen = 0;
31 
32 my $last_level = 0;
33 my $last_tid;
34 my $last_date;
35 my $last_from;
36 my $last_subj;
37 
38 my $threads = 0;
39 my $threads_per_page = 100;
40 
41 sub maxs {
42 	my ($a, $b) = @_;
43 	return $a unless defined $b;
44 	return $a gt $b ? $a : $b;
45 }
46 
47 sub mins {
48 	my ($a, $b) = @_;
49 	return $a unless defined $b;
50 	return $a lt $b ? $a : $b;
51 }
52 
53 sub pagename {
54 	my $i = shift;
55 	return $i == 1 && "index.html" || "$i.html";
56 }
57 
58 sub endfile {
59 	say $pfh '</ul></div>';
60 	close($pfh);
61 	push @pages, "$from_day - $to_day";
62 }
63 
64 sub nextfile {
65 	endfile if defined $pfh;
66 	$page += 1;
67 
68 	my $path;
69 	($pfh, $path) = tempfile "/tmp/gotmarc.index.XXXXXXXXXX";
70 	binmode($pfh, ':utf8');
71 	push @files, $path;
72 	say $pfh "<div class='thread'><ul>";
73 }
74 
75 sub nav {
76 	my ($pfh, $n) = @_;
77 	my ($first, $last) = (pagename(1), pagename($page));
78 	my ($next, $prev) = (pagename($n+1), pagename($n-1));
79 
80 	say $pfh "<nav>";
81 	say $pfh "<a href='$first'>First</a>" if $n > 2;
82 	say $pfh "<a href='$prev'>Prev</a>" if $n > 1;
83 	say $pfh "<a href='$next'>Next</a>" if $n < $page;
84 	say $pfh "<a href='$last'>Last</a>" if $n < $page - 1;
85 	say $pfh "</nav>";
86 }
87 
88 sub copyfrom {
89 	my ($path, $fh) = @_;
90 
91 	# there are probably faster ways to do this like File::Copy,
92 	# but it bypasses the bufio cache...
93 	open(my $pfh, '<', $path) or die "can't open $path: $!";
94 	print $fh $_ while <$pfh>;
95 }
96 
97 sub renderpages {
98 	close($pfh);
99 
100 	for (my $i = 1; $i <= $page; $i++) {
101 		my $name = pagename($i);
102 		my $path = shift @files;
103 		my $dest = "$outdir/$name";
104 
105 		open(my $pfh, '>', $dest)
106 		    or die "can't open $dest for writing: $!";
107 
108 		my $title = "Game of Trees Mail Archive | page $i";
109 		my $subtitle = $pages[$i-1];
110 
111 		initpage($pfh, $title);
112 		index_header $pfh, $i, $subtitle;
113 		say $pfh "<main>";
114 
115 		nav $pfh, $i if $page > 1;
116 		copyfrom($path, $pfh);
117 		nav $pfh, $i if $page > 1;
118 
119 		say $pfh "</main>";
120 		endpage($pfh);
121 
122 		close($pfh);
123 		unlink $path;
124 	}
125 }
126 
127 sub endthread {
128 	say $tfh "</ul></li>" x $last_level;
129 	say $tfh "</ul>\n</div>\n";
130 	endpage($tfh);
131 	close($tfh);
132 
133 	$last_level = 0;
134 }
135 
136 sub nextthread {
137 	endthread if defined $tfh;
138 	my ($mid, $subj) = @_;
139 	my $dest = "$outdir/thread/$mid.html";
140 	open($tfh, '>', $dest) or die "can't open $dest: $!";
141 	initpage($tfh, $subj);
142 	thread_header $tfh, undef, undef, ["Thread: $subj"];
143 	print $tfh "<div class='thread'><ul class='mails'>\n";
144 }
145 
146 sub entry {
147 	my ($fh, $type, $mid, $date, $from, $subj) = @_;
148 	my $encmid = urlencode $mid;
149 
150 	print $fh "<li id='$encmid' class='mail'>";
151 	print $fh "<p class='mail-meta'>";
152 	print $fh "<time>$date</time> ";
153 	print $fh "<span class='from'>$from</span>";
154 	print $fh "<span class='colon'>:</span>";
155 	print $fh "</p>";
156 	print $fh "<p class='subject'>";
157 	print $fh "<a href='/$type/$encmid.html'>$subj</a>";
158 	print $fh "</p>";
159 	print $fh "</li>\n";
160 }
161 
162 sub index_entry {
163 	my ($fh, $mid, $date, $from, $subj) = @_;
164 
165 	entry $fh, "thread", $mid, $date, $from, $subj;
166 }
167 
168 sub thread_entry {
169 	my ($fh, $mid, $level, $date, $from, $subj) = @_;
170 
171 	say $fh "</ul>\n</li>" x ($last_level - $level) if $last_level > $level;
172 	say $fh "<li>\n<ul>" if $last_level < $level;
173 
174 	entry $fh, "mail", $mid, $date, $from, $subj;
175 }
176 
177 unveil($outdir, "rwc") or die "unveil $outdir: $!";
178 unveil(".", "r") or die "unveil .: $!";
179 
180 # can't use tmppath because File::Temp checks wether /tmp exists.
181 unveil("/tmp", "rwc") or die "unveil /tmp: $!";
182 
183 # fattr for File::Temp
184 pledge("stdio rpath wpath cpath fattr") or die "pledge: $!";
185 
186 nextfile;
187 
188 while (<>) {
189 	my ($level, $fname, $mid, $date, $from, $subj) = parse;
190 
191 	if ($level == 0) {
192 		nextthread $mid, $subj;
193 
194 		$threads++;
195 		if ($threads > $threads_per_page) {
196 			nextfile;
197 			$threads = 0;
198 			$to_day = undef;
199 			$from_day = undef;
200 		}
201 
202 		my $day = $date =~ s/ .*//r;
203 		$to_day = mins $day, $to_day;
204 		$from_day = maxs $day, $from_day;
205 	}
206 
207 	thread_entry $tfh, $mid, $level, $date, $from, $subj;
208 	$last_level = $level;
209 	$threads_seen = 1;
210 
211 	index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
212 	    if defined $last_tid && $level == 0;
213 
214 	# `gt' on dates works because the format used allow for
215 	# lexicographic comparisons.
216 	if ($level == 0 || $date gt $last_date) {
217 		$last_date = $date;
218 		$last_from = $from;
219 	}
220 
221 	if ($level == 0) {
222 		$last_tid = $mid;
223 		$last_subj = $subj;
224 	}
225 }
226 
227 index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
228     if defined $last_tid;
229 
230 endfile;
231 endthread if $threads_seen;
232 renderpages;