1 # GotMArc was written by Omar Polo <op@openbsd.org> and is placed in
2 # the public domain.  The author hereby disclaims copyright to this
3 # source code.
4 
5 package GotMArc;
6 use strict;
7 use warnings;
8 use v5.32;
9 use Exporter;
10 use File::Basename;
11 
12 our @ISA = qw(Exporter);
13 our @EXPORT_OK = qw(san urlencode parse initpage endpage index_header thread_header);
14 
15 sub san {
16 	my $str = shift;
17 	$str =~ s/&/\&amp;/g;
18 	$str =~ s/</\&lt;/g;
19 	$str =~ s/>/\&gt;/g;
20 	return $str;
21 }
22 
23 sub urlencode {
24 	my $str = shift;
25 	unless (defined($str)) {
26 		my ($pkg, $file, $line) = caller 1;
27 		die "bad $pkg / $file:$line";
28 	}
29 	$str =~ s/([^-_~.A-Za-z0-9])/sprintf("%%%2X", ord($1))/ge;
30 	return $str;
31 }
32 
33 sub ssan {
34 	my $str = shift;
35 	$str =~ s/\s+/ /g;
36 	$str =~ s/\s+$//;
37 	return san($str);
38 }
39 
40 sub parse {
41 	my ($indent, $fname, $date, $from, $subj) = m{
42 		^([^-]*)-			# the indent level
43 		([^ ]+)\s			# filename
44 		(\d{4}-\d\d-\d\d[ ]\d\d:\d\d)	# date
45 		<([^>]+)>			# from
46 		(.*)				# subject
47 	}x or die "can't parse: $_";
48 
49 	my $level = length($indent);
50 	$level = 10 if $indent =~ m/\.\.\d+\.\./;
51 
52 	$from = ssan($from);
53 	$subj = ssan($subj);
54 
55 	my ($time, $id) = split /\./, basename($fname);
56 	my $mid = "$time.$id";
57 
58 	return {level => $level, fname => $fname,
59 	    mid => $mid, date => $date, from => $from, subj => $subj};
60 }
61 
62 sub readall {
63 	my $path = shift;
64 	local $/ = undef;
65 	open my $fh, "<", $path or die "can't open $path: $!";
66 	<$fh>;
67 }
68 
69 my $small_logo = readall "logo-small.html";
70 my $hdr = readall "head.html";
71 my $foot = readall "foot.html";
72 my $idxhdr = readall "index-header.html";
73 
74 sub initpage {
75 	my ($fh, $title) = @_;
76 	say $fh $hdr =~ s/TITLE/$title/r;
77 }
78 
79 sub endpage {
80 	my $fh = shift;
81 	say $fh $foot;
82 }
83 
84 sub index_header {
85 	my ($fh, $page, $subtitle) = @_;
86 	my $html = $idxhdr =~ s/PAGE/$page/r;
87 	$html =~ s/SUBTITLE/$subtitle/;
88 	print $fh $html;
89 }
90 
91 sub thread_header {
92 	my ($fh, $tid, $mid, $e) = @_;
93 	my @entries = @$e;
94 
95 	my $enctid = urlencode $tid if defined $tid;
96 	my $encmid = urlencode $mid if defined $mid;
97 
98 	print $fh "<header class='mail-header'>\n";
99 
100 	print $fh "<p>";
101 	print $fh $small_logo;
102 	print $fh "<a href='/'>Index</a>";
103 	print $fh " | <a href='/thread/$enctid.html#$encmid'>Thread</a>"
104 	    if defined $enctid;
105 	print $fh "</p>\n";
106 
107 	say $fh "<dl>";
108 	foreach my $entry (@entries) {
109 		my ($k, $v) = split /: /, $entry, 2;
110 		chomp $v;
111 		say $fh "<dt>$k:</dt><dd>$v</dd>";
112 	}
113 	say $fh "</dl>";
114 
115 	say $fh "<p>Download raw <a href='/text/$encmid.txt'>body</a>.</p>"
116 	    if defined $encmid;
117 
118 	say $fh "</header>\n";
119 };
120 
121 1;