1 /* -*- mode:c; indent-tabs-mode: t; -*- */
2 %{
3 
4 /*
5  * Copyright (c) 2020 Omar Polo <op@omarpolo.com>
6  *
7  * Permission to use, copy, modify, and distribute this software for any
8  * purpose with or without fee is hereby granted, provided that the above
9  * copyright notice and this permission notice appear in all copies.
10  *
11  * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
12  * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
13  * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
14  * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
15  * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
16  * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
17  * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
18  */
19 
20 #include "star-platinum.h"
21 
22 #include <X11/Xlib.h>
23 #include <X11/keysymdef.h>
24 
25 #include <err.h>
26 #include <string.h>
27 
28 #include "y.tab.h"
29 
30 int state  = 0;
31 KeySym key = 0;
32 
33 %}
34 
35 %x COMMENT
36 %x KEY
37 %x STRING
38 
39 %%
40 
41 <INITIAL>#	BEGIN(COMMENT);
42 <COMMENT>.*\n	yylineno++; BEGIN(INITIAL); return '\n';
43 
44 <INITIAL>\"	BEGIN(KEY);
45 <KEY>\"		{
46 	BEGIN(INITIAL);
47 	yylval.key = (struct key){ state, key };
48 	state = 0;
49 	key = 0;
50 	return TKEY;
51  }
52 
53 <KEY>C-		state |= ControlMask;
54 <KEY>S-		state |= ShiftMask;
55 <KEY>M-		state |= Mod1Mask;
56 <KEY>s-		state |= Mod4Mask;
57 
58 <KEY><[^>]+>	{
59 	char *c;
60 
61 	if ((c = strdup(yytext)) == NULL)
62 		err(1, "strdup");
63 
64 	c++;			/* skip the < */
65 	c[strlen(c)-1] = '\0';	/* trim the > */
66 
67 	if ((key = XStringToKeysym(c)) == NoSymbol)
68 		yyerror("invalid keysym %s", c);
69 
70 	free(--c);
71  }
72 
73 <KEY>SPC	key = XK_space;
74 <KEY>RET	key = XK_Return;
75 
76 <KEY>"("	key = XK_parenleft;
77 <KEY>")"	key = XK_parenright;
78 
79 <KEY>.		{
80 	if ((key = XStringToKeysym(yytext)) == NoSymbol)
81 		yyerror("invalid key %s", yytext);
82  }
83 
84 <INITIAL>\'	BEGIN(STRING);
85 <STRING>[^']*\'	{
86 	if ((yylval.str = strdup(yytext)) == NULL)
87 		err(1, "strdup");
88 	yylval.str[strlen(yylval.str)-1] = '\0'; /* remove the closing quote */
89 	BEGIN(INITIAL);
90 	return TSTRING;
91  }
92 
93 match		return TMATCH;
94 class		return TCLASS;
95 on		return TON;
96 do		return TDO;
97 toggle		return TTOGGLE;
98 activate	return TACTIVATE;
99 deactivate	return TDEACTIVATE;
100 ignore		return TIGNORE;
101 exec		return TEXEC;
102 all		return TALL;
103 
104 \n		yylineno++; return '\n';
105 [ \r\t\f]+
106 
107 .		return TERR;
108 
109 %%
110 
111 int
112 yywrap(void)
113 {
114 	return 1;
115 }