1 // 386 support
2 
3 defn acidinit()			// Called after all the init modules are loaded
4 {
5 	bplist = {};
6 	bpfmt = 'b';
7 
8 	srcpath = {
9 		"./",
10 		"/sys/src/libc/port/",
11 		"/sys/src/libc/9sys/",
12 		"/sys/src/libc/386/"
13 	};
14 
15 	srcfiles = {};			// list of loaded files
16 	srctext = {};			// the text of the files
17 }
18 
19 defn linkreg(addr)
20 {
21 	return {};
22 }
23 
24 defn stk()				// trace
25 {
26 	_stk({"PC", *PC, "SP", *SP}, 0);
27 }
28 
29 defn lstk()				// trace with locals
30 {
31 	_stk({"PC", *PC, "SP", *SP}, 1);
32 }
33 
34 defn gpr()		// print general(hah hah!) purpose registers
35 {
36 	print("AX\t", *AX, " BX\t", *BX, " CX\t", *CX, " DX\t", *DX, "\n");
37 	print("DI\t", *DI, " SI\t", *SI, " BP\t", *BP, "\n");
38 }
39 
40 defn spr()				// print special processor registers
41 {
42 	local pc;
43 	local cause;
44 
45 	pc = *PC;
46 	print("PC\t", pc, " ", fmt(pc, 'a'), "  ");
47 	pfl(pc);
48 	print("SP\t", *SP, " ECODE ", *ECODE, " EFLAG ", *EFLAGS, "\n");
49 	print("CS\t", *CS, " DS\t ", *DS, " SS\t", *SS, "\n");
50 	print("GS\t", *GS, " FS\t ", *FS, " ES\t", *ES, "\n");
51 	
52 	cause = *TRAP;
53 	print("TRAP\t", cause, " ", reason(cause), "\n");
54 }
55 
56 defn regs()				// print all registers
57 {
58 	spr();
59 	gpr();
60 }
61 
62 defn mmregs()
63 {
64 	print("MM0\t", *MM0, " MM1\t", *MM1, "\n");
65 	print("MM2\t", *MM2, " MM3\t", *MM3, "\n");
66 	print("MM4\t", *MM4, " MM5\t", *MM5, "\n");
67 	print("MM6\t", *MM6, " MM7\t", *MM7, "\n");
68 }
69 
70 defn pstop(pid)
71 {
72 	local l;
73 	local pc;
74 
75 	pc = *PC;
76 
77 	print(pid,": ", reason(*TRAP), "\t");
78 	print(fmt(pc, 'a'), "\t", *fmt(pc, 'i'), "\n");
79 
80 	if notes then {
81 		if notes[0] != "sys: breakpoint" then {
82 			print("Notes pending:\n");
83 			l = notes;
84 			while l do {
85 				print("\t", head l, "\n");
86 				l = tail l;
87 			}
88 		}
89 	}
90 }
91 
92 aggr Ureg
93 {
94 	'U' 0 di;
95 	'U' 4 si;
96 	'U' 8 bp;
97 	'U' 12 nsp;
98 	'U' 16 bx;
99 	'U' 20 dx;
100 	'U' 24 cx;
101 	'U' 28 ax;
102 	'U' 32 gs;
103 	'U' 36 fs;
104 	'U' 40 es;
105 	'U' 44 ds;
106 	'U' 48 trap;
107 	'U' 52 ecode;
108 	'U' 56 pc;
109 	'U' 60 cs;
110 	'U' 64 flags;
111 	{
112 	'U' 68 usp;
113 	'U' 68 sp;
114 	};
115 	'U' 72 ss;
116 };
117 
118 defn
119 Ureg(addr) {
120 	complex Ureg addr;
121 	print("	di	", addr.di, "\n");
122 	print("	si	", addr.si, "\n");
123 	print("	bp	", addr.bp, "\n");
124 	print("	nsp	", addr.nsp, "\n");
125 	print("	bx	", addr.bx, "\n");
126 	print("	dx	", addr.dx, "\n");
127 	print("	cx	", addr.cx, "\n");
128 	print("	ax	", addr.ax, "\n");
129 	print("	gs	", addr.gs, "\n");
130 	print("	fs	", addr.fs, "\n");
131 	print("	es	", addr.es, "\n");
132 	print("	ds	", addr.ds, "\n");
133 	print("	trap	", addr.trap, "\n");
134 	print("	ecode	", addr.ecode, "\n");
135 	print("	pc	", addr.pc, "\n");
136 	print("	cs	", addr.cs, "\n");
137 	print("	flags	", addr.flags, "\n");
138 	print("	sp	", addr.sp, "\n");
139 	print("	ss	", addr.ss, "\n");
140 };
141 sizeofUreg = 76;
142 
143 aggr Linkdebug
144 {
145 	'X' 0 version;
146 	'X' 4 map;
147 };
148 
149 aggr Linkmap
150 {
151 	'X' 0 addr;
152 	'X' 4 name;
153 	'X' 8 dynsect;
154 	'X' 12 next;
155 	'X' 16 prev;
156 };
157 
158 defn
159 linkdebug()
160 {
161 	local a;
162 
163 	if !havesymbol("_DYNAMIC") then
164 		return 0;
165 	
166 	a = _DYNAMIC;
167 	while *a != 0 do {
168 		if *a == 21 then // 21 == DT_DEBUG
169 			return *(a+4);
170 		a = a+8;
171 	}
172 	return 0;
173 }
174 
175 defn
176 dynamicmap()
177 {
178 	if systype == "linux"  || systype == "freebsd" then {
179 		local r, m, n;
180 	
181 		r = linkdebug();
182 		if r then {
183 			complex Linkdebug r;
184 			m = r.map;
185 			n = 0;
186 			while m != 0 && n < 100 do {
187 				complex Linkmap m;
188 				if m.name && *(m.name\b) && access(*(m.name\s)) then
189 					print("textfile({\"", *(m.name\s), "\", ", m.addr\X, "});\n");
190 				m = m.next;
191 				n = n+1;
192 			}
193 		}
194 	}
195 }
196 
197 defn
198 acidmap()
199 {
200 //	dynamicmap();
201 	acidtypes();
202 }
203 
204 print(acidfile);