1 AC_INIT([telescope], [0.9-current], [telescope@omarpolo.com], [telescope], [gemini://telescope.omarpolo.com])
2 AC_CONFIG_AUX_DIR(etc)
3 AC_CONFIG_LIBOBJ_DIR(compat)
4 AC_CANONICAL_HOST
5 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects])
6 AC_PROG_CC
7 AC_USE_SYSTEM_EXTENSIONS
8 AC_PROG_YACC
9 
10 PKG_PROG_PKG_CONFIG
11 
12 AC_ARG_VAR(HOSTCC, [The C compiler on the host.])
13 AC_ARG_VAR(HOSTCFLAGS, [CFLAGS for the host compiler])
14 
15 test -z "${HOSTCC}"     && HOSTCC='$(CC)'
16 test -z "${HOSTCFLAGS}" && HOSTCFLAGS='$(CFLAGS)'
17 
18 AC_ARG_WITH([Werror],
19 	AS_HELP_STRING([--with-Werror],
20 		[Add the compiler flag -Werror]))
21 
22 AC_ARG_WITH([libimsg],
23 	AS_HELP_STRING([--with-libimsg],
24 		[Build with imsg-compat library (default: disabled)]))
25 
26 AC_ARG_WITH([libbsd],
27 	AS_HELP_STRING([--with-libbsd],
28 		[Build with libbsd library (default: disabled)]))
29 
30 AS_IF([test "x$with_libbsd" = "xyes"], [
31 	PKG_CHECK_MODULES([libbsd], [libbsd-overlay libbsd-ctor], [
32 		CFLAGS="$libbsd_CFLAGS $CFLAGS"
33 		LIBS="$libbsd_LIBS $LIBS"
34 	])
35 ])
36 
37 AC_REPLACE_FUNCS([
38 	asprintf \
39 	err \
40 	explicit_bzero \
41 	freezero \
42 	getdtablecount \
43 	getdtablesize \
44 	getprogname \
45 	memmem \
46 	reallocarray \
47 	recallocarray \
48 	strcasestr \
49 	strlcat \
50 	strlcpy \
51 	strsep \
52 	strtonum \
53 	setproctitle \
54 ])
55 
56 AC_MSG_CHECKING([for sys/queue.h with TAILQ_FOREACH_SAFE])
57 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
58 #include <sys/queue.h>
59 #include <stddef.h>
60 ], [
61 	TAILQ_HEAD(tailhead, entry) head;
62 	struct entry {
63 		TAILQ_ENTRY(entry) entries;
64 	} *np, *nt;
65 	TAILQ_INIT(&head);
66 	TAILQ_FOREACH_SAFE(np, &head, entries, nt) {
67 		/* nop */ ;
68 	}
69 	return 0;
70 ])], [
71 	AC_MSG_RESULT(yes)
72 	AC_DEFINE([HAVE_QUEUE_H], 1, [QUEUE_H])
73 ], AC_MSG_RESULT(no))
74 
75 AC_CHECK_DECL(timespecsub,
76     [AC_DEFINE([HAVE_TIMESPECSUB], 1, [have timespecsub])], [],
77     [#include <sys/time.h>])
78 
79 AC_CHECK_DECL(timercmp,
80     [AC_DEFINE([HAVE_TIMERCMP], 1, [have timercmp])], [],
81     [#include <sys/time.h>])
82 
83 dnl can't be used as r-value.
84 AC_MSG_CHECKING([for TIMEVAL_TO_TIMESPEC])
85 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
86 #include <sys/time.h>
87 ], [
88 	struct timeval a = {0, 0};
89 	struct timespec b;
90 	TIMEVAL_TO_TIMESPEC(&a, &b);
91 	return (int)b.tv_sec;
92 ])], [
93 	AC_MSG_RESULT(yes)
94 	AC_DEFINE([HAVE_TIMEVAL_TO_TIMESPEC], 1, [have TIMEVAL_TO_TIMESPEC])
95 ], AC_MSG_RESULT(no))
96 
97 AC_CHECK_HEADER([endian.h], [AC_DEFINE(HAVE_ENDIAN_H, 1, [have endian.h])], [
98 	AC_CHECK_HEADER([sys/endian.h],
99 		[AC_DEFINE(HAVE_SYS_ENDIAN_H, 1, [have sys/endian.h])], [
100 		AC_CHECK_HEADERS([libkern/OSByteOrder.h],
101 			[AC_DEFINE(HAVE_LIBKERN_OSBYTEORDER_H, 1, [have OSByteOrder.h])],
102 			[AC_MSG_ERROR([can't find compatible endian.h header])],
103 			[#include <machine/endian.h>])
104 	])
105 ])
106 
107 AC_CHECK_DECL(PR_SET_NAME, AC_DEFINE([HAVE_PR_SET_NAME], 1, [pr_set_name]), [],
108 	[[#include <sys/prctl.h>]])
109 
110 AC_SEARCH_LIBS([initscr], [ncursesw ncurses], [], [
111 	AC_MSG_ERROR([requires either ncursesw or ncurses library])
112 ])
113 
114 AC_SEARCH_LIBS([keyname], [ncursesw ncurses tinfow tinfo], [], [
115 	AC_MSG_ERROR([requires either ncursesw or ncurses library with terminfo support])
116 ])
117 
118 AC_SEARCH_LIBS([tls_init], [tls], [], [
119 	AC_MSG_ERROR([requires libtls])
120 ])
121 
122 PKG_CHECK_MODULES([libgrapheme], [libgrapheme], [
123 	AC_SUBST([LIBGRAPHEME], [])
124 	CFLAGS="$libgrapheme_CFLAGS $CFLAGS"
125 	LIBS="$libgrapheme_LIBS $LIBS"
126 ], [
127 	# build the bundled version.
128 	AC_SUBST([LIBGRAPHEME], "$srcdir/libgrapheme/libgrapheme.a")
129 	CFLAGS="-I$srcdir/libgrapheme $CFLAGS"
130 ])
131 
132 AS_IF([test "x$with_libimsg" = "xyes"], [
133 	PKG_CHECK_MODULES([libimsg], [libimsg], [
134 		CFLAGS="$libimsg_CFLAGS $CFLAGS"
135 		LIBS="$libimsg_LIBS $LIBS"
136 	])
137 ])
138 
139 AC_SEARCH_LIBS([imsg_init], [util], [
140 		AC_DEFINE([HAVE_IMSG], 1,
141 			[Define to 1 if you have imsg functions (-lutil or -limsg).])
142 	], [
143 		AC_LIBOBJ(imsg)
144 		AC_LIBOBJ(imsg-buffer)
145 	]
146 )
147 
148 AC_SEARCH_LIBS([ohash_init], [util], [], [
149 	AC_LIBOBJ(ohash)
150 	AC_LIBOBJ(fmt_scaled)
151 ])
152 
153 AC_CHECK_FUNCS([asr_run])
154 
155 AC_SEARCH_LIBS([RAND_add], [crypto], [:], [
156 	AC_MSG_ERROR([can't find libcrypto])
157 ])
158 
159 AC_SEARCH_LIBS([SSL_CTX_new], [ssl], [:], [
160 	AC_MSG_ERROR([can't find libssl])
161 ])
162 
163 AC_CHECK_HEADERS([linux/landlock.h])
164 
165 dnl after all the function checks, add optional support for -Werror
166 AS_IF([test "x$with_Werror" = "xyes"], [
167 	CFLAGS="$CFLAGS -Werror"
168 ])
169 
170 # check compiler flags
171 AC_DEFUN([CC_ADD_CHECK_FLAGS], [
172 	AC_MSG_CHECKING([if $CC supports $1 flag])
173 	old_CFLAGS="$CFLAGS"
174 	CFLAGS="$CFLAGS -Werror $1"
175 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [
176 		AC_MSG_RESULT(yes)
177 		CFLAGS="$old_CFLAGS $1"
178 	], [
179 		AC_MSG_RESULT(no)
180 		CFLAGS="$old_CFLAGS"
181 	])
182 ])
183 CC_ADD_CHECK_FLAGS([-Wall])
184 CC_ADD_CHECK_FLAGS([-Wextra])
185 CC_ADD_CHECK_FLAGS([-Wmissing-declarations])
186 CC_ADD_CHECK_FLAGS([-Wmissing-prototypes])
187 CC_ADD_CHECK_FLAGS([-Wstrict-prototypes])
188 CC_ADD_CHECK_FLAGS([-Wwrite-strings])
189 CC_ADD_CHECK_FLAGS([-Wno-unused-parameter])
190 CC_ADD_CHECK_FLAGS([-Wno-format-truncation])
191 CC_ADD_CHECK_FLAGS([-Wno-pointer-sign])
192 CC_ADD_CHECK_FLAGS([-Wpointer-arith])
193 CC_ADD_CHECK_FLAGS([-Wsign-compare])
194 CC_ADD_CHECK_FLAGS([-Wcast-align])
195 
196 AC_CONFIG_HEADERS([config.h])
197 AC_CONFIG_FILES([
198 	Makefile
199 	test/Makefile
200 	pages/about_about.gmi
201 	pages/about_blank.gmi
202 	pages/about_crash.gmi
203 	pages/about_help.gmi
204 	pages/about_license.gmi
205 	pages/about_new.gmi
206 	pages/bookmarks.gmi
207 ])
208 
209 AC_OUTPUT