1 .text
2 
3 .p2align 2,0x90
4 .globl _sha1block
5 	.type _sha1block, @function
6 _sha1block:
7 
8 /* x = (wp[off-f] ^ wp[off-8] ^ wp[off-14] ^ wp[off-16]) <<< 1;
9  * wp[off] = x;
10  * x += A <<< 5;
11  * E += 0xca62c1d6 + x;
12  * x = FN(B,C,D);
13  * E += x;
14  * B >>> 2
15  */
16 #define BSWAPDI	BYTE $0x0f; BYTE $0xcf;
17 
18 #define BODY(off,FN,V,A,B,C,D,E)\
19 	movl (off-64)(%ebp), %edi;\
20 	xorl (off-56)(%ebp), %edi;\
21 	xorl (off-32)(%ebp), %edi;\
22 	xorl (off-12)(%ebp), %edi;\
23 	roll $1, %edi;\
24 	movl %edi, off(%ebp);\
25 	leal V(%edi, E, 1), E;\
26 	movl A, %edi;\
27 	roll $5, %edi;\
28 	addl %edi, E;\
29 	FN(B,C,D)\
30 	addl %edi, E;\
31 	rorl $2, B;\
32 
33 #define BODY0(off,FN,V,A,B,C,D,E)\
34 	movl off(%ebx), %edi;\
35 	bswap %edi;\
36 	movl %edi, off(%ebp);\
37 	leal V(%edi,E,1), E;\
38 	movl A, %edi;\
39 	roll $5,%edi;\
40 	addl %edi,E;\
41 	FN(B,C,D)\
42 	addl %edi,E;\
43 	rorl $2,B;\
44 
45 /*
46  * fn1 = (((C^D)&B)^D);
47  */
48 #define FN1(B,C,D)\
49 	movl C, %edi;\
50 	xorl D, %edi;\
51 	andl B, %edi;\
52 	xorl D, %edi;\
53 
54 /*
55  * fn24 = B ^ C ^ D
56  */
57 #define FN24(B,C,D)\
58 	movl B, %edi;\
59 	xorl C, %edi;\
60 	xorl D, %edi;\
61 
62 /*
63  * fn3 = ((B ^ C) & (D ^= B)) ^ B
64  * D ^= B to restore D
65  */
66 #define FN3(B,C,D)\
67 	movl B, %edi;\
68 	xorl C, %edi;\
69 	xorl B, D;\
70 	andl D, %edi;\
71 	xorl B, %edi;\
72 	xorl B, D;\
73 
74 /*
75  * stack offsets
76  * void sha1block(uchar *DATA, int LEN, ulong *STATE)
77  */
78 #define	DATA	8
79 #define	LEN	12
80 #define	STATE	16
81 
82 /*
83  * stack offsets for locals
84  * ulong w[80];
85  * uchar *edata;
86  * ulong *w15, *w40, *w60, *w80;
87  * register local
88  * ulong *wp = %ebp
89  * ulong a = eax, b = ebx, c = ecx, d = edx, e = esi
90  * ulong tmp = edi
91  */
92 #define WARRAY	(-4-(80*4))
93 #define TMP1	(-8-(80*4))
94 #define TMP2	(-12-(80*4))
95 #define W15	(-16-(80*4))
96 #define W40	(-20-(80*4))
97 #define W60	(-24-(80*4))
98 #define W80	(-28-(80*4))
99 #define EDATA	(-32-(80*4))
100 #define OLDEBX	(-36-(80*4))
101 #define OLDESI	(-40-(80*4))
102 #define OLDEDI	(-44-(80*4))
103 
104 	/* Prelude */
105 	pushl %ebp
106 	mov %ebx, OLDEBX(%esp)
107 	mov %esi, OLDESI(%esp)
108 	mov %edi, OLDEDI(%esp)
109 
110 	movl DATA(%esp), %eax
111 	addl LEN(%esp), %eax
112 	movl %eax, EDATA(%esp)
113 
114 	leal (WARRAY+15*4)(%esp), %edi	/* aw15 */
115 	movl %edi, W15(%esp)
116 	leal (WARRAY+40*4)(%esp), %edx	/* aw40 */
117 	movl %edx, W40(%esp)
118 	leal (WARRAY+60*4)(%esp), %ecx	/* aw60 */
119 	movl %ecx, W60(%esp)
120 	leal (WARRAY+80*4)(%esp), %edi	/* aw80 */
121 	movl %edi, W80(%esp)
122 
123 mainloop:
124 	leal WARRAY(%esp), %ebp		/* warray */
125 
126 	movl STATE(%esp), %edi		/* state */
127 	movl (%edi),%eax
128 	movl 4(%edi),%ebx
129 	movl %ebx, TMP1(%esp)		/* tmp1 */
130 	movl 8(%edi), %ecx
131 	movl 12(%edi), %edx
132 	movl 16(%edi), %esi
133 
134 	movl DATA(%esp), %ebx		/* data */
135 
136 loop1:
137 	BODY0(0,FN1,0x5a827999,%eax,TMP1(%esp),%ecx,%edx,%esi)
138 	movl %esi,TMP2(%esp)
139 	BODY0(4,FN1,0x5a827999,%esi,%eax,TMP1(%esp),%ecx,%edx)
140 	movl TMP1(%esp),%esi
141 	BODY0(8,FN1,0x5a827999,%edx,TMP2(%esp),%eax,%esi,%ecx)
142 	BODY0(12,FN1,0x5a827999,%ecx,%edx,TMP2(%esp),%eax,%esi)
143 	movl %esi,TMP1(%esp)
144 	BODY0(16,FN1,0x5a827999,%esi,%ecx,%edx,TMP2(%esp),%eax)
145 	movl TMP2(%esp),%esi
146 
147 	addl $20, %ebx
148 	addl $20, %ebp
149 	cmpl W15(%esp), %ebp	/* w15 */
150 	jb loop1
151 
152 	BODY0(0,FN1,0x5a827999,%eax,TMP1(%esp),%ecx,%edx,%esi)
153 	addl $4, %ebx
154 	MOVL %ebx, DATA(%esp)	/* data */
155 	MOVL TMP1(%esp),%ebx
156 
157 	BODY(4,FN1,0x5a827999,%esi,%eax,%ebx,%ecx,%edx)
158 	BODY(8,FN1,0x5a827999,%edx,%esi,%eax,%ebx,%ecx)
159 	BODY(12,FN1,0x5a827999,%ecx,%edx,%esi,%eax,%ebx)
160 	BODY(16,FN1,0x5a827999,%ebx,%ecx,%edx,%esi,%eax)
161 
162 	addl $20, %ebp
163 
164 loop2:
165 	BODY(0,FN24,0x6ed9eba1,%eax,%ebx,%ecx,%edx,%esi)
166 	BODY(4,FN24,0x6ed9eba1,%esi,%eax,%ebx,%ecx,%edx)
167 	BODY(8,FN24,0x6ed9eba1,%edx,%esi,%eax,%ebx,%ecx)
168 	BODY(12,FN24,0x6ed9eba1,%ecx,%edx,%esi,%eax,%ebx)
169 	BODY(16,FN24,0x6ed9eba1,%ebx,%ecx,%edx,%esi,%eax)
170 
171 	addl $20,%ebp
172 	cmpl W40(%esp), %ebp
173 	jb loop2
174 
175 loop3:
176 	BODY(0,FN3,0x8f1bbcdc,%eax,%ebx,%ecx,%edx,%esi)
177 	BODY(4,FN3,0x8f1bbcdc,%esi,%eax,%ebx,%ecx,%edx)
178 	BODY(8,FN3,0x8f1bbcdc,%edx,%esi,%eax,%ebx,%ecx)
179 	BODY(12,FN3,0x8f1bbcdc,%ecx,%edx,%esi,%eax,%ebx)
180 	BODY(16,FN3,0x8f1bbcdc,%ebx,%ecx,%edx,%esi,%eax)
181 
182 	addl $20, %ebp
183 	cmpl W60(%esp), %ebp 	/* w60 */
184 	jb loop3
185 
186 loop4:
187 	BODY(0,FN24,0xca62c1d6,%eax,%ebx,%ecx,%edx,%esi)
188 	BODY(4,FN24,0xca62c1d6,%esi,%eax,%ebx,%ecx,%edx)
189 	BODY(8,FN24,0xca62c1d6,%edx,%esi,%eax,%ebx,%ecx)
190 	BODY(12,FN24,0xca62c1d6,%ecx,%edx,%esi,%eax,%ebx)
191 	BODY(16,FN24,0xca62c1d6,%ebx,%ecx,%edx,%esi,%eax)
192 
193 	addl $20, %ebp
194 	cmpl W80(%esp), %ebp 	/* w80 */
195 	jb loop4
196 
197 	movl STATE(%esp), %edi	/* state */
198 	addl %eax, 0(%edi)
199 	addl %ebx, 4(%edi)
200 	addl %ecx, 8(%edi)
201 	addl %edx, 12(%edi)
202 	addl %esi, 16(%edi)
203 
204 	movl EDATA(%esp), %edi	/* edata */
205 	cmpl %edi, DATA(%esp)	/* data */
206 	jb mainloop
207 
208 	/* Postlude */
209 	mov OLDEBX(%esp), %ebx
210 	mov OLDESI(%esp), %esi
211 	mov OLDEDI(%esp), %edi
212 	movl %esp, %ebp
213 	leave
214 	ret