1 awk '
2 function error(s) { print "dformat error: " s " near input line " NR | "cat 1>&2" }
3 
4 BEGIN { s =   "recht 0.3        addrht 0.055    recspread 0.15 "
5         s = s "charwid 0.07     textht 0.167    addrdelta 4 "
6         s = s "bitwid 0.125     linedisp 0.04   addr both "
7         s = s "fill off         linethrutext 1"
8         n = split(s, x)
9         for (i = 1; i <= n-1; i += 2) oparm[x[i]] = parm[x[i]] = x[i+1]
10 }
11 
12 inlang == 0   { if ($0 !~ /^\.begin[ \t]/ || $2 != "dformat") print
13                 else {
14                         inlang = 1; print ".PS"; boxacnt = 0
15                         if (firstpic != 1) { firstpic = 1; print "fillval = 0.9" }
16                 }
17                 next
18               }
19 /^\.end/      { inlang = 0; print ".PE"; next }
20 
21 $1 == "style" { if (!($2 in parm)) error("unrecognized name: " $2)
22                 else if ($3 == "reset") {
23                         t = oparm[$2]; oparm[$2] = parm[$2]; parm[$2] = t
24                 } else {
25                         oparm[$2] = parm[$2]; parm[$2] = $3
26                 }
27                 next
28               }
29 
30 $1 == "pic"   { $1 = ""; print $0; next }
31 
32 /^[^ \t]/     { printf "BoxA: box invis ht %g wid 0", parm["recht"]
33                 if (boxacnt++) printf " with .n at BoxA.s - (0,%g)",
34                                 parm["recspread"] + maxdy*parm["textht"]
35                 printf "\n"
36                 maxdy = sumboxlen = 0
37                 gsub(/[ \t]+$/, "")
38                 if ($0 != "noname") {
39                         printf " \"%s  \" rjust at BoxA.w\n", $0
40                         printf " box invis with .e at BoxA.w ht 0 wid %g\n",
41                                 parm["charwid"] * (length($0) + 3)
42                 }
43                 printf " BoxB: box invis ht %g wid 0 at BoxA\n", parm["recht"]
44                 next
45               }
46 /./           { boxname = ""
47                 if ($1 ~ /:$/) {
48                         boxname = substr($1, 1, length($1)-1)
49                         $1 = ""; $0 = " " $0
50                 }
51                 range = $1; $1 = ""
52                 gsub(/^[ \t]+/, ""); gsub(/[ \t]+$/, ""); text = $0
53                 n = split(range, x, "-")
54                 rlo =                   x[1]
55                 rhi =   (n >= 2) ?      x[2]  : rlo
56                 cwid = (rhi >= rlo) ? rhi - rlo + 1 : rlo - rhi + 1
57                 rwid =  (n >= 3) ? (0 + x[3]) : cwid
58                 btype =                 x[4]
59                 if (btype !~ /^(dot|dash|invis)/) btype = "solid"
60                 textlen = parm["charwid"] * length(text)
61                 boxlen = parm["bitwid"] * rwid
62                 dy = 0
63                 if (textlen > boxlen) { # set dy, the channel for this text
64                         chan[maxdy+1] = -999
65                         for (dy = 1; chan[dy]+textlen > sumboxlen; dy++) ;
66                         if (dy > maxdy) maxdy = dy
67                         if (parm["linethrutext"] == 0)
68                                 for (k = 1; k <= dy; k++)
69                                         chan[k] = sumboxlen+boxlen
70                         else
71                                 chan[dy] = sumboxlen
72                 }
73                 sumboxlen += boxlen
74                 fill = ""
75                 if (parm["fill"] == "on") fill = " fill "
76                 if (boxname != "") printf "  %s:", boxname
77                 printf "  BoxB: box %s %s ht %g wid %g with .w at BoxB.e\n",
78                         fill, btype, parm["recht"], boxlen
79                 if (dy == 0) printf "    \"%s\" at BoxB.c\n", text
80                 else {  if (rwid < 2) start = "BoxB.s"
81                         else start = "BoxB.se - (" parm["linedisp"] ",0)"
82                         printf "    line from %s down %g\n",
83                                 start, dy*parm["textht"]
84                         printf "    \"%s\\|\" at last line .s rjust\n", text
85                         printf "    box invis with .e at last line .s ht 0 wid %g\n",
86                                 textlen
87                 }
88 
89                 if (parm["addr"] ~ /^(left|right|both)$/) {
90                     dp = int(parm["addrdelta"])     # Delta Point size
91                     if (dp < 0 || dp > 9) error("bad addrdelta value: " dp)
92                     dah = parm["addrht"]            # Delta Addr Height
93                     pb = parm["addr"]               # Parameter for Bits
94                     if (rlo == rhi) {
95                         printf "    \"\\s-%d%s\\s+%d\" at BoxB.s + (0,%g)\n",
96                                 dp, rlo, dp, dah
97                     } else {
98                         if (pb == "left" || pb == "both")
99                             printf "\t\"\\|\\s-%d%s\\s+%d\" ljust at BoxB.sw + (0,%g)\n",
100                                 dp, rlo, dp, dah
101                         if (pb == "right" || pb == "both")
102                             printf "\t\"\\s-%d%s\\s+%d\\|\" rjust at BoxB.se + (0,%g)\n",
103                                 dp, rhi, dp, dah
104                     }
105                 }
106               }
107 END           { if (inlang) error("eof inside begin/end") }
108 ' $*