1 #!/usr/bin/env perl
2 #
3 # mkindex was written by Omar Polo <op@openbsd.org> and is placed in
4 # the public domain.  The author hereby disclaims copyright to this
5 # source code.
6 
7 use open ":std", ":encoding(UTF-8)";
8 use utf8;
9 use strict;
10 use warnings;
11 use v5.32;
12 use File::Temp qw(tempfile);
13 
14 use OpenBSD::Pledge;
15 use OpenBSD::Unveil;
16 
17 use lib ".";
18 use GotMArc qw(parse san urlencode initpage endpage index_header thread_header);
19 
20 my $outdir = $ENV{'OUTDIR'};
21 die 'Set $OUTDIR' unless defined $outdir;
22 
23 my $tfh; # thread file handle
24 my $pfh; # page file handle
25 my $page = 0;
26 my @pages;
27 my @files;
28 my $from_day;
29 my $to_day;
30 my $threads_seen = 0;
31 my $last_level = 0;
32 my $threads = 0;
33 my $threads_per_page = 100;
34 
35 sub maxs {
36 	my ($a, $b) = @_;
37 	return $a unless defined $b;
38 	return $a gt $b ? $a : $b;
39 }
40 
41 sub mins {
42 	my ($a, $b) = @_;
43 	return $a unless defined $b;
44 	return $a lt $b ? $a : $b;
45 }
46 
47 sub pagename {
48 	my $i = shift;
49 	return $i == 1 && "index.html" || "$i.html";
50 }
51 
52 sub endfile {
53 	say $pfh '</ul></div>';
54 	close($pfh);
55 	push @pages, "$from_day - $to_day";
56 }
57 
58 sub nextfile {
59 	endfile if defined $pfh;
60 	$page += 1;
61 
62 	my $path;
63 	($pfh, $path) = tempfile "/tmp/gotmarc.index.XXXXXXXXXX";
64 	push @files, $path;
65 	say $pfh "<div class='thread'><ul>";
66 }
67 
68 sub nav {
69 	my ($pfh, $n) = @_;
70 	my ($first, $last) = (pagename(1), pagename($page));
71 	my ($next, $prev) = (pagename($n+1), pagename($n-1));
72 
73 	say $pfh "<nav>";
74 	say $pfh "<a href='$first'>First</a>" if $n > 2;
75 	say $pfh "<a href='$prev'>Prev</a>" if $n > 1;
76 	say $pfh "<a href='$next'>Next</a>" if $n < $page;
77 	say $pfh "<a href='$last'>Last</a>" if $n < $page - 1;
78 	say $pfh "</nav>";
79 }
80 
81 sub copyfrom {
82 	my ($path, $fh) = @_;
83 
84 	# there are probably faster ways to do this like File::Copy,
85 	# but it bypasses the bufio cache...
86 	open(my $pfh, '<', $path) or die "can't open $path: $!";
87 	print $fh $_ while <$pfh>;
88 }
89 
90 sub renderpages {
91 	close($pfh);
92 
93 	for (my $i = 1; $i <= $page; $i++) {
94 		my $name = pagename($i);
95 		my $path = shift @files;
96 		my $dest = "$outdir/$name";
97 
98 		open(my $pfh, '>', $dest)
99 		    or die "can't open $dest for writing: $!";
100 
101 		my $title = "Game of Trees Mail Archive | page $i";
102 		my $subtitle = $pages[$i-1];
103 
104 		initpage($pfh, $title);
105 		index_header $pfh, $i, $subtitle;
106 		say $pfh "<main>";
107 
108 		nav $pfh, $i if $page > 1;
109 		copyfrom($path, $pfh);
110 		nav $pfh, $i if $page > 1;
111 
112 		say $pfh "</main>";
113 		endpage($pfh);
114 
115 		close($pfh);
116 		unlink $path;
117 	}
118 }
119 
120 sub endthread {
121 	say $tfh "</ul></li>" x $last_level;
122 	say $tfh "</ul>\n</div>\n";
123 	endpage($tfh);
124 	close($tfh);
125 
126 	$last_level = 0;
127 }
128 
129 sub nextthread {
130 	endthread if defined $tfh;
131 	my ($mid, $subj) = @_;
132 	my $dest = "$outdir/thread/$mid.html";
133 	open($tfh, '>', $dest) or die "can't open $dest: $!";
134 	initpage($tfh, $subj);
135 	thread_header $tfh, undef, undef, ["Thread: $subj"];
136 	print $tfh "<div class='thread'><ul class='mails'>\n";
137 }
138 
139 sub entry {
140 	my ($fh, $type, $mid, $date, $from, $subj) = @_;
141 	my $encmid = urlencode $mid;
142 
143 	print $fh "<li id='$encmid' class='mail'>";
144 	print $fh "<p class='mail-meta'>";
145 	print $fh "<time>$date</time> ";
146 	print $fh "<span class='from'>$from</span>";
147 	print $fh "<span class='colon'>:</span>";
148 	print $fh "</p>";
149 	print $fh "<p class='subject'>";
150 	print $fh "<a href='/$type/$encmid.html'>$subj</a>";
151 	print $fh "</p>";
152 	print $fh "</li>\n";
153 }
154 
155 sub thread_entry {
156 	my ($fh, $mid, $level, $date, $from, $subj) = @_;
157 
158 	say $fh "</ul>\n</li>" x ($last_level - $level) if $last_level > $level;
159 	say $fh "<li>\n<ul>" if $last_level < $level;
160 
161 	entry $fh, "mail", $mid, $date, $from, $subj;
162 }
163 
164 unveil($outdir, "rwc") or die "unveil $outdir: $!";
165 unveil(".", "r") or die "unveil .: $!";
166 
167 # can't use tmppath because File::Temp checks wether /tmp exists.
168 unveil("/tmp", "rwc") or die "unveil /tmp: $!";
169 
170 # fattr for File::Temp
171 pledge("stdio rpath wpath cpath fattr") or die "pledge: $!";
172 
173 nextfile;
174 
175 while (<>) {
176 	my ($level, $fname, $mid, $date, $from, $subj) = parse;
177 
178 	if ($level == 0) {
179 		nextthread $mid, $subj;
180 
181 		$threads++;
182 		if ($threads > $threads_per_page) {
183 			nextfile;
184 			$threads = 0;
185 			$to_day = undef;
186 			$from_day = undef;
187 		}
188 
189 		my $day = $date =~ s/ .*//r;
190 		$to_day = mins $day, $to_day;
191 		$from_day = maxs $day, $from_day;
192 
193 		entry $pfh, "thread", $mid, $date, $from, $subj;
194 	}
195 
196 	thread_entry $tfh, $mid, $level, $date, $from, $subj;
197 	$last_level = $level;
198 	$threads_seen = 1;
199 }
200 
201 endfile;
202 endthread if $threads_seen;
203 renderpages;