1 #!/usr/bin/env perl
2 
3 use open ":std", ":encoding(UTF-8)";
4 use utf8;
5 use strict;
6 use warnings;
7 use v5.32;
8 
9 use OpenBSD::Pledge;
10 use OpenBSD::Unveil;
11 
12 use lib ".";
13 use GotMArc qw($logo parse san initpage endpage);
14 
15 my $outdir = $ENV{'OUTDIR'};
16 die 'Set $OUTDIR' unless defined $outdir;
17 
18 my $tfh; # thread file handle
19 my $pfh; # page file handle
20 my $page = 0;
21 my @pages;
22 my $from_day;
23 my $to_day;
24 my $threads_seen = 0;
25 my $last_level = 0;
26 my $entries = 0;
27 my $entries_per_page = 100;
28 
29 sub maxs {
30 	my ($a, $b) = @_;
31 	return $a unless defined $b;
32 	return $a gt $b ? $a : $b;
33 }
34 
35 sub mins {
36 	my ($a, $b) = @_;
37 	return $a unless defined $b;
38 	return $a lt $b ? $a : $b;
39 }
40 
41 sub pagename {
42 	my $i = shift;
43 	return $i == 1 && "index.html" || "$i.html";
44 }
45 
46 sub endfile {
47 	say $pfh '</ul></div>';
48 	close($pfh);
49 	push @pages, "$from_day - $to_day";
50 }
51 
52 sub nextfile {
53 	endfile if defined $pfh;
54 	$page += 1;
55 	my $path = pagename($page);
56 	open($pfh, '>', $path)
57 	    or die "can't open $path: $!";
58 	say $pfh "<div class='thread'><ul>";
59 }
60 
61 sub nav {
62 	my ($pfh, $first, $last, $n) = @_;
63 	my ($next, $prev) = (pagename($n+1), pagename($n-1));
64 
65 	say $pfh "<nav class='next-prev'>";
66 	say $pfh "<a href='$first'>First</a>" if $n > 2;
67 	say $pfh "<a href='$prev'>Prev</a>" if $n > 1;
68 	say $pfh "<a href='$next'>Next</a>" if $n < $page;
69 	say $pfh "<a href='$last'>Last</a>" if $n < $page - 1;
70 	say $pfh "</nav>";
71 }
72 
73 sub copyfrom {
74 	my ($path, $fh) = @_;
75 
76 	# there are probably faster ways to do this like File::Copy,
77 	# but it bypasses the bufio cache...
78 	open(my $pfh, '<', $path) or die "can't open $path: $!";
79 	print $fh $_ while (<$pfh>);
80 }
81 
82 sub fixfiles {
83 	close($pfh);
84 
85 	my ($first, $last) = (pagename(0), pagename($page));
86 
87 	for (my $i = 1; $i <= $page; $i++) {
88 		my $path = pagename($i);
89 		my $dest = "$outdir/$path";
90 
91 		open(my $pfh, '>', $dest)
92 		    or die "can't open $dest for writing: $!";
93 
94 		my $title = "Game of Trees Mail Archive | page $i";
95 		initpage($pfh, $title);
96 
97 		my $subtitle = $pages[$i-1];
98 
99 		my $hdr = <<EOF;
100 <header class='index-header'>
101   <a href="https://gameoftrees.org" target="_blank">
102     <img src='/got.png'
103          srcset='/got.png, /got@2x.png 2x'
104          alt='"GOT" where the "O" is a cute smiling sun.' />
105   </a>
106   <h1>Game of Trees Mail Archive</h1>
107   <p>Page $i</p>
108   <p>$subtitle</p>
109 </header>
110 <main>
111 EOF
112 		say $pfh $hdr;
113 
114 		nav $pfh, $first, $last, $i if $page > 1;
115 		copyfrom($path, $pfh);
116 		nav $pfh, $first, $last, $i if $page > 1;
117 
118 		say $pfh "</main>";
119 
120 		endpage($pfh);
121 		close($pfh);
122 
123 		unlink $path;
124 	}
125 }
126 
127 sub nextthread {
128 	endthread() if defined($tfh);
129 	my ($mid, $subj) = @_;
130 	my $dest = "$outdir/thread/$mid.html";
131 	open($tfh, '>', $dest) or die "can't open $dest: $!";
132 	initpage($tfh, $subj);
133 
134 	print $tfh "<header class='mail-header'>";
135 	print $tfh "<p>";
136 	print $tfh $logo;
137 	print $tfh "<a href='/'>Index</a>";
138 	print $tfh "</p>";
139 	print $tfh "<dl><dt>Thread:</dt><dd>$subj</dd></dl>";
140 	print $tfh "</header>\n";
141 	# print $tfh "<div class='thread'><ul class='mails'>\n";
142 }
143 
144 sub endthread {
145 	say $tfh "</ul></li>" x $last_level;
146 	say $tfh "</ul></div>\n";
147 	endpage($tfh);
148 	close($tfh);
149 
150 	$last_level = 0;
151 }
152 
153 sub entry {
154 	my ($fh, $type, $mid, $date, $from, $subj) = @_;
155 	print $fh "<li id='$mid' class='mail'>";
156 	print $fh "<p class='mail-meta'>";
157 	print $fh "<time>$date</time> ";
158 	print $fh "<span class='from'>$from</span>";
159 	print $fh "<span class='colon'>:</span>";
160 	print $fh "</p>";
161 	print $fh "<p class='subject'>";
162 	print $fh "<a href='/$type/$mid.html'>$subj</a>";
163 	print $fh "</p>";
164 	print $fh "</li>\n";
165 }
166 
167 sub thread_entry {
168 	my ($fh, $mid, $level, $date, $from, $subj) = @_;
169 
170 	say $fh "</ul>\n</li>" x ($last_level - $level) if $last_level > $level;
171 	say $fh "</ul>\n</div>" if $threads_seen && $level == 0;
172 
173 	say $fh "<div class='thread'>" if $level == 0;
174 
175 	if ($last_level < $level) {
176 		say $fh "<li>\n<ul>";
177 	} elsif ($last_level == 0) {
178 		say $fh "<ul class='mails'>";
179 	}
180 
181 	entry $fh, "mail", $mid, $date, $from, $subj;
182 }
183 
184 unveil($outdir, "rwc") or die "unveil $outdir: $!";
185 unveil(".", "rwc") or die "unveil .: $!";
186 
187 pledge("stdio rpath wpath cpath") or die "pledge: $!";
188 
189 nextfile;
190 
191 while (<>) {
192 	my ($level, $fname, $mid, $date, $from, $subj) = parse;
193 	my $day = $date =~ s/ .*//r;
194 
195 	if ($level == 0) {
196 		nextthread $mid, $subj;
197 
198 		$entries++;
199 		if ($entries > $entries_per_page) {
200 			nextfile;
201 			$entries = 0;
202 			$to_day = undef;
203 			$from_day = undef;
204 		}
205 		entry $pfh, "thread", $mid, $date, $from, $subj;
206 	}
207 
208 	$to_day = mins $day, $to_day;
209 	$from_day = maxs $day, $from_day;
210 
211 	thread_entry($tfh, $mid, $level, $date, $from, $subj);
212 	$last_level = $level;
213 	$threads_seen = 1;
214 }
215 
216 endfile;
217 endthread if $threads_seen;
218 fixfiles();