1 AC_INIT([kamid], [0.1], [kamid@omarpolo.com], [kamid], [gemini://kamid.omarpolo.com])
2 AC_CONFIG_LIBOBJ_DIR(compat)
3 AC_CANONICAL_HOST
4 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects])
5 AC_PROG_CC
6 AC_USE_SYSTEM_EXTENSIONS
7 AC_PROG_YACC
8 
9 PKG_PROG_PKG_CONFIG
10 
11 # Some functions can be in libbsd.  Thanks to lldpb for the inspiration :)
12 AC_ARG_WITH([libbsd],
13   AS_HELP_STRING([--with-libbsd], [Use libbsd @<:@default=auto@:>@]),
14   [],
15   [with_libbsd=auto])
16 if test x"$with_libbsd" != x"no"; then
17   PKG_CHECK_MODULES([libbsd], [libbsd-overlay libbsd-ctor], [
18     _save_AM_CFLAGS="$AM_CFLAGS"
19     _save_LIBS="$LIBS"
20     AM_CFLAGS="$AM_CFLAGS $libbsd_CFLAGS"
21     LIBS="$LIBS $libbsd_LIBS"
22     AC_MSG_CHECKING([if libbsd can be linked correctly])
23     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
24   @%:@include <sys/time.h>
25   @%:@include <sys/types.h>
26   ]], [[]])],[
27         AC_MSG_RESULT(yes)
28         AM_CFLAGS="$AM_CFLAGS $libbsd_CFLAGS"
29         AM_LDFLAGS="$AM_LDFLAGS $libbsd_LIBS"
30         with_libbsd=yes
31       ],[
32         AC_MSG_RESULT(no)
33         AM_CFLAGS="$_save_AM_CFLAGS"
34         LIBS="$_save_LIBS"
35         if test x"$with_libbsd" = x"yes"; then
36            AC_MSG_FAILURE([*** no libbsd support found])
37         fi
38         with_libbsd=no
39       ])
40   ], [
41     if test x"$with_libbsd" = x"yes"; then
42        AC_MSG_FAILURE([*** no libbsd support found])
43     fi
44     with_libbsd=no
45   ])
46 fi
47 
48 AC_SEARCH_LIBS([arc4random], [],
49 	[AC_DEFINE([HAVE_ARC4RANDOM], 1, [arc4random])],
50 	[AC_DEFINE([HAVE_ARC4RANDOM], 0, [arc4random])])
51 
52 AC_REPLACE_FUNCS([
53 	asprintf	\
54 	err		\
55 	freezero	\
56 	getdtablecount	\
57 	getdtablesize	\
58 	getprogname	\
59 	memmem		\
60 	recallocarray	\
61 	setproctitle	\
62 	setprogname	\
63 	strlcat		\
64 	strlcpy		\
65 	strsep		\
66 	strtonum	\
67 ])
68 
69 AC_MSG_CHECKING([for sys/queue.h with TAILQ_FOREACH_SAFE and STAILQ_ENTRY])
70 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
71 #include <sys/queue.h>
72 #include <stddef.h>
73 ], [
74 	TAILQ_HEAD(tailhead, entry) head;
75 	struct entry {
76 		TAILQ_ENTRY(entry) entries;
77 	} *np, *nt;
78 	TAILQ_INIT(&head);
79 	TAILQ_FOREACH_SAFE(np, &head, entries, nt) {
80 		/* nop */ ;
81 	}
82 
83 	STAILQ_HEAD(listhead, qentry) qhead = STAILQ_HEAD_INITIALIZER(qhead);
84 	struct qentry {
85 		STAILQ_ENTRY(qentry) entries;
86 	} foo;
87 
88 	return 0;
89 ])], [
90 	AC_MSG_RESULT(yes)
91 	AC_DEFINE([HAVE_QUEUE_H], 1, [QUEUE_H])
92 ], AC_MSG_RESULT(no))
93 
94 AC_CHECK_HEADERS([sys/tree.h])
95 
96 AC_CHECK_DECL(PR_SET_NAME, AC_DEFINE([HAVE_PR_SET_NAME], 1, [pr_set_name]), [],
97 	[[#include <sys/prctl.h>]])
98 
99 AC_CHECK_LIB([crypto], [RAND_add], [], [
100 	AC_MSG_ERROR([requires openssl])
101 ])
102 
103 AC_CHECK_LIB(tls, tls_init, [], [
104 	AC_MSG_ERROR([requires libtls])
105 ])
106 
107 # small hack to avoid linking *everything* to readline.
108 libs_orig="${LIBS}"
109 AC_CHECK_LIB(readline, readline, [], [
110 	AC_DEFINE([HAVE_READLINE], 0, [1 if readline is found])
111 ])
112 KAMIFTP_LIBS="${LIBS}"
113 LIBS="${libs_orig}"
114 AC_SUBST([KAMIFTP_LIBS])
115 
116 AS_CASE([$host_os],
117 	[*openbsd*], [AC_CHECK_LIB([event], [event_init], [],
118 			[AC_MSG_ERROR([requires libevent])])],
119 	[PKG_CHECK_MODULES([libevent2], [libevent_core >= 2],
120 		[
121 			AC_DEFINE([HAVE_EVENT2], 1, [1 if using event2])
122 			AM_CFLAGS="$libevent2_CFLAGS $AM_CFLAGS"
123 			LIBS="$libevent2_LIBS $LIBS"
124 		], [AC_MSG_ERROR([requires libevent])])])
125 
126 AC_CHECK_LIB(util, imsg_init, [], [
127 	AC_LIBOBJ(imsg)
128 	AC_LIBOBJ(imsg-buffer)
129 	AC_LIBOBJ(ohash)
130 ])
131 
132 # check compiler flags
133 AC_DEFUN([CC_ADD_CHECK_FLAGS], [
134 	AC_MSG_CHECKING([if $CC supports $1 flag])
135 	old_AM_CFLAGS="$AM_CFLAGS"
136 	AM_CFLAGS="$AM_CFLAGS $1"
137 	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], [
138 		AC_MSG_RESULT(yes)
139 	], [
140 		AC_MSG_RESULT(no)
141 		AM_CFLAGS="$old_AM_CFLAGS"
142 	])
143 ])
144 CC_ADD_CHECK_FLAGS([-Wall])
145 CC_ADD_CHECK_FLAGS([-Wextra])
146 CC_ADD_CHECK_FLAGS([-Wmissing-prototypes])
147 CC_ADD_CHECK_FLAGS([-Wstrict-prototypes])
148 CC_ADD_CHECK_FLAGS([-Wwrite-strings])
149 CC_ADD_CHECK_FLAGS([-Wno-unused-parameter])
150 
151 AC_SUBST([AM_CFLAGS])
152 
153 AC_CONFIG_HEADERS([config.h])
154 AC_CONFIG_FILES([
155 	Makefile
156 ])
157 
158 AC_OUTPUT