1 /*
2  * Much of the design is taken from doas (parse.y rev 1.29)
3  *
4  * Copyright (c) 2021 Omar Polo <op@omarpolo.com>
5  * Copyright (c) 2015 Ted Unangst <tedu@openbsd.org>
6  *
7  * Permission to use, copy, modify, and distribute this software for any
8  * purpose with or without fee is hereby granted, provided that the above
9  * copyright notice and this permission notice appear in all copies.
10  *
11  * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
12  * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
13  * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
14  * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
15  * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
16  * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
17  * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
18  *
19  */
20 
21 %{
22 
23 #include "telescope.h"
24 
25 #include <phos/phos.h>
26 
27 #include <assert.h>
28 #include <ctype.h>
29 #include <limits.h>
30 #include <ncurses.h>
31 #include <stdarg.h>
32 #include <stdio.h>
33 #include <stdlib.h>
34 #include <string.h>
35 
36 typedef struct {
37 	union {
38 		char	*str;
39 		int	 num;
40 	};
41 	int lineno;
42 	int colno;
43 } yystype;
44 #define YYSTYPE yystype
45 
46 static char *current_style;
47 static int color_type;
48 
49 static const char *path;
50 
51 FILE *yyfp;
52 
53 int parse_errors = 0;
54 
55 static void yyerror(const char *, ...);
56 static int yylex(void);
57 static void setprfx(const char *, const char *);
58 static void setvari(char *, int);
59 static void setvars(char *, char *);
60 static int colorname(const char *);
61 static void setcolor(const char *, const char *, const char *);
62 static int attrname(char *);
63 static void setattr(char *, char *, char *);
64 static void add_proxy(char *, char *);
65 
66 %}
67 
68 %token TSET
69 %token TSTYLE TPRFX TCONT TBG TFG TATTR
70 %token TBIND TUNBIND
71 %token TPROXY TVIA
72 
73 %token <str> TSTRING
74 %token <num> TNUMBER
75 
76 %%
77 
78 grammar		: /* empty */
79 		| grammar '\n'
80 		| grammar rule '\n'
81 		| error '\n'
82 		;
83 
84 rule		: set
85 		| style {
86 			free(current_style);
87 			current_style = NULL;
88 		}
89 		| bind
90 		| unbind
91 		| proxy
92 		;
93 
94 set		: TSET TSTRING '=' TSTRING	{ setvars($2, $4); }
95 		| TSET TSTRING '=' TNUMBER	{ setvari($2, $4); }
96 		;
97 
98 style		: TSTYLE TSTRING { current_style = $2; } stylespec ;
99 stylespec	: styleopt | '{' styleopts '}' ;
100 
101 styleopts	: /* empty */
102 		| styleopts '\n'
103 		| styleopts styleopt '\n'
104 		;
105 
106 styleopt	: TPRFX TSTRING		{ setprfx($2, $2); }
107 		| TPRFX TSTRING TSTRING	{ setprfx($2, $2); }
108 		| TBG { color_type = TBG; } colorspec
109 		| TFG { color_type = TFG; } colorspec
110 		| TATTR attr
111 		;
112 
113 colorspec	: TSTRING			{ setcolor($1, $1, $1); free($1); }
114 		| TSTRING TSTRING		{ setcolor($1, $2, $1); free($1); free($2); }
115 		| TSTRING TSTRING TSTRING	{ setcolor($1, $2, $3); free($1); free($2); free($3); }
116 		;
117 
118 attr		: TSTRING			{ setattr($1, $1, $1); free($1); }
119 		| TSTRING TSTRING		{ setattr($1, $2, $1); free($1); free($2); }
120 		| TSTRING TSTRING TSTRING	{ setattr($1, $2, $3); free($1); free($2); free($3); }
121 		;
122 
123 bind		: TBIND TSTRING TSTRING TSTRING	{ printf("TODO: bind %s %s %s\n", $2, $3, $4); }
124 		;
125 
126 unbind		: TUNBIND TSTRING TSTRING	{ printf("TODO: unbind %s %s\n", $2, $3); }
127 		;
128 
129 proxy		: TPROXY TSTRING TVIA TSTRING { add_proxy($2, $4); free($4); }
130 		;
131 
132 %%
133 
134 void
135 yyerror(const char *fmt, ...)
136 {
137 	va_list va;
138 
139 	fprintf(stderr, "%s:%d ", path, yylval.lineno+1);
140 	va_start(va, fmt);
141 	vfprintf(stderr, fmt, va);
142 	va_end(va);
143 	fprintf(stderr, "\n");
144 	parse_errors++;
145 }
146 
147 static struct keyword {
148 	const char *word;
149 	int token;
150 } keywords[] = {
151 	{ "attr", TATTR },
152 	{ "bg", TBG },
153 	{ "bind", TBIND },
154 	{ "cont", TCONT },
155 	{ "fg", TFG },
156 	{ "prefix", TPRFX },
157 	{ "proxy", TPROXY },
158 	{ "set", TSET },
159 	{ "style", TSTYLE },
160 	{ "unbind", TUNBIND },
161 	{ "via", TVIA },
162 };
163 
164 int
165 yylex(void)
166 {
167 	char buf[1024], *ebuf, *p, *str;
168 	const char *errstr;
169 	int c, quotes = 0, escape = 0, qpos = -1, nonkw = 0;
170 	size_t i;
171 
172 	p = buf;
173 	ebuf = buf + sizeof(buf);
174 
175 repeat:
176 	/* skip whitespace first */
177 	for (c = getc(yyfp); c == ' ' || c == '\t' || c == '\f'; c = getc(yyfp))
178 		yylval.colno++;
179 
180 	/* check for special one-character constructions */
181 	switch (c) {
182 	case '\r':
183 		/* silently eat up any \r */
184 		goto repeat;
185 	case '\n':
186 		yylval.colno = 0;
187 		yylval.lineno++;
188 		/* fallthrough */
189 	case '{':
190 	case '}':
191 	case '=':
192 		return c;
193 	case '#':
194 		/* skip comments; NUL is allowed; no continuation */
195 		while ((c = getc(yyfp)) != '\n')
196 			if (c == EOF)
197 				goto eof;
198 		yylval.colno = 0;
199 		yylval.lineno++;
200 		return c;
201 	case EOF:
202 		goto eof;
203 	}
204 
205 	/* parsing next word */
206 	for (;; c = getc(yyfp), yylval.colno++) {
207 		switch (c) {
208 		case '\0':
209 			yyerror("unallowed character NULL in column %d",
210 			    yylval.colno+1);
211 			escape = 0;
212 			continue;
213 		case '\\':
214 			escape = !escape;
215 			if (escape)
216 				continue;
217 			break;
218 		case '\n':
219 			if (quotes)
220 				yyerror("unterminated quotes in column %d",
221 				    yylval.colno+1);
222 			if (escape) {
223 				nonkw = 1;
224 				escape = 0;
225 				yylval.colno = 0;
226 				yylval.lineno++;
227 			}
228 			goto eow;
229 		case EOF:
230 			if (escape)
231 				yyerror("unterminated escape in column %d",
232 				    yylval.colno);
233 			if (quotes)
234 				yyerror("unterminated quotes in column %d",
235 				    qpos + 1);
236 			goto eow;
237 		case '{':
238 		case '}':
239 		case '=':
240 		case '#':
241 		case ' ':
242 		case '\t':
243 			if (!escape && !quotes)
244 				goto eow;
245 			break;
246 		case '"':
247 			if (!escape) {
248 				quotes = !quotes;
249 				if (quotes) {
250 					nonkw = 1;
251 					qpos = yylval.colno;
252 				}
253 				continue;
254 			}
255 		}
256 		*p++ = c;
257 		if (p == ebuf) {
258 			yyerror("line too long");
259 			p = buf;
260 		}
261 		escape = 0;
262 	}
263 
264 eow:
265 	*p = 0;
266 	if (c != EOF)
267 		ungetc(c, yyfp);
268 	if (p == buf) {
269 		/*
270 		 * There could be a number of reason for empty buffer,
271 		 * and we handle all of them here, to avoid cluttering
272 		 * the main loop.
273 		 */
274 		if (c == EOF)
275 			goto eof;
276 		else if (qpos == -1) /* accept, e.g., empty args: cmd foo args "" */
277 			goto repeat;
278 	}
279 	if (!nonkw) {
280 		for (i = 0; i < sizeof(keywords) / sizeof(keywords[0]); i++) {
281 			if (strcmp(buf, keywords[i].word) == 0)
282 				return keywords[i].token;
283 		}
284 	}
285 	c = *buf;
286 	if (!nonkw && (c == '-' || isdigit(c))) {
287 		yylval.num = strtonum(buf, INT_MIN, INT_MAX, &errstr);
288 		if (errstr != NULL)
289 			yyerror("number is %s: %s", errstr, buf);
290 		return TNUMBER;
291 	}
292 	if ((str = strdup(buf)) == NULL)
293 		err(1, "%s", __func__);
294 	yylval.str = str;
295 	return TSTRING;
296 
297 eof:
298 	if (ferror(yyfp))
299 		yyerror("input error reading config");
300 	return 0;
301 }
302 
303 static void
304 setprfx(const char *prfx, const char *cont)
305 {
306 	assert(current_style != NULL);
307 
308 	if (!config_setprfx(current_style, prfx, cont))
309 		yyerror("invalid style %s", current_style);
310 }
311 
312 static void
313 setvari(char *var, int val)
314 {
315 	if (!config_setvari(var, val))
316 		yyerror("invalid variable or value: %s = %d",
317 		    var, val);
318 
319 	free(var);
320 }
321 
322 static void
323 setvars(char *var, char *val)
324 {
325         if (!config_setvars(var, val))
326 		yyerror("invalid variable or value: %s = \"%s\"",
327 		    var, val);
328 
329 	free(var);
330 }
331 
332 static int
333 colorname(const char *name)
334 {
335 	struct {
336 		const char	*name;
337 		short		 val;
338 	} *i, colors[] = {
339 		{ "default",	-1 },
340 		{ "black",	COLOR_BLACK },
341 		{ "red",	COLOR_RED },
342 		{ "green",	COLOR_GREEN },
343 		{ "yellow",	COLOR_YELLOW },
344 		{ "blue",	COLOR_BLUE },
345 		{ "magenta",	COLOR_MAGENTA },
346 		{ "cyan",	COLOR_CYAN },
347 		{ "white",	COLOR_WHITE },
348 		{ NULL, 0 },
349 	};
350 	const char *errstr;
351 	int n;
352 
353 	if (has_prefix(name, "colo")) {
354 		/* people are strange */
355 		if (has_prefix(name, "color"))
356 			name += 5;
357 		else if (has_prefix(name, "colour"))
358 			name += 6;
359 		else
360 			goto err;
361 
362 		n = strtonum(name, 0, 256, &errstr);
363 		if (errstr != NULL)
364 			yyerror("color number is %s: %s", errstr, name);
365 		return n;
366 	}
367 
368 	for (i = colors; i->name != NULL; ++i) {
369 		if (!strcmp(i->name, name))
370 			return i->val;
371 	}
372 
373 err:
374 	yyerror("unknown color name \"%s\"", name);
375 	return -1;
376 }
377 
378 void
379 setcolor(const char *prfx, const char *line, const char *trail)
380 {
381 	int p, l, t;
382 
383 	assert(current_style != NULL);
384 
385 	p = colorname(prfx);
386 	l = colorname(line);
387 	t = colorname(trail);
388 
389 	if (!config_setcolor(color_type == TBG, current_style, p, l, t))
390 		yyerror("invalid style %s", current_style);
391 }
392 
393 static int
394 attrname(char *n)
395 {
396 	struct {
397 		const char	*name;
398 		unsigned int	 val;
399 	} *i, attrs[] = {
400 		{ "normal",	A_NORMAL },
401 		{ "standout",	A_STANDOUT },
402 		{ "underline",	A_UNDERLINE },
403 		{ "reverse",	A_REVERSE },
404 		{ "blink",	A_BLINK },
405 		{ "dim",	A_DIM },
406 		{ "bold",	A_BOLD },
407 		{ NULL, 0 },
408 	};
409 	int ret, found;
410 	char *ap;
411 
412 	ret = 0;
413 	while ((ap = strsep(&n, ",")) != NULL) {
414 		if (*ap == '\0')
415 			continue;
416 
417 		found = 0;
418 		for (i = attrs; i ->name != NULL; ++i) {
419 			if (strcmp(i->name, ap))
420 				continue;
421 			ret |= i->val;
422 			found = 1;
423 			break;
424 		}
425 
426 		if (!found)
427 			yyerror("unknown attribute \"%s\" at col %d",
428 			    ap, yylval.colno+1);
429 	}
430 
431 	return ret;
432 }
433 
434 static void
435 setattr(char *prfx, char *line, char *trail)
436 {
437 	int p, l, t;
438 
439 	assert(current_style != NULL);
440 
441 	p = attrname(prfx);
442 	l = attrname(line);
443 	t = attrname(trail);
444 
445 	if (!config_setattr(current_style, p, l, t))
446 		yyerror("invalid style %s", current_style);
447 }
448 
449 static void
450 add_proxy(char *proto, char *proxy)
451 {
452 	struct proxy *p;
453 	struct phos_uri uri;
454 
455 	if (!phos_parse_absolute_uri(proxy, &uri)) {
456 		yyerror("can't parse URL: %s", proxy);
457 		return;
458 	}
459 
460 	if (*uri.path != '\0' || *uri.query != '\0' || *uri.fragment != '\0') {
461 		yyerror("proxy url can't have path, query or fragments");
462 		return;
463 	}
464 
465 	if (strcmp(uri.scheme, "gemini")) {
466 		yyerror("disallowed proxy protocol %s", uri.scheme);
467 		return;
468 	}
469 
470 	if ((p = calloc(1, sizeof(*p))) == NULL)
471 		err(1, "calloc");
472 
473 	p->match_proto = proto;
474 
475 	if ((p->host = strdup(uri.host)) == NULL)
476 		err(1, "strdup");
477 
478 	if ((p->port = strdup(uri.port)) == NULL)
479 		err(1, "strdup");
480 
481 	TAILQ_INSERT_HEAD(&proxies, p, proxies);
482 }
483 
484 void
485 parseconfig(const char *filename, int fonf)
486 {
487 	if ((yyfp = fopen(filename, "r")) == NULL) {
488 		if (fonf)
489 			err(1, "%s", filename);
490 		return;
491 	}
492 
493 	path = filename;
494 	yyparse();
495 	fclose(yyfp);
496 	if (parse_errors)
497 		exit(1);
498 }