1 # GotMArc was written by Omar Polo <op@openbsd.org> and is placed in
2 # the public domain.  The author hereby disclaims copyright to this
3 # source code.
4 
5 package GotMArc;
6 use strict;
7 use warnings;
8 use v5.32;
9 use Exporter;
10 use File::Basename;
11 
12 our @ISA = qw(Exporter);
13 our @EXPORT_OK = qw(san urlencode parse initpage endpage index_header
14     thread_header threntry);
15 
16 sub san {
17 	my $str = shift;
18 	$str =~ s/&/\&amp;/g;
19 	$str =~ s/</\&lt;/g;
20 	$str =~ s/>/\&gt;/g;
21 	return $str;
22 }
23 
24 sub urlencode {
25 	my $str = shift;
26 	unless (defined($str)) {
27 		my ($pkg, $file, $line) = caller 1;
28 		die "bad $pkg / $file:$line";
29 	}
30 	$str =~ s/([^-_~.A-Za-z0-9])/sprintf("%%%2X", ord($1))/ge;
31 	return $str;
32 }
33 
34 sub ssan {
35 	my $str = shift;
36 	$str =~ s/\s+/ /g;
37 	$str =~ s/\s+$//;
38 	return san($str);
39 }
40 
41 sub parse {
42 	my $line = shift;
43 	my ($indent, $fname, $date, $from, $subj) = $line =~ m{
44 		^([^-]*)-			# the indent level
45 		([^ ]+)\s			# filename
46 		(\d{4}-\d\d-\d\d[ ]\d\d:\d\d)	# date
47 		<([^>]+)>			# from
48 		(.*)				# subject
49 	}x or die "can't parse: $line";
50 
51 	my $level = length($indent);
52 	$level = 10 if $indent =~ m/\.\.\d+\.\./;
53 
54 	$from = ssan($from);
55 	$subj = ssan($subj);
56 
57 	my ($time, $id) = split /\./, basename($fname);
58 	my $mid = "$time.$id";
59 
60 	return {level => $level, fname => $fname,
61 	    mid => $mid, date => $date, from => $from, subj => $subj};
62 }
63 
64 sub readall {
65 	my $path = shift;
66 	local $/ = undef;
67 	open my $fh, "<", $path or die "can't open $path: $!";
68 	<$fh>;
69 }
70 
71 my $small_logo = readall "logo-small.html";
72 my $hdr = readall "head.html";
73 my $foot = readall "foot.html";
74 my $idxhdr = readall "index-header.html";
75 
76 sub initpage {
77 	my ($fh, $title) = @_;
78 	say $fh $hdr =~ s/TITLE/$title/r;
79 }
80 
81 sub endpage {
82 	my $fh = shift;
83 	say $fh $foot;
84 }
85 
86 sub index_header {
87 	my ($fh, $page, $subtitle) = @_;
88 	my $html = $idxhdr =~ s/PAGE/$page/r;
89 	$html =~ s/SUBTITLE/$subtitle/;
90 	print $fh $html;
91 }
92 
93 sub thread_header {
94 	my ($fh, $tid, $mid, $e) = @_;
95 	my @entries = @$e;
96 
97 	my $enctid = urlencode $tid if defined $tid;
98 	my $encmid = urlencode $mid if defined $mid;
99 
100 	print $fh "<header class='mail-header'>\n";
101 
102 	print $fh "<p>";
103 	print $fh $small_logo;
104 	print $fh "<a href='/'>Index</a>";
105 	print $fh " | <a href='/thread/$enctid.html#$encmid'>Thread</a>"
106 	    if defined $enctid;
107 	print $fh " | <a href='/search'>Search</a>";
108 	print $fh "</p>\n";
109 
110 	say $fh "<dl>";
111 	foreach my $entry (@entries) {
112 		my ($k, $v) = split /: /, $entry, 2;
113 		chomp $v;
114 		say $fh "<dt>$k:</dt><dd>$v</dd>";
115 	}
116 	say $fh "</dl>";
117 
118 	say $fh "<p>Download raw <a href='/text/$encmid.txt'>body</a>.</p>"
119 	    if defined $encmid;
120 
121 	say $fh "</header>\n";
122 }
123 
124 sub threntry {
125 	my ($fh, $type, $base, $last_level, $mail, $cur) = @_;
126 	my $level = $mail->{level} - $base;
127 
128 	say $fh "</ul></li>" x ($last_level - $level) if $last_level > $level;
129 	say $fh "<li><ul>" if $last_level < $level;
130 
131 	my $encmid = urlencode $mail->{mid};
132 
133 	print $fh "<li id='$encmid' class='mail'>";
134 	print $fh "<p class='mail-meta'>";
135 	print $fh "<time>$mail->{date}</time> ";
136 	print $fh "<span class='from'>$mail->{from}</span>";
137 	print $fh "<span class='colon'>:</span>";
138 	print $fh "</p>";
139 	print $fh "<p class='subject'>";
140 
141 	my $subj = $mail->{subj};
142 	if (!defined($cur) || $mail->{mid} ne $cur->{mid}) {
143 		print $fh "<a href='/$type/$encmid.html'>$subj</a>";
144 	} else {
145 		print $fh "<span>$subj</span>";
146 	}
147 
148 	print $fh "</p>";
149 	print $fh "</li>";
150 
151 	return $level;
152 }
153 
154 1;