1 #!/usr/bin/env perl
2 #
3 # mkindex was written by Omar Polo <op@openbsd.org> and is placed in
4 # the public domain.  The author hereby disclaims copyright to this
5 # source code.
6 
7 use open ":std", ":encoding(UTF-8)";
8 use utf8;
9 use strict;
10 use warnings;
11 use v5.32;
12 use File::Temp qw(tempfile);
13 
14 use OpenBSD::Pledge;
15 use OpenBSD::Unveil;
16 
17 use lib ".";
18 use GotMArc qw(parse san urlencode initpage endpage index_header thread_header);
19 
20 my $outdir = $ENV{'OUTDIR'};
21 die 'Set $OUTDIR' unless defined $outdir;
22 
23 my $tfh; # thread file handle
24 my $pfh; # page file handle
25 my $page = 0;
26 my @pages;
27 my @files;
28 my $from_day;
29 my $to_day;
30 my $threads_seen = 0;
31 
32 my $last_level = 0;
33 my $last_tid;
34 my $last_date;
35 my $last_from;
36 my $last_subj;
37 
38 my $threads = 0;
39 my $threads_per_page = 100;
40 
41 sub maxs {
42 	my ($a, $b) = @_;
43 	return $a unless defined $b;
44 	return $a gt $b ? $a : $b;
45 }
46 
47 sub mins {
48 	my ($a, $b) = @_;
49 	return $a unless defined $b;
50 	return $a lt $b ? $a : $b;
51 }
52 
53 sub pagename {
54 	my $i = shift;
55 	return $i == 1 && "index.html" || "$i.html";
56 }
57 
58 sub endfile {
59 	say $pfh '</ul></div>';
60 	close($pfh);
61 	push @pages, "$from_day - $to_day";
62 }
63 
64 sub nextfile {
65 	endfile if defined $pfh;
66 	$page += 1;
67 
68 	my $path;
69 	($pfh, $path) = tempfile "/tmp/gotmarc.index.XXXXXXXXXX";
70 	push @files, $path;
71 	say $pfh "<div class='thread'><ul>";
72 }
73 
74 sub nav {
75 	my ($pfh, $n) = @_;
76 	my ($first, $last) = (pagename(1), pagename($page));
77 	my ($next, $prev) = (pagename($n+1), pagename($n-1));
78 
79 	say $pfh "<nav>";
80 	say $pfh "<a href='$first'>First</a>" if $n > 2;
81 	say $pfh "<a href='$prev'>Prev</a>" if $n > 1;
82 	say $pfh "<a href='$next'>Next</a>" if $n < $page;
83 	say $pfh "<a href='$last'>Last</a>" if $n < $page - 1;
84 	say $pfh "</nav>";
85 }
86 
87 sub copyfrom {
88 	my ($path, $fh) = @_;
89 
90 	# there are probably faster ways to do this like File::Copy,
91 	# but it bypasses the bufio cache...
92 	open(my $pfh, '<', $path) or die "can't open $path: $!";
93 	print $fh $_ while <$pfh>;
94 }
95 
96 sub renderpages {
97 	close($pfh);
98 
99 	for (my $i = 1; $i <= $page; $i++) {
100 		my $name = pagename($i);
101 		my $path = shift @files;
102 		my $dest = "$outdir/$name";
103 
104 		open(my $pfh, '>', $dest)
105 		    or die "can't open $dest for writing: $!";
106 
107 		my $title = "Game of Trees Mail Archive | page $i";
108 		my $subtitle = $pages[$i-1];
109 
110 		initpage($pfh, $title);
111 		index_header $pfh, $i, $subtitle;
112 		say $pfh "<main>";
113 
114 		nav $pfh, $i if $page > 1;
115 		copyfrom($path, $pfh);
116 		nav $pfh, $i if $page > 1;
117 
118 		say $pfh "</main>";
119 		endpage($pfh);
120 
121 		close($pfh);
122 		unlink $path;
123 	}
124 }
125 
126 sub endthread {
127 	say $tfh "</ul></li>" x $last_level;
128 	say $tfh "</ul>\n</div>\n";
129 	endpage($tfh);
130 	close($tfh);
131 
132 	$last_level = 0;
133 }
134 
135 sub nextthread {
136 	endthread if defined $tfh;
137 	my ($mid, $subj) = @_;
138 	my $dest = "$outdir/thread/$mid.html";
139 	open($tfh, '>', $dest) or die "can't open $dest: $!";
140 	initpage($tfh, $subj);
141 	thread_header $tfh, undef, undef, ["Thread: $subj"];
142 	print $tfh "<div class='thread'><ul class='mails'>\n";
143 }
144 
145 sub entry {
146 	my ($fh, $type, $mid, $date, $from, $subj) = @_;
147 	my $encmid = urlencode $mid;
148 
149 	print $fh "<li id='$encmid' class='mail'>";
150 	print $fh "<p class='mail-meta'>";
151 	print $fh "<time>$date</time> ";
152 	print $fh "<span class='from'>$from</span>";
153 	print $fh "<span class='colon'>:</span>";
154 	print $fh "</p>";
155 	print $fh "<p class='subject'>";
156 	print $fh "<a href='/$type/$encmid.html'>$subj</a>";
157 	print $fh "</p>";
158 	print $fh "</li>\n";
159 }
160 
161 sub index_entry {
162 	my ($fh, $mid, $date, $from, $subj) = @_;
163 
164 	entry $fh, "thread", $mid, $date, $from, $subj;
165 }
166 
167 sub thread_entry {
168 	my ($fh, $mid, $level, $date, $from, $subj) = @_;
169 
170 	say $fh "</ul>\n</li>" x ($last_level - $level) if $last_level > $level;
171 	say $fh "<li>\n<ul>" if $last_level < $level;
172 
173 	entry $fh, "mail", $mid, $date, $from, $subj;
174 }
175 
176 unveil($outdir, "rwc") or die "unveil $outdir: $!";
177 unveil(".", "r") or die "unveil .: $!";
178 
179 # can't use tmppath because File::Temp checks wether /tmp exists.
180 unveil("/tmp", "rwc") or die "unveil /tmp: $!";
181 
182 # fattr for File::Temp
183 pledge("stdio rpath wpath cpath fattr") or die "pledge: $!";
184 
185 nextfile;
186 
187 while (<>) {
188 	my ($level, $fname, $mid, $date, $from, $subj) = parse;
189 
190 	if ($level == 0) {
191 		nextthread $mid, $subj;
192 
193 		$threads++;
194 		if ($threads > $threads_per_page) {
195 			nextfile;
196 			$threads = 0;
197 			$to_day = undef;
198 			$from_day = undef;
199 		}
200 
201 		my $day = $date =~ s/ .*//r;
202 		$to_day = mins $day, $to_day;
203 		$from_day = maxs $day, $from_day;
204 	}
205 
206 	thread_entry $tfh, $mid, $level, $date, $from, $subj;
207 	$last_level = $level;
208 	$threads_seen = 1;
209 
210 	index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
211 	    if defined $last_tid && $level == 0;
212 
213 	$last_tid = $mid if $level == 0;
214 	$last_date = $date;
215 	$last_from = $from;
216 	$last_subj = $subj if $level == 0;
217 }
218 
219 index_entry $pfh, $last_tid, $last_date, $last_from, $last_subj
220     if defined $last_tid;
221 
222 endfile;
223 endthread if $threads_seen;
224 renderpages;